scripts/sphinx-pre-install

   1 #!/usr/bin/perl
   2 # SPDX-License-Identifier: GPL-2.0-or-later
   3 use strict;
   4
   5 # Copyright (c) 2017-2019 Mauro Carvalho Chehab <mchehab@kernel.org>
   6 #
   7
   8 my $prefix = "./";
   9 $prefix = "$ENV{'srctree'}/" if ($ENV{'srctree'});
  10
  11 my $conf = $prefix . "Documentation/conf.py";
  12 my $requirement_file = $prefix . "Documentation/sphinx/requirements.txt";
  13 my $virtenv_prefix = "sphinx_";
  14
  15 #
  16 # Static vars
  17 #
  18
  19 my %missing;
  20 my $system_release;
  21 my $need = 0;
  22 my $optional = 0;
  23 my $need_symlink = 0;
  24 my $need_sphinx = 0;
  25 my $rec_sphinx_upgrade = 0;
  26 my $install = "";
  27 my $virtenv_dir = "";
  28 my $min_version;
  29
  30 #
  31 # Command line arguments
  32 #
  33
  34 my $pdf = 1;
  35 my $virtualenv = 1;
  36 my $version_check = 0;
  37
  38 #
  39 # List of required texlive packages on Fedora and OpenSuse
  40 #
  41
  42 my %texlive = (
  43         'amsfonts.sty'       => 'texlive-amsfonts',
  44         'amsmath.sty'        => 'texlive-amsmath',
  45         'amssymb.sty'        => 'texlive-amsfonts',
  46         'amsthm.sty'         => 'texlive-amscls',
  47         'anyfontsize.sty'    => 'texlive-anyfontsize',
  48         'atbegshi.sty'       => 'texlive-oberdiek',
  49         'bm.sty'             => 'texlive-tools',
  50         'capt-of.sty'        => 'texlive-capt-of',
  51         'cmap.sty'           => 'texlive-cmap',
  52         'ecrm1000.tfm'       => 'texlive-ec',
  53         'eqparbox.sty'       => 'texlive-eqparbox',
  54         'eu1enc.def'         => 'texlive-euenc',
  55         'fancybox.sty'       => 'texlive-fancybox',
  56         'fancyvrb.sty'       => 'texlive-fancyvrb',
  57         'float.sty'          => 'texlive-float',
  58         'fncychap.sty'       => 'texlive-fncychap',
  59         'footnote.sty'       => 'texlive-mdwtools',
  60         'framed.sty'         => 'texlive-framed',
  61         'luatex85.sty'       => 'texlive-luatex85',
  62         'multirow.sty'       => 'texlive-multirow',
  63         'needspace.sty'      => 'texlive-needspace',
  64         'palatino.sty'       => 'texlive-psnfss',
  65         'parskip.sty'        => 'texlive-parskip',
  66         'polyglossia.sty'    => 'texlive-polyglossia',
  67         'tabulary.sty'       => 'texlive-tabulary',
  68         'threeparttable.sty' => 'texlive-threeparttable',
  69         'titlesec.sty'       => 'texlive-titlesec',
  70         'ucs.sty'            => 'texlive-ucs',
  71         'upquote.sty'        => 'texlive-upquote',
  72         'wrapfig.sty'        => 'texlive-wrapfig',
  73 );
  74
  75 #
  76 # Subroutines that checks if a feature exists
  77 #
  78
  79 sub check_missing(%)
  80 {
  81         my %map = %{$_[0]};
  82
  83         foreach my $prog (sort keys %missing) {
  84                 my $is_optional = $missing{$prog};
  85
  86                 # At least on some LTS distros like CentOS 7, texlive doesn't
  87                 # provide all packages we need. When such distros are
  88                 # detected, we have to disable PDF output.
  89                 #
  90                 # So, we need to ignore the packages that distros would
  91                 # need for LaTeX to work
  92                 if ($is_optional == 2 && !$pdf) {
  93                         $optional--;
  94                         next;
  95                 }
  96
  97                 if ($is_optional) {
  98                         print "Warning: better to also install \"$prog\".\n";
  99                 } else {
 100                         print "ERROR: please install \"$prog\", otherwise, build won't work.\n";
 101                 }
 102                 if (defined($map{$prog})) {
 103                         $install .= " " . $map{$prog};
 104                 } else {
 105                         $install .= " " . $prog;
 106                 }
 107         }
 108
 109         $install =~ s/^\s//;
 110 }
 111
 112 sub add_package($$)
 113 {
 114         my $package = shift;
 115         my $is_optional = shift;
 116
 117         $missing{$package} = $is_optional;
 118         if ($is_optional) {
 119                 $optional++;
 120         } else {
 121                 $need++;
 122         }
 123 }
 124
 125 sub check_missing_file($$$)
 126 {
 127         my $files = shift;
 128         my $package = shift;
 129         my $is_optional = shift;
 130
 131         for (@$files) {
 132                 return if(-e $_);
 133         }
 134
 135         add_package($package, $is_optional);
 136 }
 137
 138 sub findprog($)
 139 {
 140         foreach(split(/:/, $ENV{PATH})) {
 141                 return "$_/$_[0]" if(-x "$_/$_[0]");
 142         }
 143 }
 144
 145 sub check_program($$)
 146 {
 147         my $prog = shift;
 148         my $is_optional = shift;
 149
 150         return if findprog($prog);
 151
 152         add_package($prog, $is_optional);
 153 }
 154
 155 sub check_perl_module($$)
 156 {
 157         my $prog = shift;
 158         my $is_optional = shift;
 159
 160         my $err = system("perl -M$prog -e 1 2>/dev/null /dev/null");
 161         return if ($err == 0);
 162
 163         add_package($prog, $is_optional);
 164 }
 165
 166 sub check_python_module($$)
 167 {
 168         my $prog = shift;
 169         my $is_optional = shift;
 170
 171         my $err = system("python3 -c 'import $prog' 2>/dev/null /dev/null");
 172         return if ($err == 0);
 173         my $err = system("python -c 'import $prog' 2>/dev/null /dev/null");
 174         return if ($err == 0);
 175
 176         add_package($prog, $is_optional);
 177 }
 178
 179 sub check_rpm_missing($$)
 180 {
 181         my @pkgs = @{$_[0]};
 182         my $is_optional = $_[1];
 183
 184         foreach my $prog(@pkgs) {
 185                 my $err = system("rpm -q '$prog' 2>/dev/null >/dev/null");
 186                 add_package($prog, $is_optional) if ($err);
 187         }
 188 }
 189
 190 sub check_pacman_missing($$)
 191 {
 192         my @pkgs = @{$_[0]};
 193         my $is_optional = $_[1];
 194
 195         foreach my $prog(@pkgs) {
 196                 my $err = system("pacman -Q '$prog' 2>/dev/null >/dev/null");
 197                 add_package($prog, $is_optional) if ($err);
 198         }
 199 }
 200
 201 sub check_missing_tex($)
 202 {
 203         my $is_optional = shift;
 204         my $kpsewhich = findprog("kpsewhich");
 205
 206         foreach my $prog(keys %texlive) {
 207                 my $package = $texlive{$prog};
 208                 if (!$kpsewhich) {
 209                         add_package($package, $is_optional);
 210                         next;
 211                 }
 212                 my $file = qx($kpsewhich $prog);
 213                 add_package($package, $is_optional) if ($file =~ /^\s*$/);
 214         }
 215 }
 216
 217 sub get_sphinx_fname()
 218 {
 219         my $fname = "sphinx-build";
 220         return $fname if findprog($fname);
 221
 222         $fname = "sphinx-build-3";
 223         if (findprog($fname)) {
 224                 $need_symlink = 1;
 225                 return $fname;
 226         }
 227
 228         if ($virtualenv) {
 229                 my $prog = findprog("virtualenv-3");
 230                 $prog = findprog("virtualenv-3.5") if (!$prog);
 231
 232                 check_program("virtualenv", 0) if (!$prog);
 233                 $need_sphinx = 1;
 234         } else {
 235                 add_package("python-sphinx", 0);
 236         }
 237
 238         return "";
 239 }
 240
 241 sub check_sphinx()
 242 {
 243         my $rec_version;
 244         my $cur_version;
 245
 246         open IN, $conf or die "Can't open $conf";
 247         while (<IN>) {
 248                 if (m/^\s*needs_sphinx\s*=\s*[\'\"]([\d\.]+)[\'\"]/) {
 249                         $min_version=$1;
 250                         last;
 251                 }
 252         }
 253         close IN;
 254
 255         die "Can't get needs_sphinx version from $conf" if (!$min_version);
 256
 257         open IN, $requirement_file or die "Can't open $requirement_file";
 258         while (<IN>) {
 259                 if (m/^\s*Sphinx\s*==\s*([\d\.]+)$/) {
 260                         $rec_version=$1;
 261                         last;
 262                 }
 263         }
 264         close IN;
 265
 266         die "Can't get recommended sphinx version from $requirement_file" if (!$min_version);
 267
 268         $virtenv_dir = $virtenv_prefix . $rec_version;
 269
 270         my $sphinx = get_sphinx_fname();
 271         return if ($sphinx eq "");
 272
 273         open IN, "$sphinx --version 2>&1 |" or die "$sphinx returned an error";
 274         while (<IN>) {
 275                 if (m/^\s*sphinx-build\s+([\d\.]+)$/) {
 276                         $cur_version=$1;
 277                         last;
 278                 }
 279                 # Sphinx 1.2.x uses a different format
 280                 if (m/^\s*Sphinx.*\s+([\d\.]+)$/) {
 281                         $cur_version=$1;
 282                         last;
 283                 }
 284         }
 285         close IN;
 286
 287         die "$sphinx didn't return its version" if (!$cur_version);
 288
 289         if ($cur_version lt $min_version) {
 290                 printf "ERROR: Sphinx version is %s. It should be >= %s (recommended >= %s)\n",
 291                        $cur_version, $min_version, $rec_version;;
 292                 $need_sphinx = 1;
 293                 return;
 294         }
 295
 296         if ($cur_version lt $rec_version) {
 297                 printf "Sphinx version %s\n", $cur_version;
 298                 print "Warning: It is recommended at least Sphinx version $rec_version.\n";
 299                 $rec_sphinx_upgrade = 1;
 300                 return;
 301         }
 302
 303         # On version check mode, just assume Sphinx has all mandatory deps
 304         exit (0) if ($version_check);
 305 }
 306
 307 #
 308 # Ancillary subroutines
 309 #
 310
 311 sub catcheck($)
 312 {
 313   my $res = "";
 314   $res = qx(cat $_[0]) if (-r $_[0]);
 315   return $res;
 316 }
 317
 318 sub which($)
 319 {
 320         my $file = shift;
 321         my @path = split ":", $ENV{PATH};
 322
 323         foreach my $dir(@path) {
 324                 my $name = $dir.'/'.$file;
 325                 return $name if (-x $name );
 326         }
 327         return undef;
 328 }
 329
 330 #
 331 # Subroutines that check distro-specific hints
 332 #
 333
 334 sub give_debian_hints()
 335 {
 336         my %map = (
 337                 "python-sphinx"         => "python3-sphinx",
 338                 "sphinx_rtd_theme"      => "python3-sphinx-rtd-theme",
 339                 "virtualenv"            => "virtualenv",
 340                 "dot"                   => "graphviz",
 341                 "convert"               => "imagemagick",
 342                 "Pod::Usage"            => "perl-modules",
 343                 "xelatex"               => "texlive-xetex",
 344                 "rsvg-convert"          => "librsvg2-bin",
 345         );
 346
 347         if ($pdf) {
 348                 check_missing_file(["/usr/share/fonts/truetype/dejavu/DejaVuSans.ttf"],
 349                                    "fonts-dejavu", 2);
 350
 351                 check_missing_file(["/usr/share/fonts/noto-cjk/NotoSansCJK-Regular.ttc",
 352                                    "/usr/share/fonts/opentype/noto/NotoSerifCJK-Regular.ttc"],
 353                                    "fonts-noto-cjk", 2);
 354         }
 355
 356         check_program("dvipng", 2) if ($pdf);
 357         check_missing(\%map);
 358
 359         return if (!$need && !$optional);
 360         printf("You should run:\n\n\tsudo apt-get install $install\n");
 361 }
 362
 363 sub give_redhat_hints()
 364 {
 365         my %map = (
 366                 "python-sphinx"         => "python3-sphinx",
 367                 "sphinx_rtd_theme"      => "python3-sphinx_rtd_theme",
 368                 "virtualenv"            => "python3-virtualenv",
 369                 "dot"                   => "graphviz",
 370                 "convert"               => "ImageMagick",
 371                 "Pod::Usage"            => "perl-Pod-Usage",
 372                 "xelatex"               => "texlive-xetex-bin",
 373                 "rsvg-convert"          => "librsvg2-tools",
 374         );
 375
 376         my @fedora26_opt_pkgs = (
 377                 "graphviz-gd",          # Fedora 26: needed for PDF support
 378         );
 379
 380         my @fedora_tex_pkgs = (
 381                 "texlive-collection-fontsrecommended",
 382                 "texlive-collection-latex",
 383                 "texlive-xecjk",
 384                 "dejavu-sans-fonts",
 385                 "dejavu-serif-fonts",
 386                 "dejavu-sans-mono-fonts",
 387         );
 388
 389         #
 390         # Checks valid for RHEL/CentOS version 7.x.
 391         #
 392         my $old = 0;
 393         my $rel;
 394         $rel = $1 if ($system_release =~ /release\s+(\d+)/);
 395
 396         if (!($system_release =~ /Fedora/)) {
 397                 $map{"virtualenv"} = "python-virtualenv";
 398
 399                 if ($rel && $rel < 8) {
 400                         $old = 1;
 401                         $pdf = 0;
 402
 403                         printf("Note: texlive packages on RHEL/CENTOS <= 7 are incomplete. Can't support PDF output\n");
 404                         printf("If you want to build PDF, please read:\n");
 405                         printf("\thttps://www.systutorials.com/241660/how-to-install-tex-live-on-centos-7-linux/\n");
 406                 }
 407         } else {
 408                 if ($rel && $rel < 26) {
 409                         $old = 1;
 410                 }
 411         }
 412         if (!$rel) {
 413                 printf("Couldn't identify release number\n");
 414                 $old = 1;
 415                 $pdf = 0;
 416         }
 417
 418         if ($pdf) {
 419                 check_missing_file(["/usr/share/fonts/google-noto-cjk/NotoSansCJK-Regular.ttc"],
 420                                    "google-noto-sans-cjk-ttc-fonts", 2);
 421         }
 422
 423         check_rpm_missing(\@fedora26_opt_pkgs, 2) if ($pdf && !$old);
 424         check_rpm_missing(\@fedora_tex_pkgs, 2) if ($pdf);
 425         check_missing_tex(2) if ($pdf);
 426         check_missing(\%map);
 427
 428         return if (!$need && !$optional);
 429
 430         if (!$old) {
 431                 # dnf, for Fedora 18+
 432                 printf("You should run:\n\n\tsudo dnf install -y $install\n");
 433         } else {
 434                 # yum, for RHEL (and clones) or Fedora version < 18
 435                 printf("You should run:\n\n\tsudo yum install -y $install\n");
 436         }
 437 }
 438
 439 sub give_opensuse_hints()
 440 {
 441         my %map = (
 442                 "python-sphinx"         => "python3-sphinx",
 443                 "sphinx_rtd_theme"      => "python3-sphinx_rtd_theme",
 444                 "virtualenv"            => "python3-virtualenv",
 445                 "dot"                   => "graphviz",
 446                 "convert"               => "ImageMagick",
 447                 "Pod::Usage"            => "perl-Pod-Usage",
 448                 "xelatex"               => "texlive-xetex-bin",
 449                 "rsvg-convert"          => "rsvg-view",
 450         );
 451
 452         my @suse_tex_pkgs = (
 453                 "texlive-babel-english",
 454                 "texlive-caption",
 455                 "texlive-colortbl",
 456                 "texlive-courier",
 457                 "texlive-dvips",
 458                 "texlive-helvetic",
 459                 "texlive-makeindex",
 460                 "texlive-metafont",
 461                 "texlive-metapost",
 462                 "texlive-palatino",
 463                 "texlive-preview",
 464                 "texlive-times",
 465                 "texlive-zapfchan",
 466                 "texlive-zapfding",
 467         );
 468
 469         $map{"latexmk"} = "texlive-latexmk-bin";
 470
 471         # FIXME: add support for installing CJK fonts
 472         #
 473         # I tried hard, but was unable to find a way to install
 474         # "Noto Sans CJK SC" on openSUSE
 475
 476         check_rpm_missing(\@suse_tex_pkgs, 2) if ($pdf);
 477         check_missing_tex(2) if ($pdf);
 478         check_missing(\%map);
 479
 480         return if (!$need && !$optional);
 481         printf("You should run:\n\n\tsudo zypper install --no-recommends $install\n");
 482 }
 483
 484 sub give_mageia_hints()
 485 {
 486         my %map = (
 487                 "python-sphinx"         => "python3-sphinx",
 488                 "sphinx_rtd_theme"      => "python3-sphinx_rtd_theme",
 489                 "virtualenv"            => "python3-virtualenv",
 490                 "dot"                   => "graphviz",
 491                 "convert"               => "ImageMagick",
 492                 "Pod::Usage"            => "perl-Pod-Usage",
 493                 "xelatex"               => "texlive",
 494                 "rsvg-convert"          => "librsvg2-tools",
 495         );
 496
 497         my @tex_pkgs = (
 498                 "texlive-fontsextra",
 499         );
 500
 501         $map{"latexmk"} = "texlive-collection-basic";
 502
 503         if ($pdf) {
 504                 check_missing_file(["/usr/share/fonts/google-noto-cjk/NotoSansCJK-Regular.ttc"],
 505                                    "google-noto-sans-cjk-ttc-fonts", 2);
 506         }
 507
 508         check_rpm_missing(\@tex_pkgs, 2) if ($pdf);
 509         check_missing(\%map);
 510
 511         return if (!$need && !$optional);
 512         printf("You should run:\n\n\tsudo urpmi $install\n");
 513 }
 514
 515 sub give_arch_linux_hints()
 516 {
 517         my %map = (
 518                 "sphinx_rtd_theme"      => "python-sphinx_rtd_theme",
 519                 "virtualenv"            => "python-virtualenv",
 520                 "dot"                   => "graphviz",
 521                 "convert"               => "imagemagick",
 522                 "xelatex"               => "texlive-bin",
 523                 "latexmk"               => "texlive-core",
 524                 "rsvg-convert"          => "extra/librsvg",
 525         );
 526
 527         my @archlinux_tex_pkgs = (
 528                 "texlive-core",
 529                 "texlive-latexextra",
 530                 "ttf-dejavu",
 531         );
 532         check_pacman_missing(\@archlinux_tex_pkgs, 2) if ($pdf);
 533
 534         if ($pdf) {
 535                 check_missing_file(["/usr/share/fonts/noto-cjk/NotoSansCJK-Regular.ttc"],
 536                                    "noto-fonts-cjk", 2);
 537         }
 538
 539         check_missing(\%map);
 540
 541         return if (!$need && !$optional);
 542         printf("You should run:\n\n\tsudo pacman -S $install\n");
 543 }
 544
 545 sub give_gentoo_hints()
 546 {
 547         my %map = (
 548                 "sphinx_rtd_theme"      => "dev-python/sphinx_rtd_theme",
 549                 "virtualenv"            => "dev-python/virtualenv",
 550                 "dot"                   => "media-gfx/graphviz",
 551                 "convert"               => "media-gfx/imagemagick",
 552                 "xelatex"               => "dev-texlive/texlive-xetex media-fonts/dejavu",
 553                 "rsvg-convert"          => "gnome-base/librsvg",
 554         );
 555
 556         check_missing_file(["/usr/share/fonts/dejavu/DejaVuSans.ttf"],
 557                            "media-fonts/dejavu", 2) if ($pdf);
 558
 559         if ($pdf) {
 560                 check_missing_file(["/usr/share/fonts/noto-cjk/NotoSansCJKsc-Regular.otf"],
 561                                    "media-fonts/noto-cjk", 2);
 562         }
 563
 564         check_missing(\%map);
 565
 566         return if (!$need && !$optional);
 567
 568         printf("You should run:\n\n");
 569
 570         my $imagemagick = "media-gfx/imagemagick svg png";
 571         my $cairo = "media-gfx/graphviz cairo pdf";
 572         my $portage_imagemagick = "/etc/portage/package.use/imagemagick";
 573         my $portage_cairo = "/etc/portage/package.use/graphviz";
 574
 575         if (qx(cat $portage_imagemagick) ne "$imagemagick\n") {
 576                 printf("\tsudo su -c 'echo \"$imagemagick\" > $portage_imagemagick'\n")
 577         }
 578         if (qx(cat $portage_cairo) ne  "$cairo\n") {
 579                 printf("\tsudo su -c 'echo \"$cairo\" > $portage_cairo'\n");
 580         }
 581
 582         printf("\tsudo emerge --ask $install\n");
 583
 584 }
 585
 586 sub check_distros()
 587 {
 588         # Distro-specific hints
 589         if ($system_release =~ /Red Hat Enterprise Linux/) {
 590                 give_redhat_hints;
 591                 return;
 592         }
 593         if ($system_release =~ /CentOS/) {
 594                 give_redhat_hints;
 595                 return;
 596         }
 597         if ($system_release =~ /Scientific Linux/) {
 598                 give_redhat_hints;
 599                 return;
 600         }
 601         if ($system_release =~ /Oracle Linux Server/) {
 602                 give_redhat_hints;
 603                 return;
 604         }
 605         if ($system_release =~ /Fedora/) {
 606                 give_redhat_hints;
 607                 return;
 608         }
 609         if ($system_release =~ /Ubuntu/) {
 610                 give_debian_hints;
 611                 return;
 612         }
 613         if ($system_release =~ /Debian/) {
 614                 give_debian_hints;
 615                 return;
 616         }
 617         if ($system_release =~ /openSUSE/) {
 618                 give_opensuse_hints;
 619                 return;
 620         }
 621         if ($system_release =~ /Mageia/) {
 622                 give_mageia_hints;
 623                 return;
 624         }
 625         if ($system_release =~ /Arch Linux/) {
 626                 give_arch_linux_hints;
 627                 return;
 628         }
 629         if ($system_release =~ /Gentoo/) {
 630                 give_gentoo_hints;
 631                 return;
 632         }
 633
 634         #
 635         # Fall-back to generic hint code for other distros
 636         # That's far from ideal, specially for LaTeX dependencies.
 637         #
 638         my %map = (
 639                 "sphinx-build" => "sphinx"
 640         );
 641         check_missing_tex(2) if ($pdf);
 642         check_missing(\%map);
 643         print "I don't know distro $system_release.\n";
 644         print "So, I can't provide you a hint with the install procedure.\n";
 645         print "There are likely missing dependencies.\n";
 646 }
 647
 648 #
 649 # Common dependencies
 650 #
 651
 652 sub deactivate_help()
 653 {
 654         printf "\tIf you want to exit the virtualenv, you can use:\n";
 655         printf "\tdeactivate\n";
 656 }
 657
 658 sub check_needs()
 659 {
 660         # Check for needed programs/tools
 661         check_sphinx();
 662
 663         if ($system_release) {
 664                 print "Detected OS: $system_release.\n\n";
 665         } else {
 666                 print "Unknown OS\n\n";
 667         }
 668
 669         print "To upgrade Sphinx, use:\n\n" if ($rec_sphinx_upgrade);
 670
 671         # Check for needed programs/tools
 672         check_perl_module("Pod::Usage", 0);
 673         check_program("make", 0);
 674         check_program("gcc", 0);
 675         check_python_module("sphinx_rtd_theme", 1) if (!$virtualenv);
 676         check_program("dot", 1);
 677         check_program("convert", 1);
 678
 679         # Extra PDF files - should use 2 for is_optional
 680         check_program("xelatex", 2) if ($pdf);
 681         check_program("rsvg-convert", 2) if ($pdf);
 682         check_program("latexmk", 2) if ($pdf);
 683
 684         check_distros();
 685
 686         if ($need_symlink) {
 687                 printf "\tsudo ln -sf %s /usr/bin/sphinx-build\n\n",
 688                        which("sphinx-build-3");
 689         }
 690         if ($need_sphinx || $rec_sphinx_upgrade) {
 691                 my $min_activate = "$ENV{'PWD'}/${virtenv_prefix}${min_version}/bin/activate";
 692                 my @activates = glob "$ENV{'PWD'}/${virtenv_prefix}*/bin/activate";
 693
 694                 @activates = sort {$b cmp $a} @activates;
 695
 696                 if ($need_sphinx && scalar @activates > 0 && $activates[0] ge $min_activate) {
 697                         printf "\nNeed to activate a compatible Sphinx version on virtualenv with:\n";
 698                         printf "\t. $activates[0]\n";
 699                         deactivate_help();
 700                         exit (1);
 701                 } else {
 702                         my $rec_activate = "$virtenv_dir/bin/activate";
 703                         my $virtualenv = findprog("virtualenv-3");
 704                         $virtualenv = findprog("virtualenv-3.5") if (!$virtualenv);
 705                         $virtualenv = findprog("virtualenv") if (!$virtualenv);
 706                         $virtualenv = "virtualenv" if (!$virtualenv);
 707
 708                         printf "\t$virtualenv $virtenv_dir\n";
 709                         printf "\t. $rec_activate\n";
 710                         printf "\tpip install -r $requirement_file\n";
 711                         deactivate_help();
 712
 713                         $need++ if (!$rec_sphinx_upgrade);
 714                 }
 715         }
 716         printf "\n";
 717
 718         print "All optional dependencies are met.\n" if (!$optional);
 719
 720         if ($need == 1) {
 721                 die "Can't build as $need mandatory dependency is missing";
 722         } elsif ($need) {
 723                 die "Can't build as $need mandatory dependencies are missing";
 724         }
 725
 726         print "Needed package dependencies are met.\n";
 727 }
 728
 729 #
 730 # Main
 731 #
 732
 733 while (@ARGV) {
 734         my $arg = shift(@ARGV);
 735
 736         if ($arg eq "--no-virtualenv") {
 737                 $virtualenv = 0;
 738         } elsif ($arg eq "--no-pdf"){
 739                 $pdf = 0;
 740         } elsif ($arg eq "--version-check"){
 741                 $version_check = 1;
 742         } else {
 743                 print "Usage:\n\t$0 <--no-virtualenv> <--no-pdf> <--version-check>\n\n";
 744                 print "Where:\n";
 745                 print "\t--no-virtualenv\t- Recommend installing Sphinx instead of using a virtualenv\n";
 746                 print "\t--version-check\t- if version is compatible, don't check for missing dependencies\n";
 747                 print "\t--no-pdf\t- don't check for dependencies required to build PDF docs\n\n";
 748                 exit -1;
 749         }
 750 }
 751
 752 #
 753 # Determine the system type. There's no standard unique way that would
 754 # work with all distros with a minimal package install. So, several
 755 # methods are used here.
 756 #
 757 # By default, it will use lsb_release function. If not available, it will
 758 # fail back to reading the known different places where the distro name
 759 # is stored
 760 #
 761
 762 $system_release = qx(lsb_release -d) if which("lsb_release");
 763 $system_release =~ s/Description:\s*// if ($system_release);
 764 $system_release = catcheck("/etc/system-release") if !$system_release;
 765 $system_release = catcheck("/etc/redhat-release") if !$system_release;
 766 $system_release = catcheck("/etc/lsb-release") if !$system_release;
 767 $system_release = catcheck("/etc/gentoo-release") if !$system_release;
 768 $system_release = catcheck("/etc/issue") if !$system_release;
 769 $system_release =~ s/\s+$//;
 770
 771 check_needs;