scripts/module.lds.S

   1 /*
   2  * Common module linker script, always used when linking a module.
   3  * Archs are free to supply their own linker scripts.  ld will
   4  * combine them automatically.
   5  */
   6 SECTIONS {
   7         /DISCARD/ : {
   8                 *(.discard)
   9                 *(.discard.*)
  10         }
  11
  12         __ksymtab               0 : { *(SORT(___ksymtab+*)) }
  13         __ksymtab_gpl           0 : { *(SORT(___ksymtab_gpl+*)) }
  14         __ksymtab_unused        0 : { *(SORT(___ksymtab_unused+*)) }
  15         __ksymtab_unused_gpl    0 : { *(SORT(___ksymtab_unused_gpl+*)) }
  16         __ksymtab_gpl_future    0 : { *(SORT(___ksymtab_gpl_future+*)) }
  17         __kcrctab               0 : { *(SORT(___kcrctab+*)) }
  18         __kcrctab_gpl           0 : { *(SORT(___kcrctab_gpl+*)) }
  19         __kcrctab_unused        0 : { *(SORT(___kcrctab_unused+*)) }
  20         __kcrctab_unused_gpl    0 : { *(SORT(___kcrctab_unused_gpl+*)) }
  21         __kcrctab_gpl_future    0 : { *(SORT(___kcrctab_gpl_future+*)) }
  22
  23         .init_array             0 : ALIGN(8) { *(SORT(.init_array.*)) *(.init_array) }
  24
  25         __jump_table            0 : ALIGN(8) { KEEP(*(__jump_table)) }
  26
  27         __patchable_function_entries : { *(__patchable_function_entries) }
  28
  29         /*
  30          * With CONFIG_LTO_CLANG, LLD always enables -fdata-sections and
  31          * -ffunction-sections, which increases the size of the final module.
  32          * Merge the split sections in the final binary.
  33          */
  34         .bss : {
  35                 *(.bss .bss.[0-9a-zA-Z_]*)
  36                 *(.bss..L*)
  37         }
  38
  39         .data : {
  40                 *(.data .data.[0-9a-zA-Z_]*)
  41                 *(.data..L*)
  42         }
  43
  44         .rodata : {
  45                 *(.rodata .rodata.[0-9a-zA-Z_]*)
  46                 *(.rodata..L*)
  47         }
  48
  49         .text : { *(.text .text.[0-9a-zA-Z_]*) }
  50 }
  51
  52 /* bring in arch-specific sections */
  53 #include <asm/module.lds.h>