arch/powerpc/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 #ifdef CONFIG_PPC64
   3 #define PROVIDE32(x)    PROVIDE(__unused__##x)
   4 #else
   5 #define PROVIDE32(x)    PROVIDE(x)
   6 #endif
   7
   8 #define BSS_FIRST_SECTIONS *(.bss.prominit)
   9 #define EMITS_PT_NOTE
  10 #define RO_EXCEPTION_TABLE_ALIGN        0
  11
  12 #include <asm/page.h>
  13 #include <asm-generic/vmlinux.lds.h>
  14 #include <asm/cache.h>
  15 #include <asm/thread_info.h>
  16
  17 #define STRICT_ALIGN_SIZE       (1 << CONFIG_DATA_SHIFT)
  18
  19 ENTRY(_stext)
  20
  21 PHDRS {
  22         text PT_LOAD FLAGS(7); /* RWX */
  23         note PT_NOTE FLAGS(0);
  24 }
  25
  26 #ifdef CONFIG_PPC64
  27 OUTPUT_ARCH(powerpc:common64)
  28 jiffies = jiffies_64;
  29 #else
  30 OUTPUT_ARCH(powerpc:common)
  31 jiffies = jiffies_64 + 4;
  32 #endif
  33 SECTIONS
  34 {
  35         . = KERNELBASE;
  36
  37 /*
  38  * Text, read only data and other permanent read-only sections
  39  */
  40
  41         _text = .;
  42         _stext = .;
  43
  44         /*
  45          * Head text.
  46          * This needs to be in its own output section to avoid ld placing
  47          * branch trampoline stubs randomly throughout the fixed sections,
  48          * which it will do (even if the branch comes from another section)
  49          * in order to optimize stub generation.
  50          */
  51         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
  52 #ifdef CONFIG_PPC64
  53                 KEEP(*(.head.text.first_256B));
  54 #ifdef CONFIG_PPC_BOOK3E
  55 #else
  56                 KEEP(*(.head.text.real_vectors));
  57                 *(.head.text.real_trampolines);
  58                 KEEP(*(.head.text.virt_vectors));
  59                 *(.head.text.virt_trampolines);
  60 # if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
  61                 KEEP(*(.head.data.fwnmi_page));
  62 # endif
  63 #endif
  64 #else /* !CONFIG_PPC64 */
  65                 HEAD_TEXT
  66 #endif
  67         } :text
  68
  69         __head_end = .;
  70
  71 #ifdef CONFIG_PPC64
  72         /*
  73          * ALIGN(0) overrides the default output section alignment because
  74          * this needs to start right after .head.text in order for fixed
  75          * section placement to work.
  76          */
  77         .text ALIGN(0) : AT(ADDR(.text) - LOAD_OFFSET) {
  78 #ifdef CONFIG_LD_HEAD_STUB_CATCH
  79                 KEEP(*(.linker_stub_catch));
  80                 . = . ;
  81 #endif
  82
  83 #else
  84         .text : AT(ADDR(.text) - LOAD_OFFSET) {
  85                 ALIGN_FUNCTION();
  86 #endif
  87                 /* careful! __ftr_alt_* sections need to be close to .text */
  88                 *(.text.hot TEXT_MAIN .text.fixup .text.unlikely .fixup __ftr_alt_* .ref.text);
  89 #ifdef CONFIG_PPC64
  90                 *(.tramp.ftrace.text);
  91 #endif
  92                 NOINSTR_TEXT
  93                 SCHED_TEXT
  94                 CPUIDLE_TEXT
  95                 LOCK_TEXT
  96                 KPROBES_TEXT
  97                 IRQENTRY_TEXT
  98                 SOFTIRQENTRY_TEXT
  99                 /*
 100                  * -Os builds call FP save/restore functions. The powerpc64
 101                  * linker generates those on demand in the .sfpr section.
 102                  * .sfpr gets placed at the beginning of a group of input
 103                  * sections, which can break start-of-text offset if it is
 104                  * included with the main text sections, so put it by itself.
 105                  */
 106                 *(.sfpr);
 107                 MEM_KEEP(init.text)
 108                 MEM_KEEP(exit.text)
 109
 110 #ifdef CONFIG_PPC32
 111                 *(.got1)
 112                 __got2_start = .;
 113                 *(.got2)
 114                 __got2_end = .;
 115 #endif /* CONFIG_PPC32 */
 116
 117         } :text
 118
 119         . = ALIGN(PAGE_SIZE);
 120         _etext = .;
 121         PROVIDE32 (etext = .);
 122
 123         /* Read-only data */
 124         RO_DATA(PAGE_SIZE)
 125
 126 #ifdef CONFIG_PPC64
 127         . = ALIGN(8);
 128         __stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) {
 129                 __start___stf_entry_barrier_fixup = .;
 130                 *(__stf_entry_barrier_fixup)
 131                 __stop___stf_entry_barrier_fixup = .;
 132         }
 133
 134         . = ALIGN(8);
 135         __entry_flush_fixup : AT(ADDR(__entry_flush_fixup) - LOAD_OFFSET) {
 136                 __start___entry_flush_fixup = .;
 137                 *(__entry_flush_fixup)
 138                 __stop___entry_flush_fixup = .;
 139         }
 140
 141         . = ALIGN(8);
 142         __stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) {
 143                 __start___stf_exit_barrier_fixup = .;
 144                 *(__stf_exit_barrier_fixup)
 145                 __stop___stf_exit_barrier_fixup = .;
 146         }
 147
 148         . = ALIGN(8);
 149         __rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) {
 150                 __start___rfi_flush_fixup = .;
 151                 *(__rfi_flush_fixup)
 152                 __stop___rfi_flush_fixup = .;
 153         }
 154 #endif /* CONFIG_PPC64 */
 155
 156 #ifdef CONFIG_PPC_BARRIER_NOSPEC
 157         . = ALIGN(8);
 158         __spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) {
 159                 __start___barrier_nospec_fixup = .;
 160                 *(__barrier_nospec_fixup)
 161                 __stop___barrier_nospec_fixup = .;
 162         }
 163 #endif /* CONFIG_PPC_BARRIER_NOSPEC */
 164
 165 #ifdef CONFIG_PPC_FSL_BOOK3E
 166         . = ALIGN(8);
 167         __spec_btb_flush_fixup : AT(ADDR(__spec_btb_flush_fixup) - LOAD_OFFSET) {
 168                 __start__btb_flush_fixup = .;
 169                 *(__btb_flush_fixup)
 170                 __stop__btb_flush_fixup = .;
 171         }
 172 #endif
 173
 174 /*
 175  * Init sections discarded at runtime
 176  */
 177         . = ALIGN(STRICT_ALIGN_SIZE);
 178         __init_begin = .;
 179         . = ALIGN(PAGE_SIZE);
 180         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 181                 _sinittext = .;
 182                 INIT_TEXT
 183                 _einittext = .;
 184 #ifdef CONFIG_PPC64
 185                 *(.tramp.ftrace.init);
 186 #endif
 187         } :text
 188
 189         /* .exit.text is discarded at runtime, not link time,
 190          * to deal with references from __bug_table
 191          */
 192         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 193                 EXIT_TEXT
 194         }
 195
 196         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
 197                 INIT_DATA
 198         }
 199
 200         .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
 201                 INIT_SETUP(16)
 202         }
 203
 204         .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 205                 INIT_CALLS
 206         }
 207
 208         .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 209                 CON_INITCALL
 210         }
 211
 212         . = ALIGN(8);
 213         __ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
 214                 __start___ftr_fixup = .;
 215                 KEEP(*(__ftr_fixup))
 216                 __stop___ftr_fixup = .;
 217         }
 218         . = ALIGN(8);
 219         __mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
 220                 __start___mmu_ftr_fixup = .;
 221                 KEEP(*(__mmu_ftr_fixup))
 222                 __stop___mmu_ftr_fixup = .;
 223         }
 224         . = ALIGN(8);
 225         __lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
 226                 __start___lwsync_fixup = .;
 227                 KEEP(*(__lwsync_fixup))
 228                 __stop___lwsync_fixup = .;
 229         }
 230 #ifdef CONFIG_PPC64
 231         . = ALIGN(8);
 232         __fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
 233                 __start___fw_ftr_fixup = .;
 234                 KEEP(*(__fw_ftr_fixup))
 235                 __stop___fw_ftr_fixup = .;
 236         }
 237 #endif
 238         .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
 239                 INIT_RAM_FS
 240         }
 241
 242         PERCPU_SECTION(L1_CACHE_BYTES)
 243
 244         . = ALIGN(8);
 245         .machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
 246                 __machine_desc_start = . ;
 247                 KEEP(*(.machine.desc))
 248                 __machine_desc_end = . ;
 249         }
 250 #ifdef CONFIG_RELOCATABLE
 251         . = ALIGN(8);
 252         .dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
 253         {
 254 #ifdef CONFIG_PPC32
 255                 __dynamic_symtab = .;
 256 #endif
 257                 *(.dynsym)
 258         }
 259         .dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
 260         .dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
 261         {
 262                 __dynamic_start = .;
 263                 *(.dynamic)
 264         }
 265         .hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
 266         .gnu.hash : AT(ADDR(.gnu.hash) - LOAD_OFFSET) { *(.gnu.hash) }
 267         .interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
 268         .rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
 269         {
 270                 __rela_dyn_start = .;
 271                 *(.rela*)
 272         }
 273 #endif
 274         /* .exit.data is discarded at runtime, not link time,
 275          * to deal with references from .exit.text
 276          */
 277         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 278                 EXIT_DATA
 279         }
 280
 281         /* freed after init ends here */
 282         . = ALIGN(PAGE_SIZE);
 283         __init_end = .;
 284
 285 /*
 286  * And now the various read/write data
 287  */
 288
 289         . = ALIGN(PAGE_SIZE);
 290         _sdata = .;
 291
 292 #ifdef CONFIG_PPC32
 293         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 294                 DATA_DATA
 295 #ifdef CONFIG_UBSAN
 296                 *(.data..Lubsan_data*)
 297                 *(.data..Lubsan_type*)
 298 #endif
 299                 *(.data.rel*)
 300                 *(SDATA_MAIN)
 301                 *(.sdata2)
 302                 *(.got.plt) *(.got)
 303                 *(.plt)
 304                 *(.branch_lt)
 305         }
 306 #else
 307         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 308                 DATA_DATA
 309                 *(.data.rel*)
 310                 *(.toc1)
 311                 *(.branch_lt)
 312         }
 313
 314         .opd : AT(ADDR(.opd) - LOAD_OFFSET) {
 315                 __start_opd = .;
 316                 KEEP(*(.opd))
 317                 __end_opd = .;
 318         }
 319
 320         . = ALIGN(256);
 321         .got : AT(ADDR(.got) - LOAD_OFFSET) {
 322                 __toc_start = .;
 323 #ifndef CONFIG_RELOCATABLE
 324                 __prom_init_toc_start = .;
 325                 arch/powerpc/kernel/prom_init.o*(.toc .got)
 326                 __prom_init_toc_end = .;
 327 #endif
 328                 *(.got)
 329                 *(.toc)
 330         }
 331 #endif
 332
 333         /* The initial task and kernel stack */
 334         INIT_TASK_DATA_SECTION(THREAD_ALIGN)
 335
 336         .data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
 337                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 338         }
 339
 340         .data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
 341                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 342         }
 343
 344         .data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
 345                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
 346         }
 347
 348         . = ALIGN(PAGE_SIZE);
 349         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 350                 NOSAVE_DATA
 351         }
 352
 353         BUG_TABLE
 354
 355         . = ALIGN(PAGE_SIZE);
 356         _edata  =  .;
 357         PROVIDE32 (edata = .);
 358
 359 /*
 360  * And finally the bss
 361  */
 362
 363         BSS_SECTION(0, 0, 0)
 364
 365         . = ALIGN(PAGE_SIZE);
 366         _end = . ;
 367         PROVIDE32 (end = .);
 368
 369         STABS_DEBUG
 370         DWARF_DEBUG
 371         ELF_DETAILS
 372
 373         DISCARDS
 374         /DISCARD/ : {
 375                 *(*.EMB.apuinfo)
 376                 *(.glink .iplt .plt .rela* .comment)
 377                 *(.gnu.version*)
 378                 *(.gnu.attributes)
 379                 *(.eh_frame)
 380         }
 381 }