arch/loongarch/vdso/vdso.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * Author: Huacai Chen <chenhuacai@loongson.cn>
   4  * Copyright (C) 2020-2022 Loongson Technology Corporation Limited
   5  */
   6
   7 OUTPUT_FORMAT("elf64-loongarch", "elf64-loongarch", "elf64-loongarch")
   8
   9 OUTPUT_ARCH(loongarch)
  10
  11 SECTIONS
  12 {
  13         PROVIDE(_start = .);
  14         . = SIZEOF_HEADERS;
  15
  16         .hash           : { *(.hash) }                  :text
  17         .gnu.hash       : { *(.gnu.hash) }
  18         .dynsym         : { *(.dynsym) }
  19         .dynstr         : { *(.dynstr) }
  20         .gnu.version    : { *(.gnu.version) }
  21         .gnu.version_d  : { *(.gnu.version_d) }
  22         .gnu.version_r  : { *(.gnu.version_r) }
  23
  24         .note           : { *(.note.*) }                :text :note
  25
  26         .text           : { *(.text*) }                 :text
  27         PROVIDE (__etext = .);
  28         PROVIDE (_etext = .);
  29         PROVIDE (etext = .);
  30
  31         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text :eh_frame_hdr
  32         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  33
  34         .dynamic        : { *(.dynamic) }               :text :dynamic
  35
  36         .rodata         : { *(.rodata*) }               :text
  37
  38         _end = .;
  39         PROVIDE(end = .);
  40
  41         /DISCARD/       : {
  42                 *(.gnu.attributes)
  43                 *(.note.GNU-stack)
  44                 *(.data .data.* .gnu.linkonce.d.* .sdata*)
  45                 *(.bss .sbss .dynbss .dynsbss)
  46         }
  47 }
  48
  49 PHDRS
  50 {
  51         text            PT_LOAD         FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
  52         dynamic         PT_DYNAMIC      FLAGS(4);               /* PF_R */
  53         note            PT_NOTE         FLAGS(4);               /* PF_R */
  54         eh_frame_hdr    PT_GNU_EH_FRAME;
  55 }
  56
  57 VERSION
  58 {
  59         LINUX_5.10 {
  60         global:
  61                 __vdso_getcpu;
  62                 __vdso_clock_getres;
  63                 __vdso_clock_gettime;
  64                 __vdso_gettimeofday;
  65                 __vdso_rt_sigreturn;
  66         local: *;
  67         };
  68 }
  69
  70 /*
  71  * Make the sigreturn code visible to the kernel.
  72  */
  73 VDSO_sigreturn          = __vdso_rt_sigreturn;