arch/arm64/kernel/head.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  * Low-level CPU initialisation
   4  * Based on arch/arm/kernel/head.S
   5  *
   6  * Copyright (C) 1994-2002 Russell King
   7  * Copyright (C) 2003-2012 ARM Ltd.
   8  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   9  *              Will Deacon <will.deacon@arm.com>
  10  */
  11
  12 #include <linux/linkage.h>
  13 #include <linux/init.h>
  14 #include <linux/pgtable.h>
  15
  16 #include <asm/asm_pointer_auth.h>
  17 #include <asm/assembler.h>
  18 #include <asm/boot.h>
  19 #include <asm/ptrace.h>
  20 #include <asm/asm-offsets.h>
  21 #include <asm/cache.h>
  22 #include <asm/cputype.h>
  23 #include <asm/el2_setup.h>
  24 #include <asm/elf.h>
  25 #include <asm/image.h>
  26 #include <asm/kernel-pgtable.h>
  27 #include <asm/kvm_arm.h>
  28 #include <asm/memory.h>
  29 #include <asm/pgtable-hwdef.h>
  30 #include <asm/page.h>
  31 #include <asm/scs.h>
  32 #include <asm/smp.h>
  33 #include <asm/sysreg.h>
  34 #include <asm/thread_info.h>
  35 #include <asm/virt.h>
  36
  37 #include "efi-header.S"
  38
  39 #define __PHYS_OFFSET   KERNEL_START
  40
  41 #if (PAGE_OFFSET & 0x1fffff) != 0
  42 #error PAGE_OFFSET must be at least 2MB aligned
  43 #endif
  44
  45 /*
  46  * Kernel startup entry point.
  47  * ---------------------------
  48  *
  49  * The requirements are:
  50  *   MMU = off, D-cache = off, I-cache = on or off,
  51  *   x0 = physical address to the FDT blob.
  52  *
  53  * This code is mostly position independent so you call this at
  54  * __pa(PAGE_OFFSET).
  55  *
  56  * Note that the callee-saved registers are used for storing variables
  57  * that are useful before the MMU is enabled. The allocations are described
  58  * in the entry routines.
  59  */
  60         __HEAD
  61         /*
  62          * DO NOT MODIFY. Image header expected by Linux boot-loaders.
  63          */
  64         efi_signature_nop                       // special NOP to identity as PE/COFF executable
  65         b       primary_entry                   // branch to kernel start, magic
  66         .quad   0                               // Image load offset from start of RAM, little-endian
  67         le64sym _kernel_size_le                 // Effective size of kernel image, little-endian
  68         le64sym _kernel_flags_le                // Informative flags, little-endian
  69         .quad   0                               // reserved
  70         .quad   0                               // reserved
  71         .quad   0                               // reserved
  72         .ascii  ARM64_IMAGE_MAGIC               // Magic number
  73         .long   .Lpe_header_offset              // Offset to the PE header.
  74
  75         __EFI_PE_HEADER
  76
  77         __INIT
  78
  79         /*
  80          * The following callee saved general purpose registers are used on the
  81          * primary lowlevel boot path:
  82          *
  83          *  Register   Scope                      Purpose
  84          *  x21        primary_entry() .. start_kernel()        FDT pointer passed at boot in x0
  85          *  x23        primary_entry() .. start_kernel()        physical misalignment/KASLR offset
  86          *  x28        __create_page_tables()                   callee preserved temp register
  87          *  x19/x20    __primary_switch()                       callee preserved temp registers
  88          *  x24        __primary_switch() .. relocate_kernel()  current RELR displacement
  89          */
  90 SYM_CODE_START(primary_entry)
  91         bl      preserve_boot_args
  92         bl      init_kernel_el                  // w0=cpu_boot_mode
  93         adrp    x23, __PHYS_OFFSET
  94         and     x23, x23, MIN_KIMG_ALIGN - 1    // KASLR offset, defaults to 0
  95         bl      set_cpu_boot_mode_flag
  96         bl      __create_page_tables
  97         /*
  98          * The following calls CPU setup code, see arch/arm64/mm/proc.S for
  99          * details.
 100          * On return, the CPU will be ready for the MMU to be turned on and
 101          * the TCR will have been set.
 102          */
 103         bl      __cpu_setup                     // initialise processor
 104         b       __primary_switch
 105 SYM_CODE_END(primary_entry)
 106
 107 /*
 108  * Preserve the arguments passed by the bootloader in x0 .. x3
 109  */
 110 SYM_CODE_START_LOCAL(preserve_boot_args)
 111         mov     x21, x0                         // x21=FDT
 112
 113         adr_l   x0, boot_args                   // record the contents of
 114         stp     x21, x1, [x0]                   // x0 .. x3 at kernel entry
 115         stp     x2, x3, [x0, #16]
 116
 117         dmb     sy                              // needed before dc ivac with
 118                                                 // MMU off
 119
 120         add     x1, x0, #0x20                   // 4 x 8 bytes
 121         b       dcache_inval_poc                // tail call
 122 SYM_CODE_END(preserve_boot_args)
 123
 124 /*
 125  * Macro to create a table entry to the next page.
 126  *
 127  *      tbl:    page table address
 128  *      virt:   virtual address
 129  *      shift:  #imm page table shift
 130  *      ptrs:   #imm pointers per table page
 131  *
 132  * Preserves:   virt
 133  * Corrupts:    ptrs, tmp1, tmp2
 134  * Returns:     tbl -> next level table page address
 135  */
 136         .macro  create_table_entry, tbl, virt, shift, ptrs, tmp1, tmp2
 137         add     \tmp1, \tbl, #PAGE_SIZE
 138         phys_to_pte \tmp2, \tmp1
 139         orr     \tmp2, \tmp2, #PMD_TYPE_TABLE   // address of next table and entry type
 140         lsr     \tmp1, \virt, #\shift
 141         sub     \ptrs, \ptrs, #1
 142         and     \tmp1, \tmp1, \ptrs             // table index
 143         str     \tmp2, [\tbl, \tmp1, lsl #3]
 144         add     \tbl, \tbl, #PAGE_SIZE          // next level table page
 145         .endm
 146
 147 /*
 148  * Macro to populate page table entries, these entries can be pointers to the next level
 149  * or last level entries pointing to physical memory.
 150  *
 151  *      tbl:    page table address
 152  *      rtbl:   pointer to page table or physical memory
 153  *      index:  start index to write
 154  *      eindex: end index to write - [index, eindex] written to
 155  *      flags:  flags for pagetable entry to or in
 156  *      inc:    increment to rtbl between each entry
 157  *      tmp1:   temporary variable
 158  *
 159  * Preserves:   tbl, eindex, flags, inc
 160  * Corrupts:    index, tmp1
 161  * Returns:     rtbl
 162  */
 163         .macro populate_entries, tbl, rtbl, index, eindex, flags, inc, tmp1
 164 .Lpe\@: phys_to_pte \tmp1, \rtbl
 165         orr     \tmp1, \tmp1, \flags    // tmp1 = table entry
 166         str     \tmp1, [\tbl, \index, lsl #3]
 167         add     \rtbl, \rtbl, \inc      // rtbl = pa next level
 168         add     \index, \index, #1
 169         cmp     \index, \eindex
 170         b.ls    .Lpe\@
 171         .endm
 172
 173 /*
 174  * Compute indices of table entries from virtual address range. If multiple entries
 175  * were needed in the previous page table level then the next page table level is assumed
 176  * to be composed of multiple pages. (This effectively scales the end index).
 177  *
 178  *      vstart: virtual address of start of range
 179  *      vend:   virtual address of end of range
 180  *      shift:  shift used to transform virtual address into index
 181  *      ptrs:   number of entries in page table
 182  *      istart: index in table corresponding to vstart
 183  *      iend:   index in table corresponding to vend
 184  *      count:  On entry: how many extra entries were required in previous level, scales
 185  *                        our end index.
 186  *              On exit: returns how many extra entries required for next page table level
 187  *
 188  * Preserves:   vstart, vend, shift, ptrs
 189  * Returns:     istart, iend, count
 190  */
 191         .macro compute_indices, vstart, vend, shift, ptrs, istart, iend, count
 192         lsr     \iend, \vend, \shift
 193         mov     \istart, \ptrs
 194         sub     \istart, \istart, #1
 195         and     \iend, \iend, \istart   // iend = (vend >> shift) & (ptrs - 1)
 196         mov     \istart, \ptrs
 197         mul     \istart, \istart, \count
 198         add     \iend, \iend, \istart   // iend += (count - 1) * ptrs
 199                                         // our entries span multiple tables
 200
 201         lsr     \istart, \vstart, \shift
 202         mov     \count, \ptrs
 203         sub     \count, \count, #1
 204         and     \istart, \istart, \count
 205
 206         sub     \count, \iend, \istart
 207         .endm
 208
 209 /*
 210  * Map memory for specified virtual address range. Each level of page table needed supports
 211  * multiple entries. If a level requires n entries the next page table level is assumed to be
 212  * formed from n pages.
 213  *
 214  *      tbl:    location of page table
 215  *      rtbl:   address to be used for first level page table entry (typically tbl + PAGE_SIZE)
 216  *      vstart: start address to map
 217  *      vend:   end address to map - we map [vstart, vend]
 218  *      flags:  flags to use to map last level entries
 219  *      phys:   physical address corresponding to vstart - physical memory is contiguous
 220  *      pgds:   the number of pgd entries
 221  *
 222  * Temporaries: istart, iend, tmp, count, sv - these need to be different registers
 223  * Preserves:   vstart, vend, flags
 224  * Corrupts:    tbl, rtbl, istart, iend, tmp, count, sv
 225  */
 226         .macro map_memory, tbl, rtbl, vstart, vend, flags, phys, pgds, istart, iend, tmp, count, sv
 227         add \rtbl, \tbl, #PAGE_SIZE
 228         mov \sv, \rtbl
 229         mov \count, #0
 230         compute_indices \vstart, \vend, #PGDIR_SHIFT, \pgds, \istart, \iend, \count
 231         populate_entries \tbl, \rtbl, \istart, \iend, #PMD_TYPE_TABLE, #PAGE_SIZE, \tmp
 232         mov \tbl, \sv
 233         mov \sv, \rtbl
 234
 235 #if SWAPPER_PGTABLE_LEVELS > 3
 236         compute_indices \vstart, \vend, #PUD_SHIFT, #PTRS_PER_PUD, \istart, \iend, \count
 237         populate_entries \tbl, \rtbl, \istart, \iend, #PMD_TYPE_TABLE, #PAGE_SIZE, \tmp
 238         mov \tbl, \sv
 239         mov \sv, \rtbl
 240 #endif
 241
 242 #if SWAPPER_PGTABLE_LEVELS > 2
 243         compute_indices \vstart, \vend, #SWAPPER_TABLE_SHIFT, #PTRS_PER_PMD, \istart, \iend, \count
 244         populate_entries \tbl, \rtbl, \istart, \iend, #PMD_TYPE_TABLE, #PAGE_SIZE, \tmp
 245         mov \tbl, \sv
 246 #endif
 247
 248         compute_indices \vstart, \vend, #SWAPPER_BLOCK_SHIFT, #PTRS_PER_PTE, \istart, \iend, \count
 249         bic \count, \phys, #SWAPPER_BLOCK_SIZE - 1
 250         populate_entries \tbl, \count, \istart, \iend, \flags, #SWAPPER_BLOCK_SIZE, \tmp
 251         .endm
 252
 253 /*
 254  * Setup the initial page tables. We only setup the barest amount which is
 255  * required to get the kernel running. The following sections are required:
 256  *   - identity mapping to enable the MMU (low address, TTBR0)
 257  *   - first few MB of the kernel linear mapping to jump to once the MMU has
 258  *     been enabled
 259  */
 260 SYM_FUNC_START_LOCAL(__create_page_tables)
 261         mov     x28, lr
 262
 263         /*
 264          * Invalidate the init page tables to avoid potential dirty cache lines
 265          * being evicted. Other page tables are allocated in rodata as part of
 266          * the kernel image, and thus are clean to the PoC per the boot
 267          * protocol.
 268          */
 269         adrp    x0, init_pg_dir
 270         adrp    x1, init_pg_end
 271         bl      dcache_inval_poc
 272
 273         /*
 274          * Clear the init page tables.
 275          */
 276         adrp    x0, init_pg_dir
 277         adrp    x1, init_pg_end
 278         sub     x1, x1, x0
 279 1:      stp     xzr, xzr, [x0], #16
 280         stp     xzr, xzr, [x0], #16
 281         stp     xzr, xzr, [x0], #16
 282         stp     xzr, xzr, [x0], #16
 283         subs    x1, x1, #64
 284         b.ne    1b
 285
 286         mov     x7, SWAPPER_MM_MMUFLAGS
 287
 288         /*
 289          * Create the identity mapping.
 290          */
 291         adrp    x0, idmap_pg_dir
 292         adrp    x3, __idmap_text_start          // __pa(__idmap_text_start)
 293
 294 #ifdef CONFIG_ARM64_VA_BITS_52
 295         mrs_s   x6, SYS_ID_AA64MMFR2_EL1
 296         and     x6, x6, #(0xf << ID_AA64MMFR2_LVA_SHIFT)
 297         mov     x5, #52
 298         cbnz    x6, 1f
 299 #endif
 300         mov     x5, #VA_BITS_MIN
 301 1:
 302         adr_l   x6, vabits_actual
 303         str     x5, [x6]
 304         dmb     sy
 305         dc      ivac, x6                // Invalidate potentially stale cache line
 306
 307         /*
 308          * VA_BITS may be too small to allow for an ID mapping to be created
 309          * that covers system RAM if that is located sufficiently high in the
 310          * physical address space. So for the ID map, use an extended virtual
 311          * range in that case, and configure an additional translation level
 312          * if needed.
 313          *
 314          * Calculate the maximum allowed value for TCR_EL1.T0SZ so that the
 315          * entire ID map region can be mapped. As T0SZ == (64 - #bits used),
 316          * this number conveniently equals the number of leading zeroes in
 317          * the physical address of __idmap_text_end.
 318          */
 319         adrp    x5, __idmap_text_end
 320         clz     x5, x5
 321         cmp     x5, TCR_T0SZ(VA_BITS_MIN) // default T0SZ small enough?
 322         b.ge    1f                      // .. then skip VA range extension
 323
 324         adr_l   x6, idmap_t0sz
 325         str     x5, [x6]
 326         dmb     sy
 327         dc      ivac, x6                // Invalidate potentially stale cache line
 328
 329 #if (VA_BITS < 48)
 330 #define EXTRA_SHIFT     (PGDIR_SHIFT + PAGE_SHIFT - 3)
 331 #define EXTRA_PTRS      (1 << (PHYS_MASK_SHIFT - EXTRA_SHIFT))
 332
 333         /*
 334          * If VA_BITS < 48, we have to configure an additional table level.
 335          * First, we have to verify our assumption that the current value of
 336          * VA_BITS was chosen such that all translation levels are fully
 337          * utilised, and that lowering T0SZ will always result in an additional
 338          * translation level to be configured.
 339          */
 340 #if VA_BITS != EXTRA_SHIFT
 341 #error "Mismatch between VA_BITS and page size/number of translation levels"
 342 #endif
 343
 344         mov     x4, EXTRA_PTRS
 345         create_table_entry x0, x3, EXTRA_SHIFT, x4, x5, x6
 346 #else
 347         /*
 348          * If VA_BITS == 48, we don't have to configure an additional
 349          * translation level, but the top-level table has more entries.
 350          */
 351         mov     x4, #1 << (PHYS_MASK_SHIFT - PGDIR_SHIFT)
 352         str_l   x4, idmap_ptrs_per_pgd, x5
 353 #endif
 354 1:
 355         ldr_l   x4, idmap_ptrs_per_pgd
 356         mov     x5, x3                          // __pa(__idmap_text_start)
 357         adr_l   x6, __idmap_text_end            // __pa(__idmap_text_end)
 358
 359         map_memory x0, x1, x3, x6, x7, x3, x4, x10, x11, x12, x13, x14
 360
 361         /*
 362          * Map the kernel image (starting with PHYS_OFFSET).
 363          */
 364         adrp    x0, init_pg_dir
 365         mov_q   x5, KIMAGE_VADDR                // compile time __va(_text)
 366         add     x5, x5, x23                     // add KASLR displacement
 367         mov     x4, PTRS_PER_PGD
 368         adrp    x6, _end                        // runtime __pa(_end)
 369         adrp    x3, _text                       // runtime __pa(_text)
 370         sub     x6, x6, x3                      // _end - _text
 371         add     x6, x6, x5                      // runtime __va(_end)
 372
 373         map_memory x0, x1, x5, x6, x7, x3, x4, x10, x11, x12, x13, x14
 374
 375         /*
 376          * Since the page tables have been populated with non-cacheable
 377          * accesses (MMU disabled), invalidate those tables again to
 378          * remove any speculatively loaded cache lines.
 379          */
 380         dmb     sy
 381
 382         adrp    x0, idmap_pg_dir
 383         adrp    x1, idmap_pg_end
 384         bl      dcache_inval_poc
 385
 386         adrp    x0, init_pg_dir
 387         adrp    x1, init_pg_end
 388         bl      dcache_inval_poc
 389
 390         ret     x28
 391 SYM_FUNC_END(__create_page_tables)
 392
 393 /*
 394  * The following fragment of code is executed with the MMU enabled.
 395  *
 396  *   x0 = __PHYS_OFFSET
 397  */
 398 SYM_FUNC_START_LOCAL(__primary_switched)
 399         adrp    x4, init_thread_union
 400         add     sp, x4, #THREAD_SIZE
 401         adr_l   x5, init_task
 402         msr     sp_el0, x5                      // Save thread_info
 403
 404         adr_l   x8, vectors                     // load VBAR_EL1 with virtual
 405         msr     vbar_el1, x8                    // vector table address
 406         isb
 407
 408         stp     xzr, x30, [sp, #-16]!
 409         mov     x29, sp
 410
 411 #ifdef CONFIG_SHADOW_CALL_STACK
 412         adr_l   scs_sp, init_shadow_call_stack  // Set shadow call stack
 413 #endif
 414
 415         str_l   x21, __fdt_pointer, x5          // Save FDT pointer
 416
 417         ldr_l   x4, kimage_vaddr                // Save the offset between
 418         sub     x4, x4, x0                      // the kernel virtual and
 419         str_l   x4, kimage_voffset, x5          // physical mappings
 420
 421         // Clear BSS
 422         adr_l   x0, __bss_start
 423         mov     x1, xzr
 424         adr_l   x2, __bss_stop
 425         sub     x2, x2, x0
 426         bl      __pi_memset
 427         dsb     ishst                           // Make zero page visible to PTW
 428
 429 #if defined(CONFIG_KASAN_GENERIC) || defined(CONFIG_KASAN_SW_TAGS)
 430         bl      kasan_early_init
 431 #endif
 432         mov     x0, x21                         // pass FDT address in x0
 433         bl      early_fdt_map                   // Try mapping the FDT early
 434         bl      init_feature_override           // Parse cpu feature overrides
 435 #ifdef CONFIG_RANDOMIZE_BASE
 436         tst     x23, ~(MIN_KIMG_ALIGN - 1)      // already running randomized?
 437         b.ne    0f
 438         bl      kaslr_early_init                // parse FDT for KASLR options
 439         cbz     x0, 0f                          // KASLR disabled? just proceed
 440         orr     x23, x23, x0                    // record KASLR offset
 441         ldp     x29, x30, [sp], #16             // we must enable KASLR, return
 442         ret                                     // to __primary_switch()
 443 0:
 444 #endif
 445         bl      switch_to_vhe                   // Prefer VHE if possible
 446         add     sp, sp, #16
 447         mov     x29, #0
 448         mov     x30, #0
 449         b       start_kernel
 450 SYM_FUNC_END(__primary_switched)
 451
 452         .pushsection ".rodata", "a"
 453 SYM_DATA_START(kimage_vaddr)
 454         .quad           _text
 455 SYM_DATA_END(kimage_vaddr)
 456 EXPORT_SYMBOL(kimage_vaddr)
 457         .popsection
 458
 459 /*
 460  * end early head section, begin head code that is also used for
 461  * hotplug and needs to have the same protections as the text region
 462  */
 463         .section ".idmap.text","awx"
 464
 465 /*
 466  * Starting from EL2 or EL1, configure the CPU to execute at the highest
 467  * reachable EL supported by the kernel in a chosen default state. If dropping
 468  * from EL2 to EL1, configure EL2 before configuring EL1.
 469  *
 470  * Since we cannot always rely on ERET synchronizing writes to sysregs (e.g. if
 471  * SCTLR_ELx.EOS is clear), we place an ISB prior to ERET.
 472  *
 473  * Returns either BOOT_CPU_MODE_EL1 or BOOT_CPU_MODE_EL2 in w0 if
 474  * booted in EL1 or EL2 respectively.
 475  */
 476 SYM_FUNC_START(init_kernel_el)
 477         mrs     x0, CurrentEL
 478         cmp     x0, #CurrentEL_EL2
 479         b.eq    init_el2
 480
 481 SYM_INNER_LABEL(init_el1, SYM_L_LOCAL)
 482         mov_q   x0, INIT_SCTLR_EL1_MMU_OFF
 483         msr     sctlr_el1, x0
 484         isb
 485         mov_q   x0, INIT_PSTATE_EL1
 486         msr     spsr_el1, x0
 487         msr     elr_el1, lr
 488         mov     w0, #BOOT_CPU_MODE_EL1
 489         eret
 490
 491 SYM_INNER_LABEL(init_el2, SYM_L_LOCAL)
 492         mov_q   x0, HCR_HOST_NVHE_FLAGS
 493         msr     hcr_el2, x0
 494         isb
 495
 496         init_el2_state
 497
 498         /* Hypervisor stub */
 499         adr_l   x0, __hyp_stub_vectors
 500         msr     vbar_el2, x0
 501         isb
 502
 503         /*
 504          * Fruity CPUs seem to have HCR_EL2.E2H set to RES1,
 505          * making it impossible to start in nVHE mode. Is that
 506          * compliant with the architecture? Absolutely not!
 507          */
 508         mrs     x0, hcr_el2
 509         and     x0, x0, #HCR_E2H
 510         cbz     x0, 1f
 511
 512         /* Switching to VHE requires a sane SCTLR_EL1 as a start */
 513         mov_q   x0, INIT_SCTLR_EL1_MMU_OFF
 514         msr_s   SYS_SCTLR_EL12, x0
 515
 516         /*
 517          * Force an eret into a helper "function", and let it return
 518          * to our original caller... This makes sure that we have
 519          * initialised the basic PSTATE state.
 520          */
 521         mov     x0, #INIT_PSTATE_EL2
 522         msr     spsr_el1, x0
 523         adr     x0, __cpu_stick_to_vhe
 524         msr     elr_el1, x0
 525         eret
 526
 527 1:
 528         mov_q   x0, INIT_SCTLR_EL1_MMU_OFF
 529         msr     sctlr_el1, x0
 530
 531         msr     elr_el2, lr
 532         mov     w0, #BOOT_CPU_MODE_EL2
 533         eret
 534
 535 __cpu_stick_to_vhe:
 536         mov     x0, #HVC_VHE_RESTART
 537         hvc     #0
 538         mov     x0, #BOOT_CPU_MODE_EL2
 539         ret
 540 SYM_FUNC_END(init_kernel_el)
 541
 542 /*
 543  * Sets the __boot_cpu_mode flag depending on the CPU boot mode passed
 544  * in w0. See arch/arm64/include/asm/virt.h for more info.
 545  */
 546 SYM_FUNC_START_LOCAL(set_cpu_boot_mode_flag)
 547         adr_l   x1, __boot_cpu_mode
 548         cmp     w0, #BOOT_CPU_MODE_EL2
 549         b.ne    1f
 550         add     x1, x1, #4
 551 1:      str     w0, [x1]                        // This CPU has booted in EL1
 552         dmb     sy
 553         dc      ivac, x1                        // Invalidate potentially stale cache line
 554         ret
 555 SYM_FUNC_END(set_cpu_boot_mode_flag)
 556
 557 /*
 558  * These values are written with the MMU off, but read with the MMU on.
 559  * Writers will invalidate the corresponding address, discarding up to a
 560  * 'Cache Writeback Granule' (CWG) worth of data. The linker script ensures
 561  * sufficient alignment that the CWG doesn't overlap another section.
 562  */
 563         .pushsection ".mmuoff.data.write", "aw"
 564 /*
 565  * We need to find out the CPU boot mode long after boot, so we need to
 566  * store it in a writable variable.
 567  *
 568  * This is not in .bss, because we set it sufficiently early that the boot-time
 569  * zeroing of .bss would clobber it.
 570  */
 571 SYM_DATA_START(__boot_cpu_mode)
 572         .long   BOOT_CPU_MODE_EL2
 573         .long   BOOT_CPU_MODE_EL1
 574 SYM_DATA_END(__boot_cpu_mode)
 575 /*
 576  * The booting CPU updates the failed status @__early_cpu_boot_status,
 577  * with MMU turned off.
 578  */
 579 SYM_DATA_START(__early_cpu_boot_status)
 580         .quad   0
 581 SYM_DATA_END(__early_cpu_boot_status)
 582
 583         .popsection
 584
 585         /*
 586          * This provides a "holding pen" for platforms to hold all secondary
 587          * cores are held until we're ready for them to initialise.
 588          */
 589 SYM_FUNC_START(secondary_holding_pen)
 590         bl      init_kernel_el                  // w0=cpu_boot_mode
 591         bl      set_cpu_boot_mode_flag
 592         mrs     x0, mpidr_el1
 593         mov_q   x1, MPIDR_HWID_BITMASK
 594         and     x0, x0, x1
 595         adr_l   x3, secondary_holding_pen_release
 596 pen:    ldr     x4, [x3]
 597         cmp     x4, x0
 598         b.eq    secondary_startup
 599         wfe
 600         b       pen
 601 SYM_FUNC_END(secondary_holding_pen)
 602
 603         /*
 604          * Secondary entry point that jumps straight into the kernel. Only to
 605          * be used where CPUs are brought online dynamically by the kernel.
 606          */
 607 SYM_FUNC_START(secondary_entry)
 608         bl      init_kernel_el                  // w0=cpu_boot_mode
 609         bl      set_cpu_boot_mode_flag
 610         b       secondary_startup
 611 SYM_FUNC_END(secondary_entry)
 612
 613 SYM_FUNC_START_LOCAL(secondary_startup)
 614         /*
 615          * Common entry point for secondary CPUs.
 616          */
 617         bl      switch_to_vhe
 618         bl      __cpu_secondary_check52bitva
 619         bl      __cpu_setup                     // initialise processor
 620         adrp    x1, swapper_pg_dir
 621         bl      __enable_mmu
 622         ldr     x8, =__secondary_switched
 623         br      x8
 624 SYM_FUNC_END(secondary_startup)
 625
 626 SYM_FUNC_START_LOCAL(__secondary_switched)
 627         adr_l   x5, vectors
 628         msr     vbar_el1, x5
 629         isb
 630
 631         adr_l   x0, secondary_data
 632         ldr     x1, [x0, #CPU_BOOT_STACK]       // get secondary_data.stack
 633         cbz     x1, __secondary_too_slow
 634         mov     sp, x1
 635         ldr     x2, [x0, #CPU_BOOT_TASK]
 636         cbz     x2, __secondary_too_slow
 637         msr     sp_el0, x2
 638         scs_load x2, x3
 639         mov     x29, #0
 640         mov     x30, #0
 641
 642 #ifdef CONFIG_ARM64_PTR_AUTH
 643         ptrauth_keys_init_cpu x2, x3, x4, x5
 644 #endif
 645
 646         b       secondary_start_kernel
 647 SYM_FUNC_END(__secondary_switched)
 648
 649 SYM_FUNC_START_LOCAL(__secondary_too_slow)
 650         wfe
 651         wfi
 652         b       __secondary_too_slow
 653 SYM_FUNC_END(__secondary_too_slow)
 654
 655 /*
 656  * The booting CPU updates the failed status @__early_cpu_boot_status,
 657  * with MMU turned off.
 658  *
 659  * update_early_cpu_boot_status tmp, status
 660  *  - Corrupts tmp1, tmp2
 661  *  - Writes 'status' to __early_cpu_boot_status and makes sure
 662  *    it is committed to memory.
 663  */
 664
 665         .macro  update_early_cpu_boot_status status, tmp1, tmp2
 666         mov     \tmp2, #\status
 667         adr_l   \tmp1, __early_cpu_boot_status
 668         str     \tmp2, [\tmp1]
 669         dmb     sy
 670         dc      ivac, \tmp1                     // Invalidate potentially stale cache line
 671         .endm
 672
 673 /*
 674  * Enable the MMU.
 675  *
 676  *  x0  = SCTLR_EL1 value for turning on the MMU.
 677  *  x1  = TTBR1_EL1 value
 678  *
 679  * Returns to the caller via x30/lr. This requires the caller to be covered
 680  * by the .idmap.text section.
 681  *
 682  * Checks if the selected granule size is supported by the CPU.
 683  * If it isn't, park the CPU
 684  */
 685 SYM_FUNC_START(__enable_mmu)
 686         mrs     x2, ID_AA64MMFR0_EL1
 687         ubfx    x2, x2, #ID_AA64MMFR0_TGRAN_SHIFT, 4
 688         cmp     x2, #ID_AA64MMFR0_TGRAN_SUPPORTED_MIN
 689         b.lt    __no_granule_support
 690         cmp     x2, #ID_AA64MMFR0_TGRAN_SUPPORTED_MAX
 691         b.gt    __no_granule_support
 692         update_early_cpu_boot_status 0, x2, x3
 693         adrp    x2, idmap_pg_dir
 694         phys_to_ttbr x1, x1
 695         phys_to_ttbr x2, x2
 696         msr     ttbr0_el1, x2                   // load TTBR0
 697         offset_ttbr1 x1, x3
 698         msr     ttbr1_el1, x1                   // load TTBR1
 699         isb
 700
 701         set_sctlr_el1   x0
 702
 703         ret
 704 SYM_FUNC_END(__enable_mmu)
 705
 706 SYM_FUNC_START(__cpu_secondary_check52bitva)
 707 #ifdef CONFIG_ARM64_VA_BITS_52
 708         ldr_l   x0, vabits_actual
 709         cmp     x0, #52
 710         b.ne    2f
 711
 712         mrs_s   x0, SYS_ID_AA64MMFR2_EL1
 713         and     x0, x0, #(0xf << ID_AA64MMFR2_LVA_SHIFT)
 714         cbnz    x0, 2f
 715
 716         update_early_cpu_boot_status \
 717                 CPU_STUCK_IN_KERNEL | CPU_STUCK_REASON_52_BIT_VA, x0, x1
 718 1:      wfe
 719         wfi
 720         b       1b
 721
 722 #endif
 723 2:      ret
 724 SYM_FUNC_END(__cpu_secondary_check52bitva)
 725
 726 SYM_FUNC_START_LOCAL(__no_granule_support)
 727         /* Indicate that this CPU can't boot and is stuck in the kernel */
 728         update_early_cpu_boot_status \
 729                 CPU_STUCK_IN_KERNEL | CPU_STUCK_REASON_NO_GRAN, x1, x2
 730 1:
 731         wfe
 732         wfi
 733         b       1b
 734 SYM_FUNC_END(__no_granule_support)
 735
 736 #ifdef CONFIG_RELOCATABLE
 737 SYM_FUNC_START_LOCAL(__relocate_kernel)
 738         /*
 739          * Iterate over each entry in the relocation table, and apply the
 740          * relocations in place.
 741          */
 742         ldr     w9, =__rela_offset              // offset to reloc table
 743         ldr     w10, =__rela_size               // size of reloc table
 744
 745         mov_q   x11, KIMAGE_VADDR               // default virtual offset
 746         add     x11, x11, x23                   // actual virtual offset
 747         add     x9, x9, x11                     // __va(.rela)
 748         add     x10, x9, x10                    // __va(.rela) + sizeof(.rela)
 749
 750 0:      cmp     x9, x10
 751         b.hs    1f
 752         ldp     x12, x13, [x9], #24
 753         ldr     x14, [x9, #-8]
 754         cmp     w13, #R_AARCH64_RELATIVE
 755         b.ne    0b
 756         add     x14, x14, x23                   // relocate
 757         str     x14, [x12, x23]
 758         b       0b
 759
 760 1:
 761 #ifdef CONFIG_RELR
 762         /*
 763          * Apply RELR relocations.
 764          *
 765          * RELR is a compressed format for storing relative relocations. The
 766          * encoded sequence of entries looks like:
 767          * [ AAAAAAAA BBBBBBB1 BBBBBBB1 ... AAAAAAAA BBBBBB1 ... ]
 768          *
 769          * i.e. start with an address, followed by any number of bitmaps. The
 770          * address entry encodes 1 relocation. The subsequent bitmap entries
 771          * encode up to 63 relocations each, at subsequent offsets following
 772          * the last address entry.
 773          *
 774          * The bitmap entries must have 1 in the least significant bit. The
 775          * assumption here is that an address cannot have 1 in lsb. Odd
 776          * addresses are not supported. Any odd addresses are stored in the RELA
 777          * section, which is handled above.
 778          *
 779          * Excluding the least significant bit in the bitmap, each non-zero
 780          * bit in the bitmap represents a relocation to be applied to
 781          * a corresponding machine word that follows the base address
 782          * word. The second least significant bit represents the machine
 783          * word immediately following the initial address, and each bit
 784          * that follows represents the next word, in linear order. As such,
 785          * a single bitmap can encode up to 63 relocations in a 64-bit object.
 786          *
 787          * In this implementation we store the address of the next RELR table
 788          * entry in x9, the address being relocated by the current address or
 789          * bitmap entry in x13 and the address being relocated by the current
 790          * bit in x14.
 791          *
 792          * Because addends are stored in place in the binary, RELR relocations
 793          * cannot be applied idempotently. We use x24 to keep track of the
 794          * currently applied displacement so that we can correctly relocate if
 795          * __relocate_kernel is called twice with non-zero displacements (i.e.
 796          * if there is both a physical misalignment and a KASLR displacement).
 797          */
 798         ldr     w9, =__relr_offset              // offset to reloc table
 799         ldr     w10, =__relr_size               // size of reloc table
 800         add     x9, x9, x11                     // __va(.relr)
 801         add     x10, x9, x10                    // __va(.relr) + sizeof(.relr)
 802
 803         sub     x15, x23, x24                   // delta from previous offset
 804         cbz     x15, 7f                         // nothing to do if unchanged
 805         mov     x24, x23                        // save new offset
 806
 807 2:      cmp     x9, x10
 808         b.hs    7f
 809         ldr     x11, [x9], #8
 810         tbnz    x11, #0, 3f                     // branch to handle bitmaps
 811         add     x13, x11, x23
 812         ldr     x12, [x13]                      // relocate address entry
 813         add     x12, x12, x15
 814         str     x12, [x13], #8                  // adjust to start of bitmap
 815         b       2b
 816
 817 3:      mov     x14, x13
 818 4:      lsr     x11, x11, #1
 819         cbz     x11, 6f
 820         tbz     x11, #0, 5f                     // skip bit if not set
 821         ldr     x12, [x14]                      // relocate bit
 822         add     x12, x12, x15
 823         str     x12, [x14]
 824
 825 5:      add     x14, x14, #8                    // move to next bit's address
 826         b       4b
 827
 828 6:      /*
 829          * Move to the next bitmap's address. 8 is the word size, and 63 is the
 830          * number of significant bits in a bitmap entry.
 831          */
 832         add     x13, x13, #(8 * 63)
 833         b       2b
 834
 835 7:
 836 #endif
 837         ret
 838
 839 SYM_FUNC_END(__relocate_kernel)
 840 #endif
 841
 842 SYM_FUNC_START_LOCAL(__primary_switch)
 843 #ifdef CONFIG_RANDOMIZE_BASE
 844         mov     x19, x0                         // preserve new SCTLR_EL1 value
 845         mrs     x20, sctlr_el1                  // preserve old SCTLR_EL1 value
 846 #endif
 847
 848         adrp    x1, init_pg_dir
 849         bl      __enable_mmu
 850 #ifdef CONFIG_RELOCATABLE
 851 #ifdef CONFIG_RELR
 852         mov     x24, #0                         // no RELR displacement yet
 853 #endif
 854         bl      __relocate_kernel
 855 #ifdef CONFIG_RANDOMIZE_BASE
 856         ldr     x8, =__primary_switched
 857         adrp    x0, __PHYS_OFFSET
 858         blr     x8
 859
 860         /*
 861          * If we return here, we have a KASLR displacement in x23 which we need
 862          * to take into account by discarding the current kernel mapping and
 863          * creating a new one.
 864          */
 865         pre_disable_mmu_workaround
 866         msr     sctlr_el1, x20                  // disable the MMU
 867         isb
 868         bl      __create_page_tables            // recreate kernel mapping
 869
 870         tlbi    vmalle1                         // Remove any stale TLB entries
 871         dsb     nsh
 872         isb
 873
 874         set_sctlr_el1   x19                     // re-enable the MMU
 875
 876         bl      __relocate_kernel
 877 #endif
 878 #endif
 879         ldr     x8, =__primary_switched
 880         adrp    x0, __PHYS_OFFSET
 881         br      x8
 882 SYM_FUNC_END(__primary_switch)