scripts/ver_linux

   1 #!/usr/bin/awk -f
   2 # SPDX-License-Identifier: GPL-2.0
   3 # Before running this script please ensure that your PATH is
   4 # typical as you use for compilation/installation. I use
   5 # /bin /sbin /usr/bin /usr/sbin /usr/local/bin, but it may
   6 # differ on your system.
   7
   8 BEGIN {
   9         usage = "If some fields are empty or look unusual you may have an old version.\n"
  10         usage = usage "Compare to the current minimal requirements in Documentation/Changes.\n"
  11         print usage
  12
  13         system("uname -a")
  14         printf("\n")
  15
  16         vernum = "[0-9]+([.]?[0-9]+)+"
  17         libc = "libc[.]so[.][0-9]+$"
  18         libcpp = "(libg|stdc)[+]+[.]so[.][0-9]+$"
  19
  20         printversion("GNU C", version("gcc -dumpversion"))
  21         printversion("GNU Make", version("make --version"))
  22         printversion("Binutils", version("ld -v"))
  23         printversion("Util-linux", version("mount --version"))
  24         printversion("Mount", version("mount --version"))
  25         printversion("Module-init-tools", version("depmod -V"))
  26         printversion("E2fsprogs", version("tune2fs"))
  27         printversion("Jfsutils", version("fsck.jfs -V"))
  28         printversion("Reiserfsprogs", version("reiserfsck -V"))
  29         printversion("Reiser4fsprogs", version("fsck.reiser4 -V"))
  30         printversion("Xfsprogs", version("xfs_db -V"))
  31         printversion("Pcmciautils", version("pccardctl -V"))
  32         printversion("Pcmcia-cs", version("cardmgr -V"))
  33         printversion("Quota-tools", version("quota -V"))
  34         printversion("PPP", version("pppd --version"))
  35         printversion("Isdn4k-utils", version("isdnctrl"))
  36         printversion("Nfs-utils", version("showmount --version"))
  37         printversion("Bison", version("bison --version"))
  38         printversion("Flex", version("flex --version"))
  39
  40         while ("ldconfig -p 2>/dev/null" | getline > 0) {
  41                 if ($NF ~ libc && !seen[ver = version("readlink " $NF)]++)
  42                         printversion("Linux C Library", ver)
  43                 else if ($NF ~ libcpp && !seen[ver = version("readlink " $NF)]++)
  44                         printversion("Linux C++ Library", ver)
  45         }
  46
  47         printversion("Dynamic linker (ldd)", version("ldd --version"))
  48         printversion("Procps", version("ps --version"))
  49         printversion("Net-tools", version("ifconfig --version"))
  50         printversion("Kbd", version("loadkeys -V"))
  51         printversion("Console-tools", version("loadkeys -V"))
  52         printversion("Oprofile", version("oprofiled --version"))
  53         printversion("Sh-utils", version("expr --v"))
  54         printversion("Udev", version("udevadm --version"))
  55         printversion("Wireless-tools", version("iwconfig --version"))
  56
  57         while ("sort /proc/modules" | getline > 0) {
  58                 mods = mods sep $1
  59                 sep = " "
  60         }
  61         printversion("Modules Loaded", mods)
  62 }
  63
  64 function version(cmd,    ver) {
  65         cmd = cmd " 2>&1"
  66         while (cmd | getline > 0) {
  67                 if (match($0, vernum)) {
  68                         ver = substr($0, RSTART, RLENGTH)
  69                         break
  70                 }
  71         }
  72         close(cmd)
  73         return ver
  74 }
  75
  76 function printversion(name, value,  ofmt) {
  77         if (value != "") {
  78                 ofmt = "%-20s\t%s\n"
  79                 printf(ofmt, name, value)
  80         }
  81 }