arch/arc/kernel/entry.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  * Common Low Level Interrupts/Traps/Exceptions(non-TLB) Handling for ARC
   4  * (included from entry-<isa>.S
   5  *
   6  * Copyright (C) 2014-15 Synopsys, Inc. (www.synopsys.com)
   7  * Copyright (C) 2004, 2007-2010, 2011-2012 Synopsys, Inc. (www.synopsys.com)
   8  */
   9
  10 /*------------------------------------------------------------------
  11  *    Function                            ABI
  12  *------------------------------------------------------------------
  13  *
  14  *  Arguments                           r0 - r7
  15  *  Caller Saved Registers              r0 - r12
  16  *  Callee Saved Registers              r13- r25
  17  *  Global Pointer (gp)                 r26
  18  *  Frame Pointer (fp)                  r27
  19  *  Stack Pointer (sp)                  r28
  20  *  Branch link register (blink)        r31
  21  *------------------------------------------------------------------
  22  */
  23
  24 ;################### Special Sys Call Wrappers ##########################
  25
  26 ENTRY(sys_clone_wrapper)
  27         SAVE_CALLEE_SAVED_USER
  28         bl  @sys_clone
  29         DISCARD_CALLEE_SAVED_USER
  30
  31         GET_CURR_THR_INFO_FLAGS   r10
  32         btst r10, TIF_SYSCALL_TRACE
  33         bnz  tracesys_exit
  34
  35         b .Lret_from_system_call
  36 END(sys_clone_wrapper)
  37
  38 ENTRY(sys_clone3_wrapper)
  39         SAVE_CALLEE_SAVED_USER
  40         bl  @sys_clone3
  41         DISCARD_CALLEE_SAVED_USER
  42
  43         GET_CURR_THR_INFO_FLAGS   r10
  44         btst r10, TIF_SYSCALL_TRACE
  45         bnz  tracesys_exit
  46
  47         b .Lret_from_system_call
  48 END(sys_clone3_wrapper)
  49
  50 ENTRY(ret_from_fork)
  51         ; when the forked child comes here from the __switch_to function
  52         ; r0 has the last task pointer.
  53         ; put last task in scheduler queue
  54         jl   @schedule_tail
  55
  56         ld   r9, [sp, PT_status32]
  57         brne r9, 0, 1f
  58
  59         jl.d [r14]              ; kernel thread entry point
  60         mov  r0, r13            ; (see PF_KTHREAD block in copy_thread)
  61
  62 1:
  63         ; Return to user space
  64         ; 1. Any forked task (Reach here via BRne above)
  65         ; 2. First ever init task (Reach here via return from JL above)
  66         ;    This is the historic "kernel_execve" use-case, to return to init
  67         ;    user mode, in a round about way since that is always done from
  68         ;    a kernel thread which is executed via JL above but always returns
  69         ;    out whenever kernel_execve (now inline do_fork()) is involved
  70         b    ret_from_exception
  71 END(ret_from_fork)
  72
  73 ;################### Non TLB Exception Handling #############################
  74
  75 ; ---------------------------------------------
  76 ; Instruction Error Exception Handler
  77 ; ---------------------------------------------
  78
  79 ENTRY(instr_service)
  80
  81         EXCEPTION_PROLOGUE
  82
  83         lr  r0, [efa]
  84         mov r1, sp
  85
  86         FAKE_RET_FROM_EXCPN
  87
  88         bl  do_insterror_or_kprobe
  89         b   ret_from_exception
  90 END(instr_service)
  91
  92 ; ---------------------------------------------
  93 ; Machine Check Exception Handler
  94 ; ---------------------------------------------
  95
  96 ENTRY(EV_MachineCheck)
  97
  98         EXCEPTION_PROLOGUE
  99
 100         lr  r2, [ecr]
 101         lr  r0, [efa]
 102         mov r1, sp
 103
 104         ; MC excpetions disable MMU
 105         ARC_MMU_REENABLE r3
 106
 107         lsr     r3, r2, 8
 108         bmsk    r3, r3, 7
 109         brne    r3, ECR_C_MCHK_DUP_TLB, 1f
 110
 111         bl      do_tlb_overlap_fault
 112         b       ret_from_exception
 113
 114 1:
 115         ; DEAD END: can't do much, display Regs and HALT
 116         SAVE_CALLEE_SAVED_USER
 117
 118         GET_CURR_TASK_FIELD_PTR   TASK_THREAD, r10
 119         st  sp, [r10, THREAD_CALLEE_REG]
 120
 121         j  do_machine_check_fault
 122
 123 END(EV_MachineCheck)
 124
 125 ; ---------------------------------------------
 126 ; Privilege Violation Exception Handler
 127 ; ---------------------------------------------
 128 ENTRY(EV_PrivilegeV)
 129
 130         EXCEPTION_PROLOGUE
 131
 132         lr  r0, [efa]
 133         mov r1, sp
 134
 135         FAKE_RET_FROM_EXCPN
 136
 137         bl  do_privilege_fault
 138         b   ret_from_exception
 139 END(EV_PrivilegeV)
 140
 141 ; ---------------------------------------------
 142 ; Extension Instruction Exception Handler
 143 ; ---------------------------------------------
 144 ENTRY(EV_Extension)
 145
 146         EXCEPTION_PROLOGUE
 147
 148         lr  r0, [efa]
 149         mov r1, sp
 150
 151         FAKE_RET_FROM_EXCPN
 152
 153         bl  do_extension_fault
 154         b   ret_from_exception
 155 END(EV_Extension)
 156
 157 ;################ Trap Handling (Syscall, Breakpoint) ##################
 158
 159 ; ---------------------------------------------
 160 ; syscall Tracing
 161 ; ---------------------------------------------
 162 tracesys:
 163         ; save EFA in case tracer wants the PC of traced task
 164         ; using ERET won't work since next-PC has already committed
 165         GET_CURR_TASK_FIELD_PTR   TASK_THREAD, r11
 166         st  r12, [r11, THREAD_FAULT_ADDR]       ; thread.fault_address
 167
 168         ; PRE Sys Call Ptrace hook
 169         mov r0, sp                      ; pt_regs needed
 170         bl  @syscall_trace_entry
 171
 172         ; Tracing code now returns the syscall num (orig or modif)
 173         mov r8, r0
 174
 175         ; Do the Sys Call as we normally would.
 176         ; Validate the Sys Call number
 177         cmp     r8,  NR_syscalls - 1
 178         mov.hi  r0, -ENOSYS
 179         bhi     tracesys_exit
 180
 181         ; Restore the sys-call args. Mere invocation of the hook abv could have
 182         ; clobbered them (since they are in scratch regs). The tracer could also
 183         ; have deliberately changed the syscall args: r0-r7
 184         ld  r0, [sp, PT_r0]
 185         ld  r1, [sp, PT_r1]
 186         ld  r2, [sp, PT_r2]
 187         ld  r3, [sp, PT_r3]
 188         ld  r4, [sp, PT_r4]
 189         ld  r5, [sp, PT_r5]
 190         ld  r6, [sp, PT_r6]
 191         ld  r7, [sp, PT_r7]
 192         ld.as   r9, [sys_call_table, r8]
 193         jl      [r9]        ; Entry into Sys Call Handler
 194
 195 tracesys_exit:
 196         st  r0, [sp, PT_r0]     ; sys call return value in pt_regs
 197
 198         ;POST Sys Call Ptrace Hook
 199         bl  @syscall_trace_exit
 200         b   ret_from_exception ; NOT ret_from_system_call at is saves r0 which
 201         ; we'd done before calling post hook above
 202
 203 ; ---------------------------------------------
 204 ; Breakpoint TRAP
 205 ; ---------------------------------------------
 206 trap_with_param:
 207         mov r0, r12     ; EFA in case ptracer/gdb wants stop_pc
 208         mov r1, sp
 209
 210         ; Save callee regs in case gdb wants to have a look
 211         ; SP will grow up by size of CALLEE Reg-File
 212         ; NOTE: clobbers r12
 213         SAVE_CALLEE_SAVED_USER
 214
 215         ; save location of saved Callee Regs @ thread_struct->pc
 216         GET_CURR_TASK_FIELD_PTR   TASK_THREAD, r10
 217         st  sp, [r10, THREAD_CALLEE_REG]
 218
 219         ; Call the trap handler
 220         bl  do_non_swi_trap
 221
 222         ; unwind stack to discard Callee saved Regs
 223         DISCARD_CALLEE_SAVED_USER
 224
 225         b   ret_from_exception
 226
 227 ; ---------------------------------------------
 228 ; syscall TRAP
 229 ; ABI: (r0-r7) upto 8 args, (r8) syscall number
 230 ; ---------------------------------------------
 231
 232 ENTRY(EV_Trap)
 233
 234         EXCEPTION_PROLOGUE
 235
 236         lr  r12, [efa]
 237
 238         FAKE_RET_FROM_EXCPN
 239
 240         ;============ TRAP 1   :breakpoints
 241         ; Check ECR for trap with arg (PROLOGUE ensures r10 has ECR)
 242         bmsk.f 0, r10, 7
 243         bnz    trap_with_param
 244
 245         ;============ TRAP  (no param): syscall top level
 246
 247         ; If syscall tracing ongoing, invoke pre-post-hooks
 248         GET_CURR_THR_INFO_FLAGS   r10
 249         btst r10, TIF_SYSCALL_TRACE
 250         bnz tracesys  ; this never comes back
 251
 252         ;============ Normal syscall case
 253
 254         ; syscall num shd not exceed the total system calls avail
 255         cmp     r8,  NR_syscalls - 1
 256         mov.hi  r0, -ENOSYS
 257         bhi     .Lret_from_system_call
 258
 259         ; Offset into the syscall_table and call handler
 260         ld.as   r9,[sys_call_table, r8]
 261         jl      [r9]        ; Entry into Sys Call Handler
 262
 263 .Lret_from_system_call:
 264
 265         st  r0, [sp, PT_r0]     ; sys call return value in pt_regs
 266
 267         ; fall through to ret_from_exception
 268 END(EV_Trap)
 269
 270 ;############# Return from Intr/Excp/Trap (Linux Specifics) ##############
 271 ;
 272 ; If ret to user mode do we need to handle signals, schedule() et al.
 273
 274 ENTRY(ret_from_exception)
 275
 276         ; Pre-{IRQ,Trap,Exception} K/U mode from pt_regs->status32
 277         ld  r8, [sp, PT_status32]   ; returning to User/Kernel Mode
 278
 279         bbit0  r8, STATUS_U_BIT, resume_kernel_mode
 280
 281         ; Before returning to User mode check-for-and-complete any pending work
 282         ; such as rescheduling/signal-delivery etc.
 283 resume_user_mode_begin:
 284
 285         ; Disable IRQs to ensures that chk for pending work itself is atomic
 286         ; (and we don't end up missing a NEED_RESCHED/SIGPENDING due to an
 287         ; interim IRQ).
 288         IRQ_DISABLE     r10
 289
 290         ; Fast Path return to user mode if no pending work
 291         GET_CURR_THR_INFO_FLAGS   r9
 292         and.f  0,  r9, _TIF_WORK_MASK
 293         bz     .Lrestore_regs
 294
 295         ; --- (Slow Path #1) task preemption ---
 296         bbit0  r9, TIF_NEED_RESCHED, .Lchk_pend_signals
 297         mov    blink, resume_user_mode_begin  ; tail-call to U mode ret chks
 298         j      @schedule        ; BTST+Bnz causes relo error in link
 299
 300 .Lchk_pend_signals:
 301         IRQ_ENABLE      r10
 302
 303         ; --- (Slow Path #2) pending signal  ---
 304         mov r0, sp      ; pt_regs for arg to do_signal()/do_notify_resume()
 305
 306         GET_CURR_THR_INFO_FLAGS   r9
 307         and.f  0,  r9, _TIF_SIGPENDING|_TIF_NOTIFY_SIGNAL
 308         bz .Lchk_notify_resume
 309
 310         ; Normal Trap/IRQ entry only saves Scratch (caller-saved) regs
 311         ; in pt_reg since the "C" ABI (kernel code) will automatically
 312         ; save/restore callee-saved regs.
 313         ;
 314         ; However, here we need to explicitly save callee regs because
 315         ; (i)  If this signal causes coredump - full regfile needed
 316         ; (ii) If signal is SIGTRAP/SIGSTOP, task is being traced thus
 317         ;      tracer might call PEEKUSR(CALLEE reg)
 318         ;
 319         ; NOTE: SP will grow up by size of CALLEE Reg-File
 320         SAVE_CALLEE_SAVED_USER          ; clobbers r12
 321
 322         ; save location of saved Callee Regs @ thread_struct->callee
 323         GET_CURR_TASK_FIELD_PTR   TASK_THREAD, r10
 324         st  sp, [r10, THREAD_CALLEE_REG]
 325
 326         bl  @do_signal
 327
 328         ; Ideally we want to discard the Callee reg above, however if this was
 329         ; a tracing signal, tracer could have done a POKEUSR(CALLEE reg)
 330         RESTORE_CALLEE_SAVED_USER
 331
 332         b      resume_user_mode_begin   ; loop back to start of U mode ret
 333
 334         ; --- (Slow Path #3) notify_resume ---
 335 .Lchk_notify_resume:
 336         btst   r9, TIF_NOTIFY_RESUME
 337         blnz   @do_notify_resume
 338         b      resume_user_mode_begin   ; unconditionally back to U mode ret chks
 339                                         ; for single exit point from this block
 340
 341 resume_kernel_mode:
 342
 343         ; Disable Interrupts from this point on
 344         ; CONFIG_PREEMPTION: This is a must for preempt_schedule_irq()
 345         ; !CONFIG_PREEMPTION: To ensure restore_regs is intr safe
 346         IRQ_DISABLE     r9
 347
 348 #ifdef CONFIG_PREEMPTION
 349
 350         ; Can't preempt if preemption disabled
 351         GET_CURR_THR_INFO_FROM_SP   r10
 352         ld  r8, [r10, THREAD_INFO_PREEMPT_COUNT]
 353         brne  r8, 0, .Lrestore_regs
 354
 355         ; check if this task's NEED_RESCHED flag set
 356         ld  r9, [r10, THREAD_INFO_FLAGS]
 357         bbit0  r9, TIF_NEED_RESCHED, .Lrestore_regs
 358
 359         ; Invoke PREEMPTION
 360         jl      preempt_schedule_irq
 361
 362         ; preempt_schedule_irq() always returns with IRQ disabled
 363 #endif
 364
 365         b       .Lrestore_regs
 366
 367 ##### DONT ADD CODE HERE - .Lrestore_regs actually follows in entry-<isa>.S
 368