tools/memory-model/linux-kernel.cat

   1 // SPDX-License-Identifier: GPL-2.0+
   2 (*
   3  * Copyright (C) 2015 Jade Alglave <j.alglave@ucl.ac.uk>,
   4  * Copyright (C) 2016 Luc Maranget <luc.maranget@inria.fr> for Inria
   5  * Copyright (C) 2017 Alan Stern <stern@rowland.harvard.edu>,
   6  *                    Andrea Parri <parri.andrea@gmail.com>
   7  *
   8  * An earlier version of this file appeared in the companion webpage for
   9  * "Frightening small children and disconcerting grown-ups: Concurrency
  10  * in the Linux kernel" by Alglave, Maranget, McKenney, Parri, and Stern,
  11  * which appeared in ASPLOS 2018.
  12  *)
  13
  14 "Linux-kernel memory consistency model"
  15
  16 (*
  17  * File "lock.cat" handles locks and is experimental.
  18  * It can be replaced by include "cos.cat" for tests that do not use locks.
  19  *)
  20
  21 include "lock.cat"
  22
  23 (*******************)
  24 (* Basic relations *)
  25 (*******************)
  26
  27 (* Fences *)
  28 let rmb = [R \ Noreturn] ; fencerel(Rmb) ; [R \ Noreturn]
  29 let wmb = [W] ; fencerel(Wmb) ; [W]
  30 let mb = ([M] ; fencerel(Mb) ; [M]) |
  31         ([M] ; fencerel(Before-atomic) ; [RMW] ; po? ; [M]) |
  32         ([M] ; po? ; [RMW] ; fencerel(After-atomic) ; [M]) |
  33         ([M] ; po? ; [LKW] ; fencerel(After-spinlock) ; [M]) |
  34         ([M] ; po ; [UL] ; (co | po) ; [LKW] ;
  35                 fencerel(After-unlock-lock) ; [M])
  36 let gp = po ; [Sync-rcu] ; po?
  37
  38 let strong-fence = mb | gp
  39
  40 (* Release Acquire *)
  41 let acq-po = [Acquire] ; po ; [M]
  42 let po-rel = [M] ; po ; [Release]
  43 let po-unlock-rf-lock-po = po ; [UL] ; rf ; [LKR] ; po
  44
  45 (**********************************)
  46 (* Fundamental coherence ordering *)
  47 (**********************************)
  48
  49 (* Sequential Consistency Per Variable *)
  50 let com = rf | co | fr
  51 acyclic po-loc | com as coherence
  52
  53 (* Atomic Read-Modify-Write *)
  54 empty rmw & (fre ; coe) as atomic
  55
  56 (**********************************)
  57 (* Instruction execution ordering *)
  58 (**********************************)
  59
  60 (* Preserved Program Order *)
  61 let dep = addr | data
  62 let rwdep = (dep | ctrl) ; [W]
  63 let overwrite = co | fr
  64 let to-w = rwdep | (overwrite & int)
  65 let to-r = addr | (dep ; rfi)
  66 let fence = strong-fence | wmb | po-rel | rmb | acq-po
  67 let ppo = to-r | to-w | fence | (po-unlock-rf-lock-po & int)
  68
  69 (* Propagation: Ordering from release operations and strong fences. *)
  70 let A-cumul(r) = rfe? ; r
  71 let cumul-fence = A-cumul(strong-fence | po-rel) | wmb | po-unlock-rf-lock-po
  72 let prop = (overwrite & ext)? ; cumul-fence* ; rfe?
  73
  74 (*
  75  * Happens Before: Ordering from the passage of time.
  76  * No fences needed here for prop because relation confined to one process.
  77  *)
  78 let hb = ppo | rfe | ((prop \ id) & int)
  79 acyclic hb as happens-before
  80
  81 (****************************************)
  82 (* Write and fence propagation ordering *)
  83 (****************************************)
  84
  85 (* Propagation: Each non-rf link needs a strong fence. *)
  86 let pb = prop ; strong-fence ; hb*
  87 acyclic pb as propagation
  88
  89 (*******)
  90 (* RCU *)
  91 (*******)
  92
  93 (*
  94  * Effect of read-side critical section proceeds from the rcu_read_lock()
  95  * onward on the one hand and from the rcu_read_unlock() backwards on the
  96  * other hand.
  97  *)
  98 let rscs = po ; crit^-1 ; po?
  99
 100 (*
 101  * The synchronize_rcu() strong fence is special in that it can order not
 102  * one but two non-rf relations, but only in conjunction with an RCU
 103  * read-side critical section.
 104  *)
 105 let rcu-link = hb* ; pb* ; prop
 106
 107 (*
 108  * Any sequence containing at least as many grace periods as RCU read-side
 109  * critical sections (joined by rcu-link) acts as a generalized strong fence.
 110  *)
 111 let rec rcu-fence = gp |
 112         (gp ; rcu-link ; rscs) |
 113         (rscs ; rcu-link ; gp) |
 114         (gp ; rcu-link ; rcu-fence ; rcu-link ; rscs) |
 115         (rscs ; rcu-link ; rcu-fence ; rcu-link ; gp) |
 116         (rcu-fence ; rcu-link ; rcu-fence)
 117
 118 (* rb orders instructions just as pb does *)
 119 let rb = prop ; rcu-fence ; hb* ; pb*
 120
 121 irreflexive rb as rcu
 122
 123 (*
 124  * The happens-before, propagation, and rcu constraints are all
 125  * expressions of temporal ordering.  They could be replaced by
 126  * a single constraint on an "executes-before" relation, xb:
 127  *
 128  * let xb = hb | pb | rb
 129  * acyclic xb as executes-before
 130  *)