include/asm-generic/vmlinux.lds.h

   1 /*
   2  * Helper macros to support writing architecture specific
   3  * linker scripts.
   4  *
   5  * A minimal linker scripts has following content:
   6  * [This is a sample, architectures may have special requiriements]
   7  *
   8  * OUTPUT_FORMAT(...)
   9  * OUTPUT_ARCH(...)
  10  * ENTRY(...)
  11  * SECTIONS
  12  * {
  13  *      . = START;
  14  *      __init_begin = .;
  15  *      HEAD_TEXT_SECTION
  16  *      INIT_TEXT_SECTION(PAGE_SIZE)
  17  *      INIT_DATA_SECTION(...)
  18  *      PERCPU_SECTION(CACHELINE_SIZE)
  19  *      __init_end = .;
  20  *
  21  *      _stext = .;
  22  *      TEXT_SECTION = 0
  23  *      _etext = .;
  24  *
  25  *      _sdata = .;
  26  *      RO_DATA_SECTION(PAGE_SIZE)
  27  *      RW_DATA_SECTION(...)
  28  *      _edata = .;
  29  *
  30  *      EXCEPTION_TABLE(...)
  31  *      NOTES
  32  *
  33  *      BSS_SECTION(0, 0, 0)
  34  *      _end = .;
  35  *
  36  *      STABS_DEBUG
  37  *      DWARF_DEBUG
  38  *
  39  *      DISCARDS                // must be the last
  40  * }
  41  *
  42  * [__init_begin, __init_end] is the init section that may be freed after init
  43  *      // __init_begin and __init_end should be page aligned, so that we can
  44  *      // free the whole .init memory
  45  * [_stext, _etext] is the text section
  46  * [_sdata, _edata] is the data section
  47  *
  48  * Some of the included output section have their own set of constants.
  49  * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
  50  *               [__nosave_begin, __nosave_end] for the nosave data
  51  */
  52
  53 #ifndef LOAD_OFFSET
  54 #define LOAD_OFFSET 0
  55 #endif
  56
  57 /* Align . to a 8 byte boundary equals to maximum function alignment. */
  58 #define ALIGN_FUNCTION()  . = ALIGN(8)
  59
  60 /*
  61  * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
  62  * generates .data.identifier sections, which need to be pulled in with
  63  * .data. We don't want to pull in .data..other sections, which Linux
  64  * has defined. Same for text and bss.
  65  *
  66  * RODATA_MAIN is not used because existing code already defines .rodata.x
  67  * sections to be brought in with rodata.
  68  */
  69 #ifdef CONFIG_LD_DEAD_CODE_DATA_ELIMINATION
  70 #define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
  71 #define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data..LPBX*
  72 #define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
  73 #define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]*
  74 #define BSS_MAIN .bss .bss.[0-9a-zA-Z_]*
  75 #define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
  76 #else
  77 #define TEXT_MAIN .text
  78 #define DATA_MAIN .data
  79 #define SDATA_MAIN .sdata
  80 #define RODATA_MAIN .rodata
  81 #define BSS_MAIN .bss
  82 #define SBSS_MAIN .sbss
  83 #endif
  84
  85 /*
  86  * Align to a 32 byte boundary equal to the
  87  * alignment gcc 4.5 uses for a struct
  88  */
  89 #define STRUCT_ALIGNMENT 32
  90 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
  91
  92 /* The actual configuration determine if the init/exit sections
  93  * are handled as text/data or they can be discarded (which
  94  * often happens at runtime)
  95  */
  96 #ifdef CONFIG_HOTPLUG_CPU
  97 #define CPU_KEEP(sec)    *(.cpu##sec)
  98 #define CPU_DISCARD(sec)
  99 #else
 100 #define CPU_KEEP(sec)
 101 #define CPU_DISCARD(sec) *(.cpu##sec)
 102 #endif
 103
 104 #if defined(CONFIG_MEMORY_HOTPLUG)
 105 #define MEM_KEEP(sec)    *(.mem##sec)
 106 #define MEM_DISCARD(sec)
 107 #else
 108 #define MEM_KEEP(sec)
 109 #define MEM_DISCARD(sec) *(.mem##sec)
 110 #endif
 111
 112 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
 113 #ifdef CC_USING_PATCHABLE_FUNCTION_ENTRY
 114 #define MCOUNT_REC()    . = ALIGN(8);                           \
 115                         __start_mcount_loc = .;                 \
 116                         KEEP(*(__patchable_function_entries))   \
 117                         __stop_mcount_loc = .;
 118 #else
 119 #define MCOUNT_REC()    . = ALIGN(8);                           \
 120                         __start_mcount_loc = .;                 \
 121                         KEEP(*(__mcount_loc))                   \
 122                         __stop_mcount_loc = .;
 123 #endif
 124 #else
 125 #define MCOUNT_REC()
 126 #endif
 127
 128 #ifdef CONFIG_TRACE_BRANCH_PROFILING
 129 #define LIKELY_PROFILE()        __start_annotated_branch_profile = .;   \
 130                                 KEEP(*(_ftrace_annotated_branch))       \
 131                                 __stop_annotated_branch_profile = .;
 132 #else
 133 #define LIKELY_PROFILE()
 134 #endif
 135
 136 #ifdef CONFIG_PROFILE_ALL_BRANCHES
 137 #define BRANCH_PROFILE()        __start_branch_profile = .;             \
 138                                 KEEP(*(_ftrace_branch))                 \
 139                                 __stop_branch_profile = .;
 140 #else
 141 #define BRANCH_PROFILE()
 142 #endif
 143
 144 #ifdef CONFIG_KPROBES
 145 #define KPROBE_BLACKLIST()      . = ALIGN(8);                                 \
 146                                 __start_kprobe_blacklist = .;                 \
 147                                 KEEP(*(_kprobe_blacklist))                    \
 148                                 __stop_kprobe_blacklist = .;
 149 #else
 150 #define KPROBE_BLACKLIST()
 151 #endif
 152
 153 #ifdef CONFIG_FUNCTION_ERROR_INJECTION
 154 #define ERROR_INJECT_WHITELIST()        STRUCT_ALIGN();                       \
 155                         __start_error_injection_whitelist = .;                \
 156                         KEEP(*(_error_injection_whitelist))                   \
 157                         __stop_error_injection_whitelist = .;
 158 #else
 159 #define ERROR_INJECT_WHITELIST()
 160 #endif
 161
 162 #ifdef CONFIG_EVENT_TRACING
 163 #define FTRACE_EVENTS() . = ALIGN(8);                                   \
 164                         __start_ftrace_events = .;                      \
 165                         KEEP(*(_ftrace_events))                         \
 166                         __stop_ftrace_events = .;                       \
 167                         __start_ftrace_eval_maps = .;                   \
 168                         KEEP(*(_ftrace_eval_map))                       \
 169                         __stop_ftrace_eval_maps = .;
 170 #else
 171 #define FTRACE_EVENTS()
 172 #endif
 173
 174 #ifdef CONFIG_TRACING
 175 #define TRACE_PRINTKS()  __start___trace_bprintk_fmt = .;      \
 176                          KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
 177                          __stop___trace_bprintk_fmt = .;
 178 #define TRACEPOINT_STR() __start___tracepoint_str = .;  \
 179                          KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
 180                          __stop___tracepoint_str = .;
 181 #else
 182 #define TRACE_PRINTKS()
 183 #define TRACEPOINT_STR()
 184 #endif
 185
 186 #ifdef CONFIG_FTRACE_SYSCALLS
 187 #define TRACE_SYSCALLS() . = ALIGN(8);                                  \
 188                          __start_syscalls_metadata = .;                 \
 189                          KEEP(*(__syscalls_metadata))                   \
 190                          __stop_syscalls_metadata = .;
 191 #else
 192 #define TRACE_SYSCALLS()
 193 #endif
 194
 195 #ifdef CONFIG_BPF_EVENTS
 196 #define BPF_RAW_TP() STRUCT_ALIGN();                                    \
 197                          __start__bpf_raw_tp = .;                       \
 198                          KEEP(*(__bpf_raw_tp_map))                      \
 199                          __stop__bpf_raw_tp = .;
 200 #else
 201 #define BPF_RAW_TP()
 202 #endif
 203
 204 #ifdef CONFIG_SERIAL_EARLYCON
 205 #define EARLYCON_TABLE() . = ALIGN(8);                          \
 206                          __earlycon_table = .;                  \
 207                          KEEP(*(__earlycon_table))              \
 208                          __earlycon_table_end = .;
 209 #else
 210 #define EARLYCON_TABLE()
 211 #endif
 212
 213 #ifdef CONFIG_SECURITY
 214 #define LSM_TABLE()     . = ALIGN(8);                                   \
 215                         __start_lsm_info = .;                           \
 216                         KEEP(*(.lsm_info.init))                         \
 217                         __end_lsm_info = .;
 218 #else
 219 #define LSM_TABLE()
 220 #endif
 221
 222 #define ___OF_TABLE(cfg, name)  _OF_TABLE_##cfg(name)
 223 #define __OF_TABLE(cfg, name)   ___OF_TABLE(cfg, name)
 224 #define OF_TABLE(cfg, name)     __OF_TABLE(IS_ENABLED(cfg), name)
 225 #define _OF_TABLE_0(name)
 226 #define _OF_TABLE_1(name)                                               \
 227         . = ALIGN(8);                                                   \
 228         __##name##_of_table = .;                                        \
 229         KEEP(*(__##name##_of_table))                                    \
 230         KEEP(*(__##name##_of_table_end))
 231
 232 #define TIMER_OF_TABLES()       OF_TABLE(CONFIG_TIMER_OF, timer)
 233 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
 234 #define CLK_OF_TABLES()         OF_TABLE(CONFIG_COMMON_CLK, clk)
 235 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
 236 #define CPU_METHOD_OF_TABLES()  OF_TABLE(CONFIG_SMP, cpu_method)
 237 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
 238
 239 #ifdef CONFIG_ACPI
 240 #define ACPI_PROBE_TABLE(name)                                          \
 241         . = ALIGN(8);                                                   \
 242         __##name##_acpi_probe_table = .;                                \
 243         KEEP(*(__##name##_acpi_probe_table))                            \
 244         __##name##_acpi_probe_table_end = .;
 245 #else
 246 #define ACPI_PROBE_TABLE(name)
 247 #endif
 248
 249 #define KERNEL_DTB()                                                    \
 250         STRUCT_ALIGN();                                                 \
 251         __dtb_start = .;                                                \
 252         KEEP(*(.dtb.init.rodata))                                       \
 253         __dtb_end = .;
 254
 255 /*
 256  * .data section
 257  */
 258 #define DATA_DATA                                                       \
 259         *(.xiptext)                                                     \
 260         *(DATA_MAIN)                                                    \
 261         *(.ref.data)                                                    \
 262         *(.data..shared_aligned) /* percpu related */                   \
 263         MEM_KEEP(init.data*)                                            \
 264         MEM_KEEP(exit.data*)                                            \
 265         *(.data.unlikely)                                               \
 266         __start_once = .;                                               \
 267         *(.data.once)                                                   \
 268         __end_once = .;                                                 \
 269         STRUCT_ALIGN();                                                 \
 270         *(__tracepoints)                                                \
 271         /* implement dynamic printk debug */                            \
 272         . = ALIGN(8);                                                   \
 273         __start___verbose = .;                                          \
 274         KEEP(*(__verbose))                                              \
 275         __stop___verbose = .;                                           \
 276         LIKELY_PROFILE()                                                \
 277         BRANCH_PROFILE()                                                \
 278         TRACE_PRINTKS()                                                 \
 279         BPF_RAW_TP()                                                    \
 280         TRACEPOINT_STR()
 281
 282 /*
 283  * Data section helpers
 284  */
 285 #define NOSAVE_DATA                                                     \
 286         . = ALIGN(PAGE_SIZE);                                           \
 287         __nosave_begin = .;                                             \
 288         *(.data..nosave)                                                \
 289         . = ALIGN(PAGE_SIZE);                                           \
 290         __nosave_end = .;
 291
 292 #define PAGE_ALIGNED_DATA(page_align)                                   \
 293         . = ALIGN(page_align);                                          \
 294         *(.data..page_aligned)
 295
 296 #define READ_MOSTLY_DATA(align)                                         \
 297         . = ALIGN(align);                                               \
 298         *(.data..read_mostly)                                           \
 299         . = ALIGN(align);
 300
 301 #define CACHELINE_ALIGNED_DATA(align)                                   \
 302         . = ALIGN(align);                                               \
 303         *(.data..cacheline_aligned)
 304
 305 #define INIT_TASK_DATA(align)                                           \
 306         . = ALIGN(align);                                               \
 307         __start_init_task = .;                                          \
 308         init_thread_union = .;                                          \
 309         init_stack = .;                                                 \
 310         KEEP(*(.data..init_task))                                       \
 311         KEEP(*(.data..init_thread_info))                                \
 312         . = __start_init_task + THREAD_SIZE;                            \
 313         __end_init_task = .;
 314
 315 #define JUMP_TABLE_DATA                                                 \
 316         . = ALIGN(8);                                                   \
 317         __start___jump_table = .;                                       \
 318         KEEP(*(__jump_table))                                           \
 319         __stop___jump_table = .;
 320
 321 /*
 322  * Allow architectures to handle ro_after_init data on their
 323  * own by defining an empty RO_AFTER_INIT_DATA.
 324  */
 325 #ifndef RO_AFTER_INIT_DATA
 326 #define RO_AFTER_INIT_DATA                                              \
 327         __start_ro_after_init = .;                                      \
 328         *(.data..ro_after_init)                                         \
 329         JUMP_TABLE_DATA                                                 \
 330         __end_ro_after_init = .;
 331 #endif
 332
 333 /*
 334  * Read only Data
 335  */
 336 #define RO_DATA_SECTION(align)                                          \
 337         . = ALIGN((align));                                             \
 338         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
 339                 __start_rodata = .;                                     \
 340                 *(.rodata) *(.rodata.*)                                 \
 341                 RO_AFTER_INIT_DATA      /* Read only after init */      \
 342                 . = ALIGN(8);                                           \
 343                 __start___tracepoints_ptrs = .;                         \
 344                 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
 345                 __stop___tracepoints_ptrs = .;                          \
 346                 *(__tracepoints_strings)/* Tracepoints: strings */      \
 347         }                                                               \
 348                                                                         \
 349         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
 350                 *(.rodata1)                                             \
 351         }                                                               \
 352                                                                         \
 353         /* PCI quirks */                                                \
 354         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
 355                 __start_pci_fixups_early = .;                           \
 356                 KEEP(*(.pci_fixup_early))                               \
 357                 __end_pci_fixups_early = .;                             \
 358                 __start_pci_fixups_header = .;                          \
 359                 KEEP(*(.pci_fixup_header))                              \
 360                 __end_pci_fixups_header = .;                            \
 361                 __start_pci_fixups_final = .;                           \
 362                 KEEP(*(.pci_fixup_final))                               \
 363                 __end_pci_fixups_final = .;                             \
 364                 __start_pci_fixups_enable = .;                          \
 365                 KEEP(*(.pci_fixup_enable))                              \
 366                 __end_pci_fixups_enable = .;                            \
 367                 __start_pci_fixups_resume = .;                          \
 368                 KEEP(*(.pci_fixup_resume))                              \
 369                 __end_pci_fixups_resume = .;                            \
 370                 __start_pci_fixups_resume_early = .;                    \
 371                 KEEP(*(.pci_fixup_resume_early))                        \
 372                 __end_pci_fixups_resume_early = .;                      \
 373                 __start_pci_fixups_suspend = .;                         \
 374                 KEEP(*(.pci_fixup_suspend))                             \
 375                 __end_pci_fixups_suspend = .;                           \
 376                 __start_pci_fixups_suspend_late = .;                    \
 377                 KEEP(*(.pci_fixup_suspend_late))                        \
 378                 __end_pci_fixups_suspend_late = .;                      \
 379         }                                                               \
 380                                                                         \
 381         /* Built-in firmware blobs */                                   \
 382         .builtin_fw        : AT(ADDR(.builtin_fw) - LOAD_OFFSET) {      \
 383                 __start_builtin_fw = .;                                 \
 384                 KEEP(*(.builtin_fw))                                    \
 385                 __end_builtin_fw = .;                                   \
 386         }                                                               \
 387                                                                         \
 388         TRACEDATA                                                       \
 389                                                                         \
 390         /* Kernel symbol table: Normal symbols */                       \
 391         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
 392                 __start___ksymtab = .;                                  \
 393                 KEEP(*(SORT(___ksymtab+*)))                             \
 394                 __stop___ksymtab = .;                                   \
 395         }                                                               \
 396                                                                         \
 397         /* Kernel symbol table: GPL-only symbols */                     \
 398         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
 399                 __start___ksymtab_gpl = .;                              \
 400                 KEEP(*(SORT(___ksymtab_gpl+*)))                         \
 401                 __stop___ksymtab_gpl = .;                               \
 402         }                                                               \
 403                                                                         \
 404         /* Kernel symbol table: Normal unused symbols */                \
 405         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
 406                 __start___ksymtab_unused = .;                           \
 407                 KEEP(*(SORT(___ksymtab_unused+*)))                      \
 408                 __stop___ksymtab_unused = .;                            \
 409         }                                                               \
 410                                                                         \
 411         /* Kernel symbol table: GPL-only unused symbols */              \
 412         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
 413                 __start___ksymtab_unused_gpl = .;                       \
 414                 KEEP(*(SORT(___ksymtab_unused_gpl+*)))                  \
 415                 __stop___ksymtab_unused_gpl = .;                        \
 416         }                                                               \
 417                                                                         \
 418         /* Kernel symbol table: GPL-future-only symbols */              \
 419         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
 420                 __start___ksymtab_gpl_future = .;                       \
 421                 KEEP(*(SORT(___ksymtab_gpl_future+*)))                  \
 422                 __stop___ksymtab_gpl_future = .;                        \
 423         }                                                               \
 424                                                                         \
 425         /* Kernel symbol table: Normal symbols */                       \
 426         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
 427                 __start___kcrctab = .;                                  \
 428                 KEEP(*(SORT(___kcrctab+*)))                             \
 429                 __stop___kcrctab = .;                                   \
 430         }                                                               \
 431                                                                         \
 432         /* Kernel symbol table: GPL-only symbols */                     \
 433         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
 434                 __start___kcrctab_gpl = .;                              \
 435                 KEEP(*(SORT(___kcrctab_gpl+*)))                         \
 436                 __stop___kcrctab_gpl = .;                               \
 437         }                                                               \
 438                                                                         \
 439         /* Kernel symbol table: Normal unused symbols */                \
 440         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
 441                 __start___kcrctab_unused = .;                           \
 442                 KEEP(*(SORT(___kcrctab_unused+*)))                      \
 443                 __stop___kcrctab_unused = .;                            \
 444         }                                                               \
 445                                                                         \
 446         /* Kernel symbol table: GPL-only unused symbols */              \
 447         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
 448                 __start___kcrctab_unused_gpl = .;                       \
 449                 KEEP(*(SORT(___kcrctab_unused_gpl+*)))                  \
 450                 __stop___kcrctab_unused_gpl = .;                        \
 451         }                                                               \
 452                                                                         \
 453         /* Kernel symbol table: GPL-future-only symbols */              \
 454         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
 455                 __start___kcrctab_gpl_future = .;                       \
 456                 KEEP(*(SORT(___kcrctab_gpl_future+*)))                  \
 457                 __stop___kcrctab_gpl_future = .;                        \
 458         }                                                               \
 459                                                                         \
 460         /* Kernel symbol table: strings */                              \
 461         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
 462                 *(__ksymtab_strings)                                    \
 463         }                                                               \
 464                                                                         \
 465         /* __*init sections */                                          \
 466         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
 467                 *(.ref.rodata)                                          \
 468                 MEM_KEEP(init.rodata)                                   \
 469                 MEM_KEEP(exit.rodata)                                   \
 470         }                                                               \
 471                                                                         \
 472         /* Built-in module parameters. */                               \
 473         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
 474                 __start___param = .;                                    \
 475                 KEEP(*(__param))                                        \
 476                 __stop___param = .;                                     \
 477         }                                                               \
 478                                                                         \
 479         /* Built-in module versions. */                                 \
 480         __modver : AT(ADDR(__modver) - LOAD_OFFSET) {                   \
 481                 __start___modver = .;                                   \
 482                 KEEP(*(__modver))                                       \
 483                 __stop___modver = .;                                    \
 484                 . = ALIGN((align));                                     \
 485                 __end_rodata = .;                                       \
 486         }                                                               \
 487         . = ALIGN((align));
 488
 489 /* RODATA & RO_DATA provided for backward compatibility.
 490  * All archs are supposed to use RO_DATA() */
 491 #define RODATA          RO_DATA_SECTION(4096)
 492 #define RO_DATA(align)  RO_DATA_SECTION(align)
 493
 494 /*
 495  * .text section. Map to function alignment to avoid address changes
 496  * during second ld run in second ld pass when generating System.map
 497  *
 498  * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
 499  * code elimination is enabled, so these sections should be converted
 500  * to use ".." first.
 501  */
 502 #define TEXT_TEXT                                                       \
 503                 ALIGN_FUNCTION();                                       \
 504                 *(.text.hot TEXT_MAIN .text.fixup .text.unlikely)       \
 505                 *(.text..refcount)                                      \
 506                 *(.ref.text)                                            \
 507         MEM_KEEP(init.text*)                                            \
 508         MEM_KEEP(exit.text*)                                            \
 509
 510
 511 /* sched.text is aling to function alignment to secure we have same
 512  * address even at second ld pass when generating System.map */
 513 #define SCHED_TEXT                                                      \
 514                 ALIGN_FUNCTION();                                       \
 515                 __sched_text_start = .;                                 \
 516                 *(.sched.text)                                          \
 517                 __sched_text_end = .;
 518
 519 /* spinlock.text is aling to function alignment to secure we have same
 520  * address even at second ld pass when generating System.map */
 521 #define LOCK_TEXT                                                       \
 522                 ALIGN_FUNCTION();                                       \
 523                 __lock_text_start = .;                                  \
 524                 *(.spinlock.text)                                       \
 525                 __lock_text_end = .;
 526
 527 #define CPUIDLE_TEXT                                                    \
 528                 ALIGN_FUNCTION();                                       \
 529                 __cpuidle_text_start = .;                               \
 530                 *(.cpuidle.text)                                        \
 531                 __cpuidle_text_end = .;
 532
 533 #define KPROBES_TEXT                                                    \
 534                 ALIGN_FUNCTION();                                       \
 535                 __kprobes_text_start = .;                               \
 536                 *(.kprobes.text)                                        \
 537                 __kprobes_text_end = .;
 538
 539 #define ENTRY_TEXT                                                      \
 540                 ALIGN_FUNCTION();                                       \
 541                 __entry_text_start = .;                                 \
 542                 *(.entry.text)                                          \
 543                 __entry_text_end = .;
 544
 545 #define IRQENTRY_TEXT                                                   \
 546                 ALIGN_FUNCTION();                                       \
 547                 __irqentry_text_start = .;                              \
 548                 *(.irqentry.text)                                       \
 549                 __irqentry_text_end = .;
 550
 551 #define SOFTIRQENTRY_TEXT                                               \
 552                 ALIGN_FUNCTION();                                       \
 553                 __softirqentry_text_start = .;                          \
 554                 *(.softirqentry.text)                                   \
 555                 __softirqentry_text_end = .;
 556
 557 /* Section used for early init (in .S files) */
 558 #define HEAD_TEXT  KEEP(*(.head.text))
 559
 560 #define HEAD_TEXT_SECTION                                                       \
 561         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {               \
 562                 HEAD_TEXT                                               \
 563         }
 564
 565 /*
 566  * Exception table
 567  */
 568 #define EXCEPTION_TABLE(align)                                          \
 569         . = ALIGN(align);                                               \
 570         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {               \
 571                 __start___ex_table = .;                                 \
 572                 KEEP(*(__ex_table))                                     \
 573                 __stop___ex_table = .;                                  \
 574         }
 575
 576 /*
 577  * Init task
 578  */
 579 #define INIT_TASK_DATA_SECTION(align)                                   \
 580         . = ALIGN(align);                                               \
 581         .data..init_task :  AT(ADDR(.data..init_task) - LOAD_OFFSET) {  \
 582                 INIT_TASK_DATA(align)                                   \
 583         }
 584
 585 #ifdef CONFIG_CONSTRUCTORS
 586 #define KERNEL_CTORS()  . = ALIGN(8);                      \
 587                         __ctors_start = .;                 \
 588                         KEEP(*(.ctors))                    \
 589                         KEEP(*(SORT(.init_array.*)))       \
 590                         KEEP(*(.init_array))               \
 591                         __ctors_end = .;
 592 #else
 593 #define KERNEL_CTORS()
 594 #endif
 595
 596 /* init and exit section handling */
 597 #define INIT_DATA                                                       \
 598         KEEP(*(SORT(___kentry+*)))                                      \
 599         *(.init.data init.data.*)                                       \
 600         MEM_DISCARD(init.data*)                                         \
 601         KERNEL_CTORS()                                                  \
 602         MCOUNT_REC()                                                    \
 603         *(.init.rodata .init.rodata.*)                                  \
 604         FTRACE_EVENTS()                                                 \
 605         TRACE_SYSCALLS()                                                \
 606         KPROBE_BLACKLIST()                                              \
 607         ERROR_INJECT_WHITELIST()                                        \
 608         MEM_DISCARD(init.rodata)                                        \
 609         CLK_OF_TABLES()                                                 \
 610         RESERVEDMEM_OF_TABLES()                                         \
 611         TIMER_OF_TABLES()                                               \
 612         CPU_METHOD_OF_TABLES()                                          \
 613         CPUIDLE_METHOD_OF_TABLES()                                      \
 614         KERNEL_DTB()                                                    \
 615         IRQCHIP_OF_MATCH_TABLE()                                        \
 616         ACPI_PROBE_TABLE(irqchip)                                       \
 617         ACPI_PROBE_TABLE(timer)                                         \
 618         EARLYCON_TABLE()                                                \
 619         LSM_TABLE()
 620
 621 #define INIT_TEXT                                                       \
 622         *(.init.text .init.text.*)                                      \
 623         *(.text.startup)                                                \
 624         MEM_DISCARD(init.text*)
 625
 626 #define EXIT_DATA                                                       \
 627         *(.exit.data .exit.data.*)                                      \
 628         *(.fini_array .fini_array.*)                                    \
 629         *(.dtors .dtors.*)                                              \
 630         MEM_DISCARD(exit.data*)                                         \
 631         MEM_DISCARD(exit.rodata*)
 632
 633 #define EXIT_TEXT                                                       \
 634         *(.exit.text)                                                   \
 635         *(.text.exit)                                                   \
 636         MEM_DISCARD(exit.text)
 637
 638 #define EXIT_CALL                                                       \
 639         *(.exitcall.exit)
 640
 641 /*
 642  * bss (Block Started by Symbol) - uninitialized data
 643  * zeroed during startup
 644  */
 645 #define SBSS(sbss_align)                                                \
 646         . = ALIGN(sbss_align);                                          \
 647         .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) {                         \
 648                 *(.dynsbss)                                             \
 649                 *(SBSS_MAIN)                                            \
 650                 *(.scommon)                                             \
 651         }
 652
 653 /*
 654  * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
 655  * sections to the front of bss.
 656  */
 657 #ifndef BSS_FIRST_SECTIONS
 658 #define BSS_FIRST_SECTIONS
 659 #endif
 660
 661 #define BSS(bss_align)                                                  \
 662         . = ALIGN(bss_align);                                           \
 663         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {                           \
 664                 BSS_FIRST_SECTIONS                                      \
 665                 *(.bss..page_aligned)                                   \
 666                 *(.dynbss)                                              \
 667                 *(BSS_MAIN)                                             \
 668                 *(COMMON)                                               \
 669         }
 670
 671 /*
 672  * DWARF debug sections.
 673  * Symbols in the DWARF debugging sections are relative to
 674  * the beginning of the section so we begin them at 0.
 675  */
 676 #define DWARF_DEBUG                                                     \
 677                 /* DWARF 1 */                                           \
 678                 .debug          0 : { *(.debug) }                       \
 679                 .line           0 : { *(.line) }                        \
 680                 /* GNU DWARF 1 extensions */                            \
 681                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
 682                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
 683                 /* DWARF 1.1 and DWARF 2 */                             \
 684                 .debug_aranges  0 : { *(.debug_aranges) }               \
 685                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
 686                 /* DWARF 2 */                                           \
 687                 .debug_info     0 : { *(.debug_info                     \
 688                                 .gnu.linkonce.wi.*) }                   \
 689                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
 690                 .debug_line     0 : { *(.debug_line) }                  \
 691                 .debug_frame    0 : { *(.debug_frame) }                 \
 692                 .debug_str      0 : { *(.debug_str) }                   \
 693                 .debug_loc      0 : { *(.debug_loc) }                   \
 694                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
 695                 .debug_pubtypes 0 : { *(.debug_pubtypes) }              \
 696                 /* DWARF 3 */                                           \
 697                 .debug_ranges   0 : { *(.debug_ranges) }                \
 698                 /* SGI/MIPS DWARF 2 extensions */                       \
 699                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
 700                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
 701                 .debug_typenames 0 : { *(.debug_typenames) }            \
 702                 .debug_varnames  0 : { *(.debug_varnames) }             \
 703                 /* GNU DWARF 2 extensions */                            \
 704                 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) }      \
 705                 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) }      \
 706                 /* DWARF 4 */                                           \
 707                 .debug_types    0 : { *(.debug_types) }                 \
 708                 /* DWARF 5 */                                           \
 709                 .debug_macro    0 : { *(.debug_macro) }                 \
 710                 .debug_addr     0 : { *(.debug_addr) }
 711
 712                 /* Stabs debugging sections.  */
 713 #define STABS_DEBUG                                                     \
 714                 .stab 0 : { *(.stab) }                                  \
 715                 .stabstr 0 : { *(.stabstr) }                            \
 716                 .stab.excl 0 : { *(.stab.excl) }                        \
 717                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
 718                 .stab.index 0 : { *(.stab.index) }                      \
 719                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
 720                 .comment 0 : { *(.comment) }
 721
 722 #ifdef CONFIG_GENERIC_BUG
 723 #define BUG_TABLE                                                       \
 724         . = ALIGN(8);                                                   \
 725         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
 726                 __start___bug_table = .;                                \
 727                 KEEP(*(__bug_table))                                    \
 728                 __stop___bug_table = .;                                 \
 729         }
 730 #else
 731 #define BUG_TABLE
 732 #endif
 733
 734 #ifdef CONFIG_UNWINDER_ORC
 735 #define ORC_UNWIND_TABLE                                                \
 736         . = ALIGN(4);                                                   \
 737         .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) {       \
 738                 __start_orc_unwind_ip = .;                              \
 739                 KEEP(*(.orc_unwind_ip))                                 \
 740                 __stop_orc_unwind_ip = .;                               \
 741         }                                                               \
 742         . = ALIGN(2);                                                   \
 743         .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) {             \
 744                 __start_orc_unwind = .;                                 \
 745                 KEEP(*(.orc_unwind))                                    \
 746                 __stop_orc_unwind = .;                                  \
 747         }                                                               \
 748         . = ALIGN(4);                                                   \
 749         .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) {             \
 750                 orc_lookup = .;                                         \
 751                 . += (((SIZEOF(.text) + LOOKUP_BLOCK_SIZE - 1) /        \
 752                         LOOKUP_BLOCK_SIZE) + 1) * 4;                    \
 753                 orc_lookup_end = .;                                     \
 754         }
 755 #else
 756 #define ORC_UNWIND_TABLE
 757 #endif
 758
 759 #ifdef CONFIG_PM_TRACE
 760 #define TRACEDATA                                                       \
 761         . = ALIGN(4);                                                   \
 762         .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {               \
 763                 __tracedata_start = .;                                  \
 764                 KEEP(*(.tracedata))                                     \
 765                 __tracedata_end = .;                                    \
 766         }
 767 #else
 768 #define TRACEDATA
 769 #endif
 770
 771 #define NOTES                                                           \
 772         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
 773                 __start_notes = .;                                      \
 774                 KEEP(*(.note.*))                                        \
 775                 __stop_notes = .;                                       \
 776         }
 777
 778 #define INIT_SETUP(initsetup_align)                                     \
 779                 . = ALIGN(initsetup_align);                             \
 780                 __setup_start = .;                                      \
 781                 KEEP(*(.init.setup))                                    \
 782                 __setup_end = .;
 783
 784 #define INIT_CALLS_LEVEL(level)                                         \
 785                 __initcall##level##_start = .;                          \
 786                 KEEP(*(.initcall##level##.init))                        \
 787                 KEEP(*(.initcall##level##s.init))                       \
 788
 789 #define INIT_CALLS                                                      \
 790                 __initcall_start = .;                                   \
 791                 KEEP(*(.initcallearly.init))                            \
 792                 INIT_CALLS_LEVEL(0)                                     \
 793                 INIT_CALLS_LEVEL(1)                                     \
 794                 INIT_CALLS_LEVEL(2)                                     \
 795                 INIT_CALLS_LEVEL(3)                                     \
 796                 INIT_CALLS_LEVEL(4)                                     \
 797                 INIT_CALLS_LEVEL(5)                                     \
 798                 INIT_CALLS_LEVEL(rootfs)                                \
 799                 INIT_CALLS_LEVEL(6)                                     \
 800                 INIT_CALLS_LEVEL(7)                                     \
 801                 __initcall_end = .;
 802
 803 #define CON_INITCALL                                                    \
 804                 __con_initcall_start = .;                               \
 805                 KEEP(*(.con_initcall.init))                             \
 806                 __con_initcall_end = .;
 807
 808 #ifdef CONFIG_BLK_DEV_INITRD
 809 #define INIT_RAM_FS                                                     \
 810         . = ALIGN(4);                                                   \
 811         __initramfs_start = .;                                          \
 812         KEEP(*(.init.ramfs))                                            \
 813         . = ALIGN(8);                                                   \
 814         KEEP(*(.init.ramfs.info))
 815 #else
 816 #define INIT_RAM_FS
 817 #endif
 818
 819 /*
 820  * Memory encryption operates on a page basis. Since we need to clear
 821  * the memory encryption mask for this section, it needs to be aligned
 822  * on a page boundary and be a page-size multiple in length.
 823  *
 824  * Note: We use a separate section so that only this section gets
 825  * decrypted to avoid exposing more than we wish.
 826  */
 827 #ifdef CONFIG_AMD_MEM_ENCRYPT
 828 #define PERCPU_DECRYPTED_SECTION                                        \
 829         . = ALIGN(PAGE_SIZE);                                           \
 830         *(.data..percpu..decrypted)                                     \
 831         . = ALIGN(PAGE_SIZE);
 832 #else
 833 #define PERCPU_DECRYPTED_SECTION
 834 #endif
 835
 836
 837 /*
 838  * Default discarded sections.
 839  *
 840  * Some archs want to discard exit text/data at runtime rather than
 841  * link time due to cross-section references such as alt instructions,
 842  * bug table, eh_frame, etc.  DISCARDS must be the last of output
 843  * section definitions so that such archs put those in earlier section
 844  * definitions.
 845  */
 846 #define DISCARDS                                                        \
 847         /DISCARD/ : {                                                   \
 848         EXIT_TEXT                                                       \
 849         EXIT_DATA                                                       \
 850         EXIT_CALL                                                       \
 851         *(.discard)                                                     \
 852         *(.discard.*)                                                   \
 853         *(.modinfo)                                                     \
 854         }
 855
 856 /**
 857  * PERCPU_INPUT - the percpu input sections
 858  * @cacheline: cacheline size
 859  *
 860  * The core percpu section names and core symbols which do not rely
 861  * directly upon load addresses.
 862  *
 863  * @cacheline is used to align subsections to avoid false cacheline
 864  * sharing between subsections for different purposes.
 865  */
 866 #define PERCPU_INPUT(cacheline)                                         \
 867         __per_cpu_start = .;                                            \
 868         *(.data..percpu..first)                                         \
 869         . = ALIGN(PAGE_SIZE);                                           \
 870         *(.data..percpu..page_aligned)                                  \
 871         . = ALIGN(cacheline);                                           \
 872         *(.data..percpu..read_mostly)                                   \
 873         . = ALIGN(cacheline);                                           \
 874         *(.data..percpu)                                                \
 875         *(.data..percpu..shared_aligned)                                \
 876         PERCPU_DECRYPTED_SECTION                                        \
 877         __per_cpu_end = .;
 878
 879 /**
 880  * PERCPU_VADDR - define output section for percpu area
 881  * @cacheline: cacheline size
 882  * @vaddr: explicit base address (optional)
 883  * @phdr: destination PHDR (optional)
 884  *
 885  * Macro which expands to output section for percpu area.
 886  *
 887  * @cacheline is used to align subsections to avoid false cacheline
 888  * sharing between subsections for different purposes.
 889  *
 890  * If @vaddr is not blank, it specifies explicit base address and all
 891  * percpu symbols will be offset from the given address.  If blank,
 892  * @vaddr always equals @laddr + LOAD_OFFSET.
 893  *
 894  * @phdr defines the output PHDR to use if not blank.  Be warned that
 895  * output PHDR is sticky.  If @phdr is specified, the next output
 896  * section in the linker script will go there too.  @phdr should have
 897  * a leading colon.
 898  *
 899  * Note that this macros defines __per_cpu_load as an absolute symbol.
 900  * If there is no need to put the percpu section at a predetermined
 901  * address, use PERCPU_SECTION.
 902  */
 903 #define PERCPU_VADDR(cacheline, vaddr, phdr)                            \
 904         __per_cpu_load = .;                                             \
 905         .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) {        \
 906                 PERCPU_INPUT(cacheline)                                 \
 907         } phdr                                                          \
 908         . = __per_cpu_load + SIZEOF(.data..percpu);
 909
 910 /**
 911  * PERCPU_SECTION - define output section for percpu area, simple version
 912  * @cacheline: cacheline size
 913  *
 914  * Align to PAGE_SIZE and outputs output section for percpu area.  This
 915  * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
 916  * __per_cpu_start will be identical.
 917  *
 918  * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
 919  * except that __per_cpu_load is defined as a relative symbol against
 920  * .data..percpu which is required for relocatable x86_32 configuration.
 921  */
 922 #define PERCPU_SECTION(cacheline)                                       \
 923         . = ALIGN(PAGE_SIZE);                                           \
 924         .data..percpu   : AT(ADDR(.data..percpu) - LOAD_OFFSET) {       \
 925                 __per_cpu_load = .;                                     \
 926                 PERCPU_INPUT(cacheline)                                 \
 927         }
 928
 929
 930 /*
 931  * Definition of the high level *_SECTION macros
 932  * They will fit only a subset of the architectures
 933  */
 934
 935
 936 /*
 937  * Writeable data.
 938  * All sections are combined in a single .data section.
 939  * The sections following CONSTRUCTORS are arranged so their
 940  * typical alignment matches.
 941  * A cacheline is typical/always less than a PAGE_SIZE so
 942  * the sections that has this restriction (or similar)
 943  * is located before the ones requiring PAGE_SIZE alignment.
 944  * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
 945  * matches the requirement of PAGE_ALIGNED_DATA.
 946  *
 947  * use 0 as page_align if page_aligned data is not used */
 948 #define RW_DATA_SECTION(cacheline, pagealigned, inittask)               \
 949         . = ALIGN(PAGE_SIZE);                                           \
 950         .data : AT(ADDR(.data) - LOAD_OFFSET) {                         \
 951                 INIT_TASK_DATA(inittask)                                \
 952                 NOSAVE_DATA                                             \
 953                 PAGE_ALIGNED_DATA(pagealigned)                          \
 954                 CACHELINE_ALIGNED_DATA(cacheline)                       \
 955                 READ_MOSTLY_DATA(cacheline)                             \
 956                 DATA_DATA                                               \
 957                 CONSTRUCTORS                                            \
 958         }                                                               \
 959         BUG_TABLE                                                       \
 960
 961 #define INIT_TEXT_SECTION(inittext_align)                               \
 962         . = ALIGN(inittext_align);                                      \
 963         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {               \
 964                 _sinittext = .;                                         \
 965                 INIT_TEXT                                               \
 966                 _einittext = .;                                         \
 967         }
 968
 969 #define INIT_DATA_SECTION(initsetup_align)                              \
 970         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {               \
 971                 INIT_DATA                                               \
 972                 INIT_SETUP(initsetup_align)                             \
 973                 INIT_CALLS                                              \
 974                 CON_INITCALL                                            \
 975                 INIT_RAM_FS                                             \
 976         }
 977
 978 #define BSS_SECTION(sbss_align, bss_align, stop_align)                  \
 979         . = ALIGN(sbss_align);                                          \
 980         __bss_start = .;                                                \
 981         SBSS(sbss_align)                                                \
 982         BSS(bss_align)                                                  \
 983         . = ALIGN(stop_align);                                          \
 984         __bss_stop = .;