include/asm-generic/vmlinux.lds.h

   1 /*
   2  * Helper macros to support writing architecture specific
   3  * linker scripts.
   4  *
   5  * A minimal linker scripts has following content:
   6  * [This is a sample, architectures may have special requiriements]
   7  *
   8  * OUTPUT_FORMAT(...)
   9  * OUTPUT_ARCH(...)
  10  * ENTRY(...)
  11  * SECTIONS
  12  * {
  13  *      . = START;
  14  *      __init_begin = .;
  15  *      HEAD_TEXT_SECTION
  16  *      INIT_TEXT_SECTION(PAGE_SIZE)
  17  *      INIT_DATA_SECTION(...)
  18  *      PERCPU_SECTION(CACHELINE_SIZE)
  19  *      __init_end = .;
  20  *
  21  *      _stext = .;
  22  *      TEXT_SECTION = 0
  23  *      _etext = .;
  24  *
  25  *      _sdata = .;
  26  *      RO_DATA(PAGE_SIZE)
  27  *      RW_DATA(...)
  28  *      _edata = .;
  29  *
  30  *      EXCEPTION_TABLE(...)
  31  *
  32  *      BSS_SECTION(0, 0, 0)
  33  *      _end = .;
  34  *
  35  *      STABS_DEBUG
  36  *      DWARF_DEBUG
  37  *      ELF_DETAILS
  38  *
  39  *      DISCARDS                // must be the last
  40  * }
  41  *
  42  * [__init_begin, __init_end] is the init section that may be freed after init
  43  *      // __init_begin and __init_end should be page aligned, so that we can
  44  *      // free the whole .init memory
  45  * [_stext, _etext] is the text section
  46  * [_sdata, _edata] is the data section
  47  *
  48  * Some of the included output section have their own set of constants.
  49  * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
  50  *               [__nosave_begin, __nosave_end] for the nosave data
  51  */
  52
  53 #ifndef LOAD_OFFSET
  54 #define LOAD_OFFSET 0
  55 #endif
  56
  57 /*
  58  * Only some architectures want to have the .notes segment visible in
  59  * a separate PT_NOTE ELF Program Header. When this happens, it needs
  60  * to be visible in both the kernel text's PT_LOAD and the PT_NOTE
  61  * Program Headers. In this case, though, the PT_LOAD needs to be made
  62  * the default again so that all the following sections don't also end
  63  * up in the PT_NOTE Program Header.
  64  */
  65 #ifdef EMITS_PT_NOTE
  66 #define NOTES_HEADERS           :text :note
  67 #define NOTES_HEADERS_RESTORE   __restore_ph : { *(.__restore_ph) } :text
  68 #else
  69 #define NOTES_HEADERS
  70 #define NOTES_HEADERS_RESTORE
  71 #endif
  72
  73 /*
  74  * Some architectures have non-executable read-only exception tables.
  75  * They can be added to the RO_DATA segment by specifying their desired
  76  * alignment.
  77  */
  78 #ifdef RO_EXCEPTION_TABLE_ALIGN
  79 #define RO_EXCEPTION_TABLE      EXCEPTION_TABLE(RO_EXCEPTION_TABLE_ALIGN)
  80 #else
  81 #define RO_EXCEPTION_TABLE
  82 #endif
  83
  84 /* Align . to a 8 byte boundary equals to maximum function alignment. */
  85 #define ALIGN_FUNCTION()  . = ALIGN(8)
  86
  87 /*
  88  * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
  89  * generates .data.identifier sections, which need to be pulled in with
  90  * .data. We don't want to pull in .data..other sections, which Linux
  91  * has defined. Same for text and bss.
  92  *
  93  * RODATA_MAIN is not used because existing code already defines .rodata.x
  94  * sections to be brought in with rodata.
  95  */
  96 #ifdef CONFIG_LD_DEAD_CODE_DATA_ELIMINATION
  97 #define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
  98 #define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data..LPBX*
  99 #define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
 100 #define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]*
 101 #define BSS_MAIN .bss .bss.[0-9a-zA-Z_]*
 102 #define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
 103 #else
 104 #define TEXT_MAIN .text
 105 #define DATA_MAIN .data
 106 #define SDATA_MAIN .sdata
 107 #define RODATA_MAIN .rodata
 108 #define BSS_MAIN .bss
 109 #define SBSS_MAIN .sbss
 110 #endif
 111
 112 /*
 113  * GCC 4.5 and later have a 32 bytes section alignment for structures.
 114  * Except GCC 4.9, that feels the need to align on 64 bytes.
 115  */
 116 #if __GNUC__ == 4 && __GNUC_MINOR__ == 9
 117 #define STRUCT_ALIGNMENT 64
 118 #else
 119 #define STRUCT_ALIGNMENT 32
 120 #endif
 121 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
 122
 123 /*
 124  * The order of the sched class addresses are important, as they are
 125  * used to determine the order of the priority of each sched class in
 126  * relation to each other.
 127  */
 128 #define SCHED_DATA                              \
 129         STRUCT_ALIGN();                         \
 130         __begin_sched_classes = .;              \
 131         *(__idle_sched_class)                   \
 132         *(__fair_sched_class)                   \
 133         *(__rt_sched_class)                     \
 134         *(__dl_sched_class)                     \
 135         *(__stop_sched_class)                   \
 136         __end_sched_classes = .;
 137
 138 /* The actual configuration determine if the init/exit sections
 139  * are handled as text/data or they can be discarded (which
 140  * often happens at runtime)
 141  */
 142 #ifdef CONFIG_HOTPLUG_CPU
 143 #define CPU_KEEP(sec)    *(.cpu##sec)
 144 #define CPU_DISCARD(sec)
 145 #else
 146 #define CPU_KEEP(sec)
 147 #define CPU_DISCARD(sec) *(.cpu##sec)
 148 #endif
 149
 150 #if defined(CONFIG_MEMORY_HOTPLUG)
 151 #define MEM_KEEP(sec)    *(.mem##sec)
 152 #define MEM_DISCARD(sec)
 153 #else
 154 #define MEM_KEEP(sec)
 155 #define MEM_DISCARD(sec) *(.mem##sec)
 156 #endif
 157
 158 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
 159 /*
 160  * The ftrace call sites are logged to a section whose name depends on the
 161  * compiler option used. A given kernel image will only use one, AKA
 162  * FTRACE_CALLSITE_SECTION. We capture all of them here to avoid header
 163  * dependencies for FTRACE_CALLSITE_SECTION's definition.
 164  *
 165  * Need to also make ftrace_stub_graph point to ftrace_stub
 166  * so that the same stub location may have different protocols
 167  * and not mess up with C verifiers.
 168  */
 169 #define MCOUNT_REC()    . = ALIGN(8);                           \
 170                         __start_mcount_loc = .;                 \
 171                         KEEP(*(__mcount_loc))                   \
 172                         KEEP(*(__patchable_function_entries))   \
 173                         __stop_mcount_loc = .;                  \
 174                         ftrace_stub_graph = ftrace_stub;
 175 #else
 176 # ifdef CONFIG_FUNCTION_TRACER
 177 #  define MCOUNT_REC()  ftrace_stub_graph = ftrace_stub;
 178 # else
 179 #  define MCOUNT_REC()
 180 # endif
 181 #endif
 182
 183 #ifdef CONFIG_TRACE_BRANCH_PROFILING
 184 #define LIKELY_PROFILE()        __start_annotated_branch_profile = .;   \
 185                                 KEEP(*(_ftrace_annotated_branch))       \
 186                                 __stop_annotated_branch_profile = .;
 187 #else
 188 #define LIKELY_PROFILE()
 189 #endif
 190
 191 #ifdef CONFIG_PROFILE_ALL_BRANCHES
 192 #define BRANCH_PROFILE()        __start_branch_profile = .;             \
 193                                 KEEP(*(_ftrace_branch))                 \
 194                                 __stop_branch_profile = .;
 195 #else
 196 #define BRANCH_PROFILE()
 197 #endif
 198
 199 #ifdef CONFIG_KPROBES
 200 #define KPROBE_BLACKLIST()      . = ALIGN(8);                                 \
 201                                 __start_kprobe_blacklist = .;                 \
 202                                 KEEP(*(_kprobe_blacklist))                    \
 203                                 __stop_kprobe_blacklist = .;
 204 #else
 205 #define KPROBE_BLACKLIST()
 206 #endif
 207
 208 #ifdef CONFIG_FUNCTION_ERROR_INJECTION
 209 #define ERROR_INJECT_WHITELIST()        STRUCT_ALIGN();                       \
 210                         __start_error_injection_whitelist = .;                \
 211                         KEEP(*(_error_injection_whitelist))                   \
 212                         __stop_error_injection_whitelist = .;
 213 #else
 214 #define ERROR_INJECT_WHITELIST()
 215 #endif
 216
 217 #ifdef CONFIG_EVENT_TRACING
 218 #define FTRACE_EVENTS() . = ALIGN(8);                                   \
 219                         __start_ftrace_events = .;                      \
 220                         KEEP(*(_ftrace_events))                         \
 221                         __stop_ftrace_events = .;                       \
 222                         __start_ftrace_eval_maps = .;                   \
 223                         KEEP(*(_ftrace_eval_map))                       \
 224                         __stop_ftrace_eval_maps = .;
 225 #else
 226 #define FTRACE_EVENTS()
 227 #endif
 228
 229 #ifdef CONFIG_TRACING
 230 #define TRACE_PRINTKS()  __start___trace_bprintk_fmt = .;      \
 231                          KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
 232                          __stop___trace_bprintk_fmt = .;
 233 #define TRACEPOINT_STR() __start___tracepoint_str = .;  \
 234                          KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
 235                          __stop___tracepoint_str = .;
 236 #else
 237 #define TRACE_PRINTKS()
 238 #define TRACEPOINT_STR()
 239 #endif
 240
 241 #ifdef CONFIG_FTRACE_SYSCALLS
 242 #define TRACE_SYSCALLS() . = ALIGN(8);                                  \
 243                          __start_syscalls_metadata = .;                 \
 244                          KEEP(*(__syscalls_metadata))                   \
 245                          __stop_syscalls_metadata = .;
 246 #else
 247 #define TRACE_SYSCALLS()
 248 #endif
 249
 250 #ifdef CONFIG_BPF_EVENTS
 251 #define BPF_RAW_TP() STRUCT_ALIGN();                                    \
 252                          __start__bpf_raw_tp = .;                       \
 253                          KEEP(*(__bpf_raw_tp_map))                      \
 254                          __stop__bpf_raw_tp = .;
 255 #else
 256 #define BPF_RAW_TP()
 257 #endif
 258
 259 #ifdef CONFIG_SERIAL_EARLYCON
 260 #define EARLYCON_TABLE() . = ALIGN(8);                          \
 261                          __earlycon_table = .;                  \
 262                          KEEP(*(__earlycon_table))              \
 263                          __earlycon_table_end = .;
 264 #else
 265 #define EARLYCON_TABLE()
 266 #endif
 267
 268 #ifdef CONFIG_SECURITY
 269 #define LSM_TABLE()     . = ALIGN(8);                                   \
 270                         __start_lsm_info = .;                           \
 271                         KEEP(*(.lsm_info.init))                         \
 272                         __end_lsm_info = .;
 273 #define EARLY_LSM_TABLE()       . = ALIGN(8);                           \
 274                         __start_early_lsm_info = .;                     \
 275                         KEEP(*(.early_lsm_info.init))                   \
 276                         __end_early_lsm_info = .;
 277 #else
 278 #define LSM_TABLE()
 279 #define EARLY_LSM_TABLE()
 280 #endif
 281
 282 #define ___OF_TABLE(cfg, name)  _OF_TABLE_##cfg(name)
 283 #define __OF_TABLE(cfg, name)   ___OF_TABLE(cfg, name)
 284 #define OF_TABLE(cfg, name)     __OF_TABLE(IS_ENABLED(cfg), name)
 285 #define _OF_TABLE_0(name)
 286 #define _OF_TABLE_1(name)                                               \
 287         . = ALIGN(8);                                                   \
 288         __##name##_of_table = .;                                        \
 289         KEEP(*(__##name##_of_table))                                    \
 290         KEEP(*(__##name##_of_table_end))
 291
 292 #define TIMER_OF_TABLES()       OF_TABLE(CONFIG_TIMER_OF, timer)
 293 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
 294 #define CLK_OF_TABLES()         OF_TABLE(CONFIG_COMMON_CLK, clk)
 295 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
 296 #define CPU_METHOD_OF_TABLES()  OF_TABLE(CONFIG_SMP, cpu_method)
 297 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
 298
 299 #ifdef CONFIG_ACPI
 300 #define ACPI_PROBE_TABLE(name)                                          \
 301         . = ALIGN(8);                                                   \
 302         __##name##_acpi_probe_table = .;                                \
 303         KEEP(*(__##name##_acpi_probe_table))                            \
 304         __##name##_acpi_probe_table_end = .;
 305 #else
 306 #define ACPI_PROBE_TABLE(name)
 307 #endif
 308
 309 #ifdef CONFIG_THERMAL
 310 #define THERMAL_TABLE(name)                                             \
 311         . = ALIGN(8);                                                   \
 312         __##name##_thermal_table = .;                                   \
 313         KEEP(*(__##name##_thermal_table))                               \
 314         __##name##_thermal_table_end = .;
 315 #else
 316 #define THERMAL_TABLE(name)
 317 #endif
 318
 319 #ifdef CONFIG_DTPM
 320 #define DTPM_TABLE()                                                    \
 321         . = ALIGN(8);                                                   \
 322         __dtpm_table = .;                                               \
 323         KEEP(*(__dtpm_table))                                           \
 324         __dtpm_table_end = .;
 325 #else
 326 #define DTPM_TABLE()
 327 #endif
 328
 329 #define KERNEL_DTB()                                                    \
 330         STRUCT_ALIGN();                                                 \
 331         __dtb_start = .;                                                \
 332         KEEP(*(.dtb.init.rodata))                                       \
 333         __dtb_end = .;
 334
 335 /*
 336  * .data section
 337  */
 338 #define DATA_DATA                                                       \
 339         *(.xiptext)                                                     \
 340         *(DATA_MAIN)                                                    \
 341         *(.ref.data)                                                    \
 342         *(.data..shared_aligned) /* percpu related */                   \
 343         MEM_KEEP(init.data*)                                            \
 344         MEM_KEEP(exit.data*)                                            \
 345         *(.data.unlikely)                                               \
 346         __start_once = .;                                               \
 347         *(.data.once)                                                   \
 348         __end_once = .;                                                 \
 349         STRUCT_ALIGN();                                                 \
 350         *(__tracepoints)                                                \
 351         /* implement dynamic printk debug */                            \
 352         . = ALIGN(8);                                                   \
 353         __start___dyndbg = .;                                           \
 354         KEEP(*(__dyndbg))                                               \
 355         __stop___dyndbg = .;                                            \
 356         LIKELY_PROFILE()                                                \
 357         BRANCH_PROFILE()                                                \
 358         TRACE_PRINTKS()                                                 \
 359         BPF_RAW_TP()                                                    \
 360         TRACEPOINT_STR()
 361
 362 /*
 363  * Data section helpers
 364  */
 365 #define NOSAVE_DATA                                                     \
 366         . = ALIGN(PAGE_SIZE);                                           \
 367         __nosave_begin = .;                                             \
 368         *(.data..nosave)                                                \
 369         . = ALIGN(PAGE_SIZE);                                           \
 370         __nosave_end = .;
 371
 372 #define PAGE_ALIGNED_DATA(page_align)                                   \
 373         . = ALIGN(page_align);                                          \
 374         *(.data..page_aligned)                                          \
 375         . = ALIGN(page_align);
 376
 377 #define READ_MOSTLY_DATA(align)                                         \
 378         . = ALIGN(align);                                               \
 379         *(.data..read_mostly)                                           \
 380         . = ALIGN(align);
 381
 382 #define CACHELINE_ALIGNED_DATA(align)                                   \
 383         . = ALIGN(align);                                               \
 384         *(.data..cacheline_aligned)
 385
 386 #define INIT_TASK_DATA(align)                                           \
 387         . = ALIGN(align);                                               \
 388         __start_init_task = .;                                          \
 389         init_thread_union = .;                                          \
 390         init_stack = .;                                                 \
 391         KEEP(*(.data..init_task))                                       \
 392         KEEP(*(.data..init_thread_info))                                \
 393         . = __start_init_task + THREAD_SIZE;                            \
 394         __end_init_task = .;
 395
 396 #define JUMP_TABLE_DATA                                                 \
 397         . = ALIGN(8);                                                   \
 398         __start___jump_table = .;                                       \
 399         KEEP(*(__jump_table))                                           \
 400         __stop___jump_table = .;
 401
 402 #define STATIC_CALL_DATA                                                \
 403         . = ALIGN(8);                                                   \
 404         __start_static_call_sites = .;                                  \
 405         KEEP(*(.static_call_sites))                                     \
 406         __stop_static_call_sites = .;
 407
 408 /*
 409  * Allow architectures to handle ro_after_init data on their
 410  * own by defining an empty RO_AFTER_INIT_DATA.
 411  */
 412 #ifndef RO_AFTER_INIT_DATA
 413 #define RO_AFTER_INIT_DATA                                              \
 414         . = ALIGN(8);                                                   \
 415         __start_ro_after_init = .;                                      \
 416         *(.data..ro_after_init)                                         \
 417         JUMP_TABLE_DATA                                                 \
 418         STATIC_CALL_DATA                                                \
 419         __end_ro_after_init = .;
 420 #endif
 421
 422 /*
 423  * Read only Data
 424  */
 425 #define RO_DATA(align)                                                  \
 426         . = ALIGN((align));                                             \
 427         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
 428                 __start_rodata = .;                                     \
 429                 *(.rodata) *(.rodata.*)                                 \
 430                 SCHED_DATA                                              \
 431                 RO_AFTER_INIT_DATA      /* Read only after init */      \
 432                 . = ALIGN(8);                                           \
 433                 __start___tracepoints_ptrs = .;                         \
 434                 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
 435                 __stop___tracepoints_ptrs = .;                          \
 436                 *(__tracepoints_strings)/* Tracepoints: strings */      \
 437         }                                                               \
 438                                                                         \
 439         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
 440                 *(.rodata1)                                             \
 441         }                                                               \
 442                                                                         \
 443         /* PCI quirks */                                                \
 444         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
 445                 __start_pci_fixups_early = .;                           \
 446                 KEEP(*(.pci_fixup_early))                               \
 447                 __end_pci_fixups_early = .;                             \
 448                 __start_pci_fixups_header = .;                          \
 449                 KEEP(*(.pci_fixup_header))                              \
 450                 __end_pci_fixups_header = .;                            \
 451                 __start_pci_fixups_final = .;                           \
 452                 KEEP(*(.pci_fixup_final))                               \
 453                 __end_pci_fixups_final = .;                             \
 454                 __start_pci_fixups_enable = .;                          \
 455                 KEEP(*(.pci_fixup_enable))                              \
 456                 __end_pci_fixups_enable = .;                            \
 457                 __start_pci_fixups_resume = .;                          \
 458                 KEEP(*(.pci_fixup_resume))                              \
 459                 __end_pci_fixups_resume = .;                            \
 460                 __start_pci_fixups_resume_early = .;                    \
 461                 KEEP(*(.pci_fixup_resume_early))                        \
 462                 __end_pci_fixups_resume_early = .;                      \
 463                 __start_pci_fixups_suspend = .;                         \
 464                 KEEP(*(.pci_fixup_suspend))                             \
 465                 __end_pci_fixups_suspend = .;                           \
 466                 __start_pci_fixups_suspend_late = .;                    \
 467                 KEEP(*(.pci_fixup_suspend_late))                        \
 468                 __end_pci_fixups_suspend_late = .;                      \
 469         }                                                               \
 470                                                                         \
 471         /* Built-in firmware blobs */                                   \
 472         .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) ALIGN(8) {    \
 473                 __start_builtin_fw = .;                                 \
 474                 KEEP(*(.builtin_fw))                                    \
 475                 __end_builtin_fw = .;                                   \
 476         }                                                               \
 477                                                                         \
 478         TRACEDATA                                                       \
 479                                                                         \
 480         /* Kernel symbol table: Normal symbols */                       \
 481         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
 482                 __start___ksymtab = .;                                  \
 483                 KEEP(*(SORT(___ksymtab+*)))                             \
 484                 __stop___ksymtab = .;                                   \
 485         }                                                               \
 486                                                                         \
 487         /* Kernel symbol table: GPL-only symbols */                     \
 488         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
 489                 __start___ksymtab_gpl = .;                              \
 490                 KEEP(*(SORT(___ksymtab_gpl+*)))                         \
 491                 __stop___ksymtab_gpl = .;                               \
 492         }                                                               \
 493                                                                         \
 494         /* Kernel symbol table: Normal unused symbols */                \
 495         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
 496                 __start___ksymtab_unused = .;                           \
 497                 KEEP(*(SORT(___ksymtab_unused+*)))                      \
 498                 __stop___ksymtab_unused = .;                            \
 499         }                                                               \
 500                                                                         \
 501         /* Kernel symbol table: GPL-only unused symbols */              \
 502         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
 503                 __start___ksymtab_unused_gpl = .;                       \
 504                 KEEP(*(SORT(___ksymtab_unused_gpl+*)))                  \
 505                 __stop___ksymtab_unused_gpl = .;                        \
 506         }                                                               \
 507                                                                         \
 508         /* Kernel symbol table: GPL-future-only symbols */              \
 509         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
 510                 __start___ksymtab_gpl_future = .;                       \
 511                 KEEP(*(SORT(___ksymtab_gpl_future+*)))                  \
 512                 __stop___ksymtab_gpl_future = .;                        \
 513         }                                                               \
 514                                                                         \
 515         /* Kernel symbol table: Normal symbols */                       \
 516         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
 517                 __start___kcrctab = .;                                  \
 518                 KEEP(*(SORT(___kcrctab+*)))                             \
 519                 __stop___kcrctab = .;                                   \
 520         }                                                               \
 521                                                                         \
 522         /* Kernel symbol table: GPL-only symbols */                     \
 523         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
 524                 __start___kcrctab_gpl = .;                              \
 525                 KEEP(*(SORT(___kcrctab_gpl+*)))                         \
 526                 __stop___kcrctab_gpl = .;                               \
 527         }                                                               \
 528                                                                         \
 529         /* Kernel symbol table: Normal unused symbols */                \
 530         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
 531                 __start___kcrctab_unused = .;                           \
 532                 KEEP(*(SORT(___kcrctab_unused+*)))                      \
 533                 __stop___kcrctab_unused = .;                            \
 534         }                                                               \
 535                                                                         \
 536         /* Kernel symbol table: GPL-only unused symbols */              \
 537         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
 538                 __start___kcrctab_unused_gpl = .;                       \
 539                 KEEP(*(SORT(___kcrctab_unused_gpl+*)))                  \
 540                 __stop___kcrctab_unused_gpl = .;                        \
 541         }                                                               \
 542                                                                         \
 543         /* Kernel symbol table: GPL-future-only symbols */              \
 544         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
 545                 __start___kcrctab_gpl_future = .;                       \
 546                 KEEP(*(SORT(___kcrctab_gpl_future+*)))                  \
 547                 __stop___kcrctab_gpl_future = .;                        \
 548         }                                                               \
 549                                                                         \
 550         /* Kernel symbol table: strings */                              \
 551         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
 552                 *(__ksymtab_strings)                                    \
 553         }                                                               \
 554                                                                         \
 555         /* __*init sections */                                          \
 556         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
 557                 *(.ref.rodata)                                          \
 558                 MEM_KEEP(init.rodata)                                   \
 559                 MEM_KEEP(exit.rodata)                                   \
 560         }                                                               \
 561                                                                         \
 562         /* Built-in module parameters. */                               \
 563         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
 564                 __start___param = .;                                    \
 565                 KEEP(*(__param))                                        \
 566                 __stop___param = .;                                     \
 567         }                                                               \
 568                                                                         \
 569         /* Built-in module versions. */                                 \
 570         __modver : AT(ADDR(__modver) - LOAD_OFFSET) {                   \
 571                 __start___modver = .;                                   \
 572                 KEEP(*(__modver))                                       \
 573                 __stop___modver = .;                                    \
 574         }                                                               \
 575                                                                         \
 576         RO_EXCEPTION_TABLE                                              \
 577         NOTES                                                           \
 578         BTF                                                             \
 579                                                                         \
 580         . = ALIGN((align));                                             \
 581         __end_rodata = .;
 582
 583 /*
 584  * Non-instrumentable text section
 585  */
 586 #define NOINSTR_TEXT                                                    \
 587                 ALIGN_FUNCTION();                                       \
 588                 __noinstr_text_start = .;                               \
 589                 *(.noinstr.text)                                        \
 590                 __noinstr_text_end = .;
 591
 592 /*
 593  * .text section. Map to function alignment to avoid address changes
 594  * during second ld run in second ld pass when generating System.map
 595  *
 596  * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
 597  * code elimination is enabled, so these sections should be converted
 598  * to use ".." first.
 599  */
 600 #define TEXT_TEXT                                                       \
 601                 ALIGN_FUNCTION();                                       \
 602                 *(.text.hot .text.hot.*)                                \
 603                 *(TEXT_MAIN .text.fixup)                                \
 604                 *(.text.unlikely .text.unlikely.*)                      \
 605                 *(.text.unknown .text.unknown.*)                        \
 606                 NOINSTR_TEXT                                            \
 607                 *(.text..refcount)                                      \
 608                 *(.ref.text)                                            \
 609         MEM_KEEP(init.text*)                                            \
 610         MEM_KEEP(exit.text*)                                            \
 611
 612
 613 /* sched.text is aling to function alignment to secure we have same
 614  * address even at second ld pass when generating System.map */
 615 #define SCHED_TEXT                                                      \
 616                 ALIGN_FUNCTION();                                       \
 617                 __sched_text_start = .;                                 \
 618                 *(.sched.text)                                          \
 619                 __sched_text_end = .;
 620
 621 /* spinlock.text is aling to function alignment to secure we have same
 622  * address even at second ld pass when generating System.map */
 623 #define LOCK_TEXT                                                       \
 624                 ALIGN_FUNCTION();                                       \
 625                 __lock_text_start = .;                                  \
 626                 *(.spinlock.text)                                       \
 627                 __lock_text_end = .;
 628
 629 #define CPUIDLE_TEXT                                                    \
 630                 ALIGN_FUNCTION();                                       \
 631                 __cpuidle_text_start = .;                               \
 632                 *(.cpuidle.text)                                        \
 633                 __cpuidle_text_end = .;
 634
 635 #define KPROBES_TEXT                                                    \
 636                 ALIGN_FUNCTION();                                       \
 637                 __kprobes_text_start = .;                               \
 638                 *(.kprobes.text)                                        \
 639                 __kprobes_text_end = .;
 640
 641 #define ENTRY_TEXT                                                      \
 642                 ALIGN_FUNCTION();                                       \
 643                 __entry_text_start = .;                                 \
 644                 *(.entry.text)                                          \
 645                 __entry_text_end = .;
 646
 647 #define IRQENTRY_TEXT                                                   \
 648                 ALIGN_FUNCTION();                                       \
 649                 __irqentry_text_start = .;                              \
 650                 *(.irqentry.text)                                       \
 651                 __irqentry_text_end = .;
 652
 653 #define SOFTIRQENTRY_TEXT                                               \
 654                 ALIGN_FUNCTION();                                       \
 655                 __softirqentry_text_start = .;                          \
 656                 *(.softirqentry.text)                                   \
 657                 __softirqentry_text_end = .;
 658
 659 #define STATIC_CALL_TEXT                                                \
 660                 ALIGN_FUNCTION();                                       \
 661                 __static_call_text_start = .;                           \
 662                 *(.static_call.text)                                    \
 663                 __static_call_text_end = .;
 664
 665 /* Section used for early init (in .S files) */
 666 #define HEAD_TEXT  KEEP(*(.head.text))
 667
 668 #define HEAD_TEXT_SECTION                                                       \
 669         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {               \
 670                 HEAD_TEXT                                               \
 671         }
 672
 673 /*
 674  * Exception table
 675  */
 676 #define EXCEPTION_TABLE(align)                                          \
 677         . = ALIGN(align);                                               \
 678         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {               \
 679                 __start___ex_table = .;                                 \
 680                 KEEP(*(__ex_table))                                     \
 681                 __stop___ex_table = .;                                  \
 682         }
 683
 684 /*
 685  * .BTF
 686  */
 687 #ifdef CONFIG_DEBUG_INFO_BTF
 688 #define BTF                                                             \
 689         .BTF : AT(ADDR(.BTF) - LOAD_OFFSET) {                           \
 690                 __start_BTF = .;                                        \
 691                 KEEP(*(.BTF))                                           \
 692                 __stop_BTF = .;                                         \
 693         }                                                               \
 694         . = ALIGN(4);                                                   \
 695         .BTF_ids : AT(ADDR(.BTF_ids) - LOAD_OFFSET) {                   \
 696                 *(.BTF_ids)                                             \
 697         }
 698 #else
 699 #define BTF
 700 #endif
 701
 702 /*
 703  * Init task
 704  */
 705 #define INIT_TASK_DATA_SECTION(align)                                   \
 706         . = ALIGN(align);                                               \
 707         .data..init_task :  AT(ADDR(.data..init_task) - LOAD_OFFSET) {  \
 708                 INIT_TASK_DATA(align)                                   \
 709         }
 710
 711 #ifdef CONFIG_CONSTRUCTORS
 712 #define KERNEL_CTORS()  . = ALIGN(8);                      \
 713                         __ctors_start = .;                 \
 714                         KEEP(*(SORT(.ctors.*)))            \
 715                         KEEP(*(.ctors))                    \
 716                         KEEP(*(SORT(.init_array.*)))       \
 717                         KEEP(*(.init_array))               \
 718                         __ctors_end = .;
 719 #else
 720 #define KERNEL_CTORS()
 721 #endif
 722
 723 /* init and exit section handling */
 724 #define INIT_DATA                                                       \
 725         KEEP(*(SORT(___kentry+*)))                                      \
 726         *(.init.data init.data.*)                                       \
 727         MEM_DISCARD(init.data*)                                         \
 728         KERNEL_CTORS()                                                  \
 729         MCOUNT_REC()                                                    \
 730         *(.init.rodata .init.rodata.*)                                  \
 731         FTRACE_EVENTS()                                                 \
 732         TRACE_SYSCALLS()                                                \
 733         KPROBE_BLACKLIST()                                              \
 734         ERROR_INJECT_WHITELIST()                                        \
 735         MEM_DISCARD(init.rodata)                                        \
 736         CLK_OF_TABLES()                                                 \
 737         RESERVEDMEM_OF_TABLES()                                         \
 738         TIMER_OF_TABLES()                                               \
 739         CPU_METHOD_OF_TABLES()                                          \
 740         CPUIDLE_METHOD_OF_TABLES()                                      \
 741         KERNEL_DTB()                                                    \
 742         IRQCHIP_OF_MATCH_TABLE()                                        \
 743         ACPI_PROBE_TABLE(irqchip)                                       \
 744         ACPI_PROBE_TABLE(timer)                                         \
 745         THERMAL_TABLE(governor)                                         \
 746         DTPM_TABLE()                                                    \
 747         EARLYCON_TABLE()                                                \
 748         LSM_TABLE()                                                     \
 749         EARLY_LSM_TABLE()                                               \
 750         KUNIT_TABLE()
 751
 752 #define INIT_TEXT                                                       \
 753         *(.init.text .init.text.*)                                      \
 754         *(.text.startup)                                                \
 755         MEM_DISCARD(init.text*)
 756
 757 #define EXIT_DATA                                                       \
 758         *(.exit.data .exit.data.*)                                      \
 759         *(.fini_array .fini_array.*)                                    \
 760         *(.dtors .dtors.*)                                              \
 761         MEM_DISCARD(exit.data*)                                         \
 762         MEM_DISCARD(exit.rodata*)
 763
 764 #define EXIT_TEXT                                                       \
 765         *(.exit.text)                                                   \
 766         *(.text.exit)                                                   \
 767         MEM_DISCARD(exit.text)
 768
 769 #define EXIT_CALL                                                       \
 770         *(.exitcall.exit)
 771
 772 /*
 773  * bss (Block Started by Symbol) - uninitialized data
 774  * zeroed during startup
 775  */
 776 #define SBSS(sbss_align)                                                \
 777         . = ALIGN(sbss_align);                                          \
 778         .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) {                         \
 779                 *(.dynsbss)                                             \
 780                 *(SBSS_MAIN)                                            \
 781                 *(.scommon)                                             \
 782         }
 783
 784 /*
 785  * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
 786  * sections to the front of bss.
 787  */
 788 #ifndef BSS_FIRST_SECTIONS
 789 #define BSS_FIRST_SECTIONS
 790 #endif
 791
 792 #define BSS(bss_align)                                                  \
 793         . = ALIGN(bss_align);                                           \
 794         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {                           \
 795                 BSS_FIRST_SECTIONS                                      \
 796                 . = ALIGN(PAGE_SIZE);                                   \
 797                 *(.bss..page_aligned)                                   \
 798                 . = ALIGN(PAGE_SIZE);                                   \
 799                 *(.dynbss)                                              \
 800                 *(BSS_MAIN)                                             \
 801                 *(COMMON)                                               \
 802         }
 803
 804 /*
 805  * DWARF debug sections.
 806  * Symbols in the DWARF debugging sections are relative to
 807  * the beginning of the section so we begin them at 0.
 808  */
 809 #define DWARF_DEBUG                                                     \
 810                 /* DWARF 1 */                                           \
 811                 .debug          0 : { *(.debug) }                       \
 812                 .line           0 : { *(.line) }                        \
 813                 /* GNU DWARF 1 extensions */                            \
 814                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
 815                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
 816                 /* DWARF 1.1 and DWARF 2 */                             \
 817                 .debug_aranges  0 : { *(.debug_aranges) }               \
 818                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
 819                 /* DWARF 2 */                                           \
 820                 .debug_info     0 : { *(.debug_info                     \
 821                                 .gnu.linkonce.wi.*) }                   \
 822                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
 823                 .debug_line     0 : { *(.debug_line) }                  \
 824                 .debug_frame    0 : { *(.debug_frame) }                 \
 825                 .debug_str      0 : { *(.debug_str) }                   \
 826                 .debug_loc      0 : { *(.debug_loc) }                   \
 827                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
 828                 .debug_pubtypes 0 : { *(.debug_pubtypes) }              \
 829                 /* DWARF 3 */                                           \
 830                 .debug_ranges   0 : { *(.debug_ranges) }                \
 831                 /* SGI/MIPS DWARF 2 extensions */                       \
 832                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
 833                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
 834                 .debug_typenames 0 : { *(.debug_typenames) }            \
 835                 .debug_varnames  0 : { *(.debug_varnames) }             \
 836                 /* GNU DWARF 2 extensions */                            \
 837                 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) }      \
 838                 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) }      \
 839                 /* DWARF 4 */                                           \
 840                 .debug_types    0 : { *(.debug_types) }                 \
 841                 /* DWARF 5 */                                           \
 842                 .debug_macro    0 : { *(.debug_macro) }                 \
 843                 .debug_addr     0 : { *(.debug_addr) }
 844
 845 /* Stabs debugging sections. */
 846 #define STABS_DEBUG                                                     \
 847                 .stab 0 : { *(.stab) }                                  \
 848                 .stabstr 0 : { *(.stabstr) }                            \
 849                 .stab.excl 0 : { *(.stab.excl) }                        \
 850                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
 851                 .stab.index 0 : { *(.stab.index) }                      \
 852                 .stab.indexstr 0 : { *(.stab.indexstr) }
 853
 854 /* Required sections not related to debugging. */
 855 #define ELF_DETAILS                                                     \
 856                 .comment 0 : { *(.comment) }                            \
 857                 .symtab 0 : { *(.symtab) }                              \
 858                 .strtab 0 : { *(.strtab) }                              \
 859                 .shstrtab 0 : { *(.shstrtab) }
 860
 861 #ifdef CONFIG_GENERIC_BUG
 862 #define BUG_TABLE                                                       \
 863         . = ALIGN(8);                                                   \
 864         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
 865                 __start___bug_table = .;                                \
 866                 KEEP(*(__bug_table))                                    \
 867                 __stop___bug_table = .;                                 \
 868         }
 869 #else
 870 #define BUG_TABLE
 871 #endif
 872
 873 #ifdef CONFIG_UNWINDER_ORC
 874 #define ORC_UNWIND_TABLE                                                \
 875         . = ALIGN(4);                                                   \
 876         .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) {       \
 877                 __start_orc_unwind_ip = .;                              \
 878                 KEEP(*(.orc_unwind_ip))                                 \
 879                 __stop_orc_unwind_ip = .;                               \
 880         }                                                               \
 881         . = ALIGN(2);                                                   \
 882         .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) {             \
 883                 __start_orc_unwind = .;                                 \
 884                 KEEP(*(.orc_unwind))                                    \
 885                 __stop_orc_unwind = .;                                  \
 886         }                                                               \
 887         . = ALIGN(4);                                                   \
 888         .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) {             \
 889                 orc_lookup = .;                                         \
 890                 . += (((SIZEOF(.text) + LOOKUP_BLOCK_SIZE - 1) /        \
 891                         LOOKUP_BLOCK_SIZE) + 1) * 4;                    \
 892                 orc_lookup_end = .;                                     \
 893         }
 894 #else
 895 #define ORC_UNWIND_TABLE
 896 #endif
 897
 898 #ifdef CONFIG_PM_TRACE
 899 #define TRACEDATA                                                       \
 900         . = ALIGN(4);                                                   \
 901         .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {               \
 902                 __tracedata_start = .;                                  \
 903                 KEEP(*(.tracedata))                                     \
 904                 __tracedata_end = .;                                    \
 905         }
 906 #else
 907 #define TRACEDATA
 908 #endif
 909
 910 #define NOTES                                                           \
 911         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
 912                 __start_notes = .;                                      \
 913                 KEEP(*(.note.*))                                        \
 914                 __stop_notes = .;                                       \
 915         } NOTES_HEADERS                                                 \
 916         NOTES_HEADERS_RESTORE
 917
 918 #define INIT_SETUP(initsetup_align)                                     \
 919                 . = ALIGN(initsetup_align);                             \
 920                 __setup_start = .;                                      \
 921                 KEEP(*(.init.setup))                                    \
 922                 __setup_end = .;
 923
 924 #define INIT_CALLS_LEVEL(level)                                         \
 925                 __initcall##level##_start = .;                          \
 926                 KEEP(*(.initcall##level##.init))                        \
 927                 KEEP(*(.initcall##level##s.init))                       \
 928
 929 #define INIT_CALLS                                                      \
 930                 __initcall_start = .;                                   \
 931                 KEEP(*(.initcallearly.init))                            \
 932                 INIT_CALLS_LEVEL(0)                                     \
 933                 INIT_CALLS_LEVEL(1)                                     \
 934                 INIT_CALLS_LEVEL(2)                                     \
 935                 INIT_CALLS_LEVEL(3)                                     \
 936                 INIT_CALLS_LEVEL(4)                                     \
 937                 INIT_CALLS_LEVEL(5)                                     \
 938                 INIT_CALLS_LEVEL(rootfs)                                \
 939                 INIT_CALLS_LEVEL(6)                                     \
 940                 INIT_CALLS_LEVEL(7)                                     \
 941                 __initcall_end = .;
 942
 943 #define CON_INITCALL                                                    \
 944                 __con_initcall_start = .;                               \
 945                 KEEP(*(.con_initcall.init))                             \
 946                 __con_initcall_end = .;
 947
 948 /* Alignment must be consistent with (kunit_suite *) in include/kunit/test.h */
 949 #define KUNIT_TABLE()                                                   \
 950                 . = ALIGN(8);                                           \
 951                 __kunit_suites_start = .;                               \
 952                 KEEP(*(.kunit_test_suites))                             \
 953                 __kunit_suites_end = .;
 954
 955 #ifdef CONFIG_BLK_DEV_INITRD
 956 #define INIT_RAM_FS                                                     \
 957         . = ALIGN(4);                                                   \
 958         __initramfs_start = .;                                          \
 959         KEEP(*(.init.ramfs))                                            \
 960         . = ALIGN(8);                                                   \
 961         KEEP(*(.init.ramfs.info))
 962 #else
 963 #define INIT_RAM_FS
 964 #endif
 965
 966 /*
 967  * Memory encryption operates on a page basis. Since we need to clear
 968  * the memory encryption mask for this section, it needs to be aligned
 969  * on a page boundary and be a page-size multiple in length.
 970  *
 971  * Note: We use a separate section so that only this section gets
 972  * decrypted to avoid exposing more than we wish.
 973  */
 974 #ifdef CONFIG_AMD_MEM_ENCRYPT
 975 #define PERCPU_DECRYPTED_SECTION                                        \
 976         . = ALIGN(PAGE_SIZE);                                           \
 977         *(.data..percpu..decrypted)                                     \
 978         . = ALIGN(PAGE_SIZE);
 979 #else
 980 #define PERCPU_DECRYPTED_SECTION
 981 #endif
 982
 983
 984 /*
 985  * Default discarded sections.
 986  *
 987  * Some archs want to discard exit text/data at runtime rather than
 988  * link time due to cross-section references such as alt instructions,
 989  * bug table, eh_frame, etc.  DISCARDS must be the last of output
 990  * section definitions so that such archs put those in earlier section
 991  * definitions.
 992  */
 993 #ifdef RUNTIME_DISCARD_EXIT
 994 #define EXIT_DISCARDS
 995 #else
 996 #define EXIT_DISCARDS                                                   \
 997         EXIT_TEXT                                                       \
 998         EXIT_DATA
 999 #endif
1000
1001 /*
1002  * Clang's -fsanitize=kernel-address and -fsanitize=thread produce
1003  * unwanted sections (.eh_frame and .init_array.*), but
1004  * CONFIG_CONSTRUCTORS wants to keep any .init_array.* sections.
1005  * https://bugs.llvm.org/show_bug.cgi?id=46478
1006  */
1007 #if defined(CONFIG_KASAN_GENERIC) || defined(CONFIG_KCSAN)
1008 # ifdef CONFIG_CONSTRUCTORS
1009 #  define SANITIZER_DISCARDS                                            \
1010         *(.eh_frame)
1011 # else
1012 #  define SANITIZER_DISCARDS                                            \
1013         *(.init_array) *(.init_array.*)                                 \
1014         *(.eh_frame)
1015 # endif
1016 #else
1017 # define SANITIZER_DISCARDS
1018 #endif
1019
1020 #define COMMON_DISCARDS                                                 \
1021         SANITIZER_DISCARDS                                              \
1022         *(.discard)                                                     \
1023         *(.discard.*)                                                   \
1024         *(.modinfo)                                                     \
1025         /* ld.bfd warns about .gnu.version* even when not emitted */    \
1026         *(.gnu.version*)                                                \
1027
1028 #define DISCARDS                                                        \
1029         /DISCARD/ : {                                                   \
1030         EXIT_DISCARDS                                                   \
1031         EXIT_CALL                                                       \
1032         COMMON_DISCARDS                                                 \
1033         }
1034
1035 /**
1036  * PERCPU_INPUT - the percpu input sections
1037  * @cacheline: cacheline size
1038  *
1039  * The core percpu section names and core symbols which do not rely
1040  * directly upon load addresses.
1041  *
1042  * @cacheline is used to align subsections to avoid false cacheline
1043  * sharing between subsections for different purposes.
1044  */
1045 #define PERCPU_INPUT(cacheline)                                         \
1046         __per_cpu_start = .;                                            \
1047         *(.data..percpu..first)                                         \
1048         . = ALIGN(PAGE_SIZE);                                           \
1049         *(.data..percpu..page_aligned)                                  \
1050         . = ALIGN(cacheline);                                           \
1051         *(.data..percpu..read_mostly)                                   \
1052         . = ALIGN(cacheline);                                           \
1053         *(.data..percpu)                                                \
1054         *(.data..percpu..shared_aligned)                                \
1055         PERCPU_DECRYPTED_SECTION                                        \
1056         __per_cpu_end = .;
1057
1058 /**
1059  * PERCPU_VADDR - define output section for percpu area
1060  * @cacheline: cacheline size
1061  * @vaddr: explicit base address (optional)
1062  * @phdr: destination PHDR (optional)
1063  *
1064  * Macro which expands to output section for percpu area.
1065  *
1066  * @cacheline is used to align subsections to avoid false cacheline
1067  * sharing between subsections for different purposes.
1068  *
1069  * If @vaddr is not blank, it specifies explicit base address and all
1070  * percpu symbols will be offset from the given address.  If blank,
1071  * @vaddr always equals @laddr + LOAD_OFFSET.
1072  *
1073  * @phdr defines the output PHDR to use if not blank.  Be warned that
1074  * output PHDR is sticky.  If @phdr is specified, the next output
1075  * section in the linker script will go there too.  @phdr should have
1076  * a leading colon.
1077  *
1078  * Note that this macros defines __per_cpu_load as an absolute symbol.
1079  * If there is no need to put the percpu section at a predetermined
1080  * address, use PERCPU_SECTION.
1081  */
1082 #define PERCPU_VADDR(cacheline, vaddr, phdr)                            \
1083         __per_cpu_load = .;                                             \
1084         .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) {        \
1085                 PERCPU_INPUT(cacheline)                                 \
1086         } phdr                                                          \
1087         . = __per_cpu_load + SIZEOF(.data..percpu);
1088
1089 /**
1090  * PERCPU_SECTION - define output section for percpu area, simple version
1091  * @cacheline: cacheline size
1092  *
1093  * Align to PAGE_SIZE and outputs output section for percpu area.  This
1094  * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
1095  * __per_cpu_start will be identical.
1096  *
1097  * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
1098  * except that __per_cpu_load is defined as a relative symbol against
1099  * .data..percpu which is required for relocatable x86_32 configuration.
1100  */
1101 #define PERCPU_SECTION(cacheline)                                       \
1102         . = ALIGN(PAGE_SIZE);                                           \
1103         .data..percpu   : AT(ADDR(.data..percpu) - LOAD_OFFSET) {       \
1104                 __per_cpu_load = .;                                     \
1105                 PERCPU_INPUT(cacheline)                                 \
1106         }
1107
1108
1109 /*
1110  * Definition of the high level *_SECTION macros
1111  * They will fit only a subset of the architectures
1112  */
1113
1114
1115 /*
1116  * Writeable data.
1117  * All sections are combined in a single .data section.
1118  * The sections following CONSTRUCTORS are arranged so their
1119  * typical alignment matches.
1120  * A cacheline is typical/always less than a PAGE_SIZE so
1121  * the sections that has this restriction (or similar)
1122  * is located before the ones requiring PAGE_SIZE alignment.
1123  * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
1124  * matches the requirement of PAGE_ALIGNED_DATA.
1125  *
1126  * use 0 as page_align if page_aligned data is not used */
1127 #define RW_DATA(cacheline, pagealigned, inittask)                       \
1128         . = ALIGN(PAGE_SIZE);                                           \
1129         .data : AT(ADDR(.data) - LOAD_OFFSET) {                         \
1130                 INIT_TASK_DATA(inittask)                                \
1131                 NOSAVE_DATA                                             \
1132                 PAGE_ALIGNED_DATA(pagealigned)                          \
1133                 CACHELINE_ALIGNED_DATA(cacheline)                       \
1134                 READ_MOSTLY_DATA(cacheline)                             \
1135                 DATA_DATA                                               \
1136                 CONSTRUCTORS                                            \
1137         }                                                               \
1138         BUG_TABLE                                                       \
1139
1140 #define INIT_TEXT_SECTION(inittext_align)                               \
1141         . = ALIGN(inittext_align);                                      \
1142         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {               \
1143                 _sinittext = .;                                         \
1144                 INIT_TEXT                                               \
1145                 _einittext = .;                                         \
1146         }
1147
1148 #define INIT_DATA_SECTION(initsetup_align)                              \
1149         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {               \
1150                 INIT_DATA                                               \
1151                 INIT_SETUP(initsetup_align)                             \
1152                 INIT_CALLS                                              \
1153                 CON_INITCALL                                            \
1154                 INIT_RAM_FS                                             \
1155         }
1156
1157 #define BSS_SECTION(sbss_align, bss_align, stop_align)                  \
1158         . = ALIGN(sbss_align);                                          \
1159         __bss_start = .;                                                \
1160         SBSS(sbss_align)                                                \
1161         BSS(bss_align)                                                  \
1162         . = ALIGN(stop_align);                                          \
1163         __bss_stop = .;