arch/x86/xen/xen-head.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /* Xen-specific pieces of head.S, intended to be included in the right
   3         place in head.S */
   4
   5 #ifdef CONFIG_XEN
   6
   7 #include <linux/elfnote.h>
   8 #include <linux/init.h>
   9
  10 #include <asm/boot.h>
  11 #include <asm/asm.h>
  12 #include <asm/msr.h>
  13 #include <asm/page_types.h>
  14 #include <asm/percpu.h>
  15 #include <asm/unwind_hints.h>
  16
  17 #include <xen/interface/elfnote.h>
  18 #include <xen/interface/features.h>
  19 #include <xen/interface/xen.h>
  20 #include <xen/interface/xen-mca.h>
  21 #include <asm/xen/interface.h>
  22
  23 .pushsection .noinstr.text, "ax"
  24         .balign PAGE_SIZE
  25 SYM_CODE_START(hypercall_page)
  26         .rept (PAGE_SIZE / 32)
  27                 UNWIND_HINT_FUNC
  28                 ANNOTATE_NOENDBR
  29                 ret
  30                 /*
  31                  * Xen will write the hypercall page, and sort out ENDBR.
  32                  */
  33                 .skip 31, 0xcc
  34         .endr
  35
  36 #define HYPERCALL(n) \
  37         .equ xen_hypercall_##n, hypercall_page + __HYPERVISOR_##n * 32; \
  38         .type xen_hypercall_##n, @function; .size xen_hypercall_##n, 32
  39 #include <asm/xen-hypercalls.h>
  40 #undef HYPERCALL
  41 SYM_CODE_END(hypercall_page)
  42 .popsection
  43
  44 #ifdef CONFIG_XEN_PV
  45         __INIT
  46 SYM_CODE_START(startup_xen)
  47         UNWIND_HINT_EMPTY
  48         ANNOTATE_NOENDBR
  49         cld
  50
  51         /* Clear .bss */
  52         xor %eax,%eax
  53         mov $__bss_start, %rdi
  54         mov $__bss_stop, %rcx
  55         sub %rdi, %rcx
  56         shr $3, %rcx
  57         rep stosq
  58
  59         mov %rsi, xen_start_info
  60         mov initial_stack(%rip), %rsp
  61
  62         /* Set up %gs.
  63          *
  64          * The base of %gs always points to fixed_percpu_data.  If the
  65          * stack protector canary is enabled, it is located at %gs:40.
  66          * Note that, on SMP, the boot cpu uses init data section until
  67          * the per cpu areas are set up.
  68          */
  69         movl    $MSR_GS_BASE,%ecx
  70         movq    $INIT_PER_CPU_VAR(fixed_percpu_data),%rax
  71         cdq
  72         wrmsr
  73
  74         call xen_start_kernel
  75 SYM_CODE_END(startup_xen)
  76         __FINIT
  77
  78 #ifdef CONFIG_XEN_PV_SMP
  79 .pushsection .text
  80 SYM_CODE_START(asm_cpu_bringup_and_idle)
  81         UNWIND_HINT_EMPTY
  82         ENDBR
  83
  84         call cpu_bringup_and_idle
  85 SYM_CODE_END(asm_cpu_bringup_and_idle)
  86 .popsection
  87 #endif
  88 #endif
  89
  90         ELFNOTE(Xen, XEN_ELFNOTE_GUEST_OS,       .asciz "linux")
  91         ELFNOTE(Xen, XEN_ELFNOTE_GUEST_VERSION,  .asciz "2.6")
  92         ELFNOTE(Xen, XEN_ELFNOTE_XEN_VERSION,    .asciz "xen-3.0")
  93 #ifdef CONFIG_X86_32
  94         ELFNOTE(Xen, XEN_ELFNOTE_VIRT_BASE,      _ASM_PTR __PAGE_OFFSET)
  95 #else
  96         ELFNOTE(Xen, XEN_ELFNOTE_VIRT_BASE,      _ASM_PTR __START_KERNEL_map)
  97         /* Map the p2m table to a 512GB-aligned user address. */
  98         ELFNOTE(Xen, XEN_ELFNOTE_INIT_P2M,       .quad (PUD_SIZE * PTRS_PER_PUD))
  99 #endif
 100 #ifdef CONFIG_XEN_PV
 101         ELFNOTE(Xen, XEN_ELFNOTE_ENTRY,          _ASM_PTR startup_xen)
 102 #endif
 103         ELFNOTE(Xen, XEN_ELFNOTE_HYPERCALL_PAGE, _ASM_PTR hypercall_page)
 104         ELFNOTE(Xen, XEN_ELFNOTE_FEATURES,
 105                 .ascii "!writable_page_tables|pae_pgdir_above_4gb")
 106         ELFNOTE(Xen, XEN_ELFNOTE_SUPPORTED_FEATURES,
 107                 .long (1 << XENFEAT_writable_page_tables) |       \
 108                       (1 << XENFEAT_dom0) |                       \
 109                       (1 << XENFEAT_linux_rsdp_unrestricted))
 110         ELFNOTE(Xen, XEN_ELFNOTE_PAE_MODE,       .asciz "yes")
 111         ELFNOTE(Xen, XEN_ELFNOTE_LOADER,         .asciz "generic")
 112         ELFNOTE(Xen, XEN_ELFNOTE_L1_MFN_VALID,
 113                 .quad _PAGE_PRESENT; .quad _PAGE_PRESENT)
 114         ELFNOTE(Xen, XEN_ELFNOTE_SUSPEND_CANCEL, .long 1)
 115         ELFNOTE(Xen, XEN_ELFNOTE_MOD_START_PFN,  .long 1)
 116         ELFNOTE(Xen, XEN_ELFNOTE_HV_START_LOW,   _ASM_PTR __HYPERVISOR_VIRT_START)
 117         ELFNOTE(Xen, XEN_ELFNOTE_PADDR_OFFSET,   _ASM_PTR 0)
 118
 119 #endif /*CONFIG_XEN */