arch/x86/platform/pvh/head.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2
   3 /*
   4  * Copyright C 2016, Oracle and/or its affiliates. All rights reserved.
   5  */
   6
   7         .code32
   8         .text
   9 #define _pa(x)          ((x) - __START_KERNEL_map)
  10
  11 #include <linux/elfnote.h>
  12 #include <linux/init.h>
  13 #include <linux/linkage.h>
  14 #include <asm/segment.h>
  15 #include <asm/asm.h>
  16 #include <asm/boot.h>
  17 #include <asm/processor-flags.h>
  18 #include <asm/msr.h>
  19 #include <asm/nospec-branch.h>
  20 #include <xen/interface/elfnote.h>
  21
  22         __HEAD
  23
  24 /*
  25  * Entry point for PVH guests.
  26  *
  27  * Xen ABI specifies the following register state when we come here:
  28  *
  29  * - `ebx`: contains the physical memory address where the loader has placed
  30  *          the boot start info structure.
  31  * - `cr0`: bit 0 (PE) must be set. All the other writeable bits are cleared.
  32  * - `cr4`: all bits are cleared.
  33  * - `cs `: must be a 32-bit read/execute code segment with a base of `0`
  34  *          and a limit of `0xFFFFFFFF`. The selector value is unspecified.
  35  * - `ds`, `es`: must be a 32-bit read/write data segment with a base of
  36  *               `0` and a limit of `0xFFFFFFFF`. The selector values are all
  37  *               unspecified.
  38  * - `tr`: must be a 32-bit TSS (active) with a base of '0' and a limit
  39  *         of '0x67'.
  40  * - `eflags`: bit 17 (VM) must be cleared. Bit 9 (IF) must be cleared.
  41  *             Bit 8 (TF) must be cleared. Other bits are all unspecified.
  42  *
  43  * All other processor registers and flag bits are unspecified. The OS is in
  44  * charge of setting up it's own stack, GDT and IDT.
  45  */
  46
  47 #define PVH_GDT_ENTRY_CS        1
  48 #define PVH_GDT_ENTRY_DS        2
  49 #define PVH_CS_SEL              (PVH_GDT_ENTRY_CS * 8)
  50 #define PVH_DS_SEL              (PVH_GDT_ENTRY_DS * 8)
  51
  52 SYM_CODE_START_LOCAL(pvh_start_xen)
  53         cld
  54
  55         lgdt (_pa(gdt))
  56
  57         mov $PVH_DS_SEL,%eax
  58         mov %eax,%ds
  59         mov %eax,%es
  60         mov %eax,%ss
  61
  62         /* Stash hvm_start_info. */
  63         mov $_pa(pvh_start_info), %edi
  64         mov %ebx, %esi
  65         mov _pa(pvh_start_info_sz), %ecx
  66         shr $2,%ecx
  67         rep
  68         movsl
  69
  70         mov $_pa(early_stack_end), %esp
  71
  72         /* Enable PAE mode. */
  73         mov %cr4, %eax
  74         orl $X86_CR4_PAE, %eax
  75         mov %eax, %cr4
  76
  77 #ifdef CONFIG_X86_64
  78         /* Enable Long mode. */
  79         mov $MSR_EFER, %ecx
  80         rdmsr
  81         btsl $_EFER_LME, %eax
  82         wrmsr
  83
  84         /* Enable pre-constructed page tables. */
  85         mov $_pa(init_top_pgt), %eax
  86         mov %eax, %cr3
  87         mov $(X86_CR0_PG | X86_CR0_PE), %eax
  88         mov %eax, %cr0
  89
  90         /* Jump to 64-bit mode. */
  91         ljmp $PVH_CS_SEL, $_pa(1f)
  92
  93         /* 64-bit entry point. */
  94         .code64
  95 1:
  96         /* Set base address in stack canary descriptor. */
  97         mov $MSR_GS_BASE,%ecx
  98         mov $_pa(canary), %eax
  99         xor %edx, %edx
 100         wrmsr
 101
 102         call xen_prepare_pvh
 103
 104         /* startup_64 expects boot_params in %rsi. */
 105         mov $_pa(pvh_bootparams), %rsi
 106         mov $_pa(startup_64), %rax
 107         ANNOTATE_RETPOLINE_SAFE
 108         jmp *%rax
 109
 110 #else /* CONFIG_X86_64 */
 111
 112         call mk_early_pgtbl_32
 113
 114         mov $_pa(initial_page_table), %eax
 115         mov %eax, %cr3
 116
 117         mov %cr0, %eax
 118         or $(X86_CR0_PG | X86_CR0_PE), %eax
 119         mov %eax, %cr0
 120
 121         ljmp $PVH_CS_SEL, $1f
 122 1:
 123         call xen_prepare_pvh
 124         mov $_pa(pvh_bootparams), %esi
 125
 126         /* startup_32 doesn't expect paging and PAE to be on. */
 127         ljmp $PVH_CS_SEL, $_pa(2f)
 128 2:
 129         mov %cr0, %eax
 130         and $~X86_CR0_PG, %eax
 131         mov %eax, %cr0
 132         mov %cr4, %eax
 133         and $~X86_CR4_PAE, %eax
 134         mov %eax, %cr4
 135
 136         ljmp $PVH_CS_SEL, $_pa(startup_32)
 137 #endif
 138 SYM_CODE_END(pvh_start_xen)
 139
 140         .section ".init.data","aw"
 141         .balign 8
 142 SYM_DATA_START_LOCAL(gdt)
 143         .word gdt_end - gdt_start
 144         .long _pa(gdt_start)
 145         .word 0
 146 SYM_DATA_END(gdt)
 147 SYM_DATA_START_LOCAL(gdt_start)
 148         .quad 0x0000000000000000            /* NULL descriptor */
 149 #ifdef CONFIG_X86_64
 150         .quad GDT_ENTRY(0xa09a, 0, 0xfffff) /* PVH_CS_SEL */
 151 #else
 152         .quad GDT_ENTRY(0xc09a, 0, 0xfffff) /* PVH_CS_SEL */
 153 #endif
 154         .quad GDT_ENTRY(0xc092, 0, 0xfffff) /* PVH_DS_SEL */
 155 SYM_DATA_END_LABEL(gdt_start, SYM_L_LOCAL, gdt_end)
 156
 157         .balign 16
 158 SYM_DATA_LOCAL(canary, .fill 48, 1, 0)
 159
 160 SYM_DATA_START_LOCAL(early_stack)
 161         .fill BOOT_STACK_SIZE, 1, 0
 162 SYM_DATA_END_LABEL(early_stack, SYM_L_LOCAL, early_stack_end)
 163
 164         ELFNOTE(Xen, XEN_ELFNOTE_PHYS32_ENTRY,
 165                      _ASM_PTR (pvh_start_xen - __START_KERNEL_map))