arch/x86/kernel/ftrace_64.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  *  Copyright (C) 2014  Steven Rostedt, Red Hat Inc
   4  */
   5
   6 #include <linux/linkage.h>
   7 #include <asm/ptrace.h>
   8 #include <asm/ftrace.h>
   9 #include <asm/export.h>
  10 #include <asm/nospec-branch.h>
  11 #include <asm/unwind_hints.h>
  12 #include <asm/frame.h>
  13
  14         .code64
  15         .section .text, "ax"
  16
  17 #ifdef CONFIG_FRAME_POINTER
  18 /* Save parent and function stack frames (rip and rbp) */
  19 #  define MCOUNT_FRAME_SIZE     (8+16*2)
  20 #else
  21 /* No need to save a stack frame */
  22 # define MCOUNT_FRAME_SIZE      0
  23 #endif /* CONFIG_FRAME_POINTER */
  24
  25 /* Size of stack used to save mcount regs in save_mcount_regs */
  26 #define MCOUNT_REG_SIZE         (FRAME_SIZE + MCOUNT_FRAME_SIZE)
  27
  28 /*
  29  * gcc -pg option adds a call to 'mcount' in most functions.
  30  * When -mfentry is used, the call is to 'fentry' and not 'mcount'
  31  * and is done before the function's stack frame is set up.
  32  * They both require a set of regs to be saved before calling
  33  * any C code and restored before returning back to the function.
  34  *
  35  * On boot up, all these calls are converted into nops. When tracing
  36  * is enabled, the call can jump to either ftrace_caller or
  37  * ftrace_regs_caller. Callbacks (tracing functions) that require
  38  * ftrace_regs_caller (like kprobes) need to have pt_regs passed to
  39  * it. For this reason, the size of the pt_regs structure will be
  40  * allocated on the stack and the required mcount registers will
  41  * be saved in the locations that pt_regs has them in.
  42  */
  43
  44 /*
  45  * @added: the amount of stack added before calling this
  46  *
  47  * After this is called, the following registers contain:
  48  *
  49  *  %rdi - holds the address that called the trampoline
  50  *  %rsi - holds the parent function (traced function's return address)
  51  *  %rdx - holds the original %rbp
  52  */
  53 .macro save_mcount_regs added=0
  54
  55 #ifdef CONFIG_FRAME_POINTER
  56         /* Save the original rbp */
  57         pushq %rbp
  58
  59         /*
  60          * Stack traces will stop at the ftrace trampoline if the frame pointer
  61          * is not set up properly. If fentry is used, we need to save a frame
  62          * pointer for the parent as well as the function traced, because the
  63          * fentry is called before the stack frame is set up, where as mcount
  64          * is called afterward.
  65          */
  66
  67         /* Save the parent pointer (skip orig rbp and our return address) */
  68         pushq \added+8*2(%rsp)
  69         pushq %rbp
  70         movq %rsp, %rbp
  71         /* Save the return address (now skip orig rbp, rbp and parent) */
  72         pushq \added+8*3(%rsp)
  73         pushq %rbp
  74         movq %rsp, %rbp
  75 #endif /* CONFIG_FRAME_POINTER */
  76
  77         /*
  78          * We add enough stack to save all regs.
  79          */
  80         subq $(FRAME_SIZE), %rsp
  81         movq %rax, RAX(%rsp)
  82         movq %rcx, RCX(%rsp)
  83         movq %rdx, RDX(%rsp)
  84         movq %rsi, RSI(%rsp)
  85         movq %rdi, RDI(%rsp)
  86         movq %r8, R8(%rsp)
  87         movq %r9, R9(%rsp)
  88         movq $0, ORIG_RAX(%rsp)
  89         /*
  90          * Save the original RBP. Even though the mcount ABI does not
  91          * require this, it helps out callers.
  92          */
  93 #ifdef CONFIG_FRAME_POINTER
  94         movq MCOUNT_REG_SIZE-8(%rsp), %rdx
  95 #else
  96         movq %rbp, %rdx
  97 #endif
  98         movq %rdx, RBP(%rsp)
  99
 100         /* Copy the parent address into %rsi (second parameter) */
 101         movq MCOUNT_REG_SIZE+8+\added(%rsp), %rsi
 102
 103          /* Move RIP to its proper location */
 104         movq MCOUNT_REG_SIZE+\added(%rsp), %rdi
 105         movq %rdi, RIP(%rsp)
 106
 107         /*
 108          * Now %rdi (the first parameter) has the return address of
 109          * where ftrace_call returns. But the callbacks expect the
 110          * address of the call itself.
 111          */
 112         subq $MCOUNT_INSN_SIZE, %rdi
 113         .endm
 114
 115 .macro restore_mcount_regs save=0
 116
 117         /* ftrace_regs_caller or frame pointers require this */
 118         movq RBP(%rsp), %rbp
 119
 120         movq R9(%rsp), %r9
 121         movq R8(%rsp), %r8
 122         movq RDI(%rsp), %rdi
 123         movq RSI(%rsp), %rsi
 124         movq RDX(%rsp), %rdx
 125         movq RCX(%rsp), %rcx
 126         movq RAX(%rsp), %rax
 127
 128         addq $MCOUNT_REG_SIZE-\save, %rsp
 129
 130         .endm
 131
 132 #ifdef CONFIG_DYNAMIC_FTRACE
 133
 134 SYM_FUNC_START(__fentry__)
 135         RET
 136 SYM_FUNC_END(__fentry__)
 137 EXPORT_SYMBOL(__fentry__)
 138
 139 SYM_FUNC_START(ftrace_caller)
 140         /* save_mcount_regs fills in first two parameters */
 141         save_mcount_regs
 142
 143         /* Stack - skipping return address of ftrace_caller */
 144         leaq MCOUNT_REG_SIZE+8(%rsp), %rcx
 145         movq %rcx, RSP(%rsp)
 146
 147 SYM_INNER_LABEL(ftrace_caller_op_ptr, SYM_L_GLOBAL)
 148         ANNOTATE_NOENDBR
 149         /* Load the ftrace_ops into the 3rd parameter */
 150         movq function_trace_op(%rip), %rdx
 151
 152         /* regs go into 4th parameter */
 153         leaq (%rsp), %rcx
 154
 155         /* Only ops with REGS flag set should have CS register set */
 156         movq $0, CS(%rsp)
 157
 158 SYM_INNER_LABEL(ftrace_call, SYM_L_GLOBAL)
 159         ANNOTATE_NOENDBR
 160         call ftrace_stub
 161
 162         /* Handlers can change the RIP */
 163         movq RIP(%rsp), %rax
 164         movq %rax, MCOUNT_REG_SIZE(%rsp)
 165
 166         restore_mcount_regs
 167
 168         /*
 169          * The code up to this label is copied into trampolines so
 170          * think twice before adding any new code or changing the
 171          * layout here.
 172          */
 173 SYM_INNER_LABEL(ftrace_caller_end, SYM_L_GLOBAL)
 174         ANNOTATE_NOENDBR
 175
 176         jmp ftrace_epilogue
 177 SYM_FUNC_END(ftrace_caller);
 178 STACK_FRAME_NON_STANDARD_FP(ftrace_caller)
 179
 180 SYM_FUNC_START(ftrace_epilogue)
 181 /*
 182  * This is weak to keep gas from relaxing the jumps.
 183  */
 184 SYM_INNER_LABEL_ALIGN(ftrace_stub, SYM_L_WEAK)
 185         UNWIND_HINT_FUNC
 186         ENDBR
 187         RET
 188 SYM_FUNC_END(ftrace_epilogue)
 189
 190 SYM_FUNC_START(ftrace_regs_caller)
 191         /* Save the current flags before any operations that can change them */
 192         pushfq
 193
 194         /* added 8 bytes to save flags */
 195         save_mcount_regs 8
 196         /* save_mcount_regs fills in first two parameters */
 197
 198 SYM_INNER_LABEL(ftrace_regs_caller_op_ptr, SYM_L_GLOBAL)
 199         ANNOTATE_NOENDBR
 200         /* Load the ftrace_ops into the 3rd parameter */
 201         movq function_trace_op(%rip), %rdx
 202
 203         /* Save the rest of pt_regs */
 204         movq %r15, R15(%rsp)
 205         movq %r14, R14(%rsp)
 206         movq %r13, R13(%rsp)
 207         movq %r12, R12(%rsp)
 208         movq %r11, R11(%rsp)
 209         movq %r10, R10(%rsp)
 210         movq %rbx, RBX(%rsp)
 211         /* Copy saved flags */
 212         movq MCOUNT_REG_SIZE(%rsp), %rcx
 213         movq %rcx, EFLAGS(%rsp)
 214         /* Kernel segments */
 215         movq $__KERNEL_DS, %rcx
 216         movq %rcx, SS(%rsp)
 217         movq $__KERNEL_CS, %rcx
 218         movq %rcx, CS(%rsp)
 219         /* Stack - skipping return address and flags */
 220         leaq MCOUNT_REG_SIZE+8*2(%rsp), %rcx
 221         movq %rcx, RSP(%rsp)
 222
 223         ENCODE_FRAME_POINTER
 224
 225         /* regs go into 4th parameter */
 226         leaq (%rsp), %rcx
 227
 228 SYM_INNER_LABEL(ftrace_regs_call, SYM_L_GLOBAL)
 229         ANNOTATE_NOENDBR
 230         call ftrace_stub
 231
 232         /* Copy flags back to SS, to restore them */
 233         movq EFLAGS(%rsp), %rax
 234         movq %rax, MCOUNT_REG_SIZE(%rsp)
 235
 236         /* Handlers can change the RIP */
 237         movq RIP(%rsp), %rax
 238         movq %rax, MCOUNT_REG_SIZE+8(%rsp)
 239
 240         /* restore the rest of pt_regs */
 241         movq R15(%rsp), %r15
 242         movq R14(%rsp), %r14
 243         movq R13(%rsp), %r13
 244         movq R12(%rsp), %r12
 245         movq R10(%rsp), %r10
 246         movq RBX(%rsp), %rbx
 247
 248         movq ORIG_RAX(%rsp), %rax
 249         movq %rax, MCOUNT_REG_SIZE-8(%rsp)
 250
 251         /*
 252          * If ORIG_RAX is anything but zero, make this a call to that.
 253          * See arch_ftrace_set_direct_caller().
 254          */
 255         testq   %rax, %rax
 256 SYM_INNER_LABEL(ftrace_regs_caller_jmp, SYM_L_GLOBAL)
 257         ANNOTATE_NOENDBR
 258         jnz     1f
 259
 260         restore_mcount_regs
 261         /* Restore flags */
 262         popfq
 263
 264         /*
 265          * As this jmp to ftrace_epilogue can be a short jump
 266          * it must not be copied into the trampoline.
 267          * The trampoline will add the code to jump
 268          * to the return.
 269          */
 270 SYM_INNER_LABEL(ftrace_regs_caller_end, SYM_L_GLOBAL)
 271         ANNOTATE_NOENDBR
 272         jmp ftrace_epilogue
 273
 274         /* Swap the flags with orig_rax */
 275 1:      movq MCOUNT_REG_SIZE(%rsp), %rdi
 276         movq %rdi, MCOUNT_REG_SIZE-8(%rsp)
 277         movq %rax, MCOUNT_REG_SIZE(%rsp)
 278
 279         restore_mcount_regs 8
 280         /* Restore flags */
 281         popfq
 282         UNWIND_HINT_FUNC
 283         jmp     ftrace_epilogue
 284
 285 SYM_FUNC_END(ftrace_regs_caller)
 286 STACK_FRAME_NON_STANDARD_FP(ftrace_regs_caller)
 287
 288
 289 #else /* ! CONFIG_DYNAMIC_FTRACE */
 290
 291 SYM_FUNC_START(__fentry__)
 292         cmpq $ftrace_stub, ftrace_trace_function
 293         jnz trace
 294
 295 SYM_INNER_LABEL(ftrace_stub, SYM_L_GLOBAL)
 296         ENDBR
 297         RET
 298
 299 trace:
 300         /* save_mcount_regs fills in first two parameters */
 301         save_mcount_regs
 302
 303         /*
 304          * When DYNAMIC_FTRACE is not defined, ARCH_SUPPORTS_FTRACE_OPS is not
 305          * set (see include/asm/ftrace.h and include/linux/ftrace.h).  Only the
 306          * ip and parent ip are used and the list function is called when
 307          * function tracing is enabled.
 308          */
 309         movq ftrace_trace_function, %r8
 310         CALL_NOSPEC r8
 311         restore_mcount_regs
 312
 313         jmp ftrace_stub
 314 SYM_FUNC_END(__fentry__)
 315 EXPORT_SYMBOL(__fentry__)
 316 STACK_FRAME_NON_STANDARD_FP(__fentry__)
 317
 318 #endif /* CONFIG_DYNAMIC_FTRACE */
 319
 320 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 321 SYM_CODE_START(return_to_handler)
 322         UNWIND_HINT_EMPTY
 323         ANNOTATE_NOENDBR
 324         subq  $16, %rsp
 325
 326         /* Save the return values */
 327         movq %rax, (%rsp)
 328         movq %rdx, 8(%rsp)
 329         movq %rbp, %rdi
 330
 331         call ftrace_return_to_handler
 332
 333         movq %rax, %rdi
 334         movq 8(%rsp), %rdx
 335         movq (%rsp), %rax
 336
 337         addq $16, %rsp
 338         /*
 339          * Jump back to the old return address. This cannot be JMP_NOSPEC rdi
 340          * since IBT would demand that contain ENDBR, which simply isn't so for
 341          * return addresses. Use a retpoline here to keep the RSB balanced.
 342          */
 343         ANNOTATE_INTRA_FUNCTION_CALL
 344         call .Ldo_rop
 345         int3
 346 .Ldo_rop:
 347         mov %rdi, (%rsp)
 348         RET
 349 SYM_CODE_END(return_to_handler)
 350 #endif