arch/x86/kernel/ftrace_64.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  *  Copyright (C) 2014  Steven Rostedt, Red Hat Inc
   4  */
   5
   6 #include <linux/linkage.h>
   7 #include <asm/ptrace.h>
   8 #include <asm/ftrace.h>
   9 #include <asm/export.h>
  10 #include <asm/nospec-branch.h>
  11 #include <asm/unwind_hints.h>
  12 #include <asm/frame.h>
  13
  14         .code64
  15         .section .text, "ax"
  16
  17 #ifdef CONFIG_FRAME_POINTER
  18 /* Save parent and function stack frames (rip and rbp) */
  19 #  define MCOUNT_FRAME_SIZE     (8+16*2)
  20 #else
  21 /* No need to save a stack frame */
  22 # define MCOUNT_FRAME_SIZE      0
  23 #endif /* CONFIG_FRAME_POINTER */
  24
  25 /* Size of stack used to save mcount regs in save_mcount_regs */
  26 #define MCOUNT_REG_SIZE         (FRAME_SIZE + MCOUNT_FRAME_SIZE)
  27
  28 /*
  29  * gcc -pg option adds a call to 'mcount' in most functions.
  30  * When -mfentry is used, the call is to 'fentry' and not 'mcount'
  31  * and is done before the function's stack frame is set up.
  32  * They both require a set of regs to be saved before calling
  33  * any C code and restored before returning back to the function.
  34  *
  35  * On boot up, all these calls are converted into nops. When tracing
  36  * is enabled, the call can jump to either ftrace_caller or
  37  * ftrace_regs_caller. Callbacks (tracing functions) that require
  38  * ftrace_regs_caller (like kprobes) need to have pt_regs passed to
  39  * it. For this reason, the size of the pt_regs structure will be
  40  * allocated on the stack and the required mcount registers will
  41  * be saved in the locations that pt_regs has them in.
  42  */
  43
  44 /*
  45  * @added: the amount of stack added before calling this
  46  *
  47  * After this is called, the following registers contain:
  48  *
  49  *  %rdi - holds the address that called the trampoline
  50  *  %rsi - holds the parent function (traced function's return address)
  51  *  %rdx - holds the original %rbp
  52  */
  53 .macro save_mcount_regs added=0
  54
  55 #ifdef CONFIG_FRAME_POINTER
  56         /* Save the original rbp */
  57         pushq %rbp
  58
  59         /*
  60          * Stack traces will stop at the ftrace trampoline if the frame pointer
  61          * is not set up properly. If fentry is used, we need to save a frame
  62          * pointer for the parent as well as the function traced, because the
  63          * fentry is called before the stack frame is set up, where as mcount
  64          * is called afterward.
  65          */
  66
  67         /* Save the parent pointer (skip orig rbp and our return address) */
  68         pushq \added+8*2(%rsp)
  69         pushq %rbp
  70         movq %rsp, %rbp
  71         /* Save the return address (now skip orig rbp, rbp and parent) */
  72         pushq \added+8*3(%rsp)
  73         pushq %rbp
  74         movq %rsp, %rbp
  75 #endif /* CONFIG_FRAME_POINTER */
  76
  77         /*
  78          * We add enough stack to save all regs.
  79          */
  80         subq $(FRAME_SIZE), %rsp
  81         movq %rax, RAX(%rsp)
  82         movq %rcx, RCX(%rsp)
  83         movq %rdx, RDX(%rsp)
  84         movq %rsi, RSI(%rsp)
  85         movq %rdi, RDI(%rsp)
  86         movq %r8, R8(%rsp)
  87         movq %r9, R9(%rsp)
  88         movq $0, ORIG_RAX(%rsp)
  89         /*
  90          * Save the original RBP. Even though the mcount ABI does not
  91          * require this, it helps out callers.
  92          */
  93 #ifdef CONFIG_FRAME_POINTER
  94         movq MCOUNT_REG_SIZE-8(%rsp), %rdx
  95 #else
  96         movq %rbp, %rdx
  97 #endif
  98         movq %rdx, RBP(%rsp)
  99
 100         /* Copy the parent address into %rsi (second parameter) */
 101         movq MCOUNT_REG_SIZE+8+\added(%rsp), %rsi
 102
 103          /* Move RIP to its proper location */
 104         movq MCOUNT_REG_SIZE+\added(%rsp), %rdi
 105         movq %rdi, RIP(%rsp)
 106
 107         /*
 108          * Now %rdi (the first parameter) has the return address of
 109          * where ftrace_call returns. But the callbacks expect the
 110          * address of the call itself.
 111          */
 112         subq $MCOUNT_INSN_SIZE, %rdi
 113         .endm
 114
 115 .macro restore_mcount_regs save=0
 116
 117         /* ftrace_regs_caller or frame pointers require this */
 118         movq RBP(%rsp), %rbp
 119
 120         movq R9(%rsp), %r9
 121         movq R8(%rsp), %r8
 122         movq RDI(%rsp), %rdi
 123         movq RSI(%rsp), %rsi
 124         movq RDX(%rsp), %rdx
 125         movq RCX(%rsp), %rcx
 126         movq RAX(%rsp), %rax
 127
 128         addq $MCOUNT_REG_SIZE-\save, %rsp
 129
 130         .endm
 131
 132 #ifdef CONFIG_DYNAMIC_FTRACE
 133
 134 SYM_FUNC_START(__fentry__)
 135         retq
 136 SYM_FUNC_END(__fentry__)
 137 EXPORT_SYMBOL(__fentry__)
 138
 139 SYM_FUNC_START(ftrace_caller)
 140         /* save_mcount_regs fills in first two parameters */
 141         save_mcount_regs
 142
 143 SYM_INNER_LABEL(ftrace_caller_op_ptr, SYM_L_GLOBAL)
 144         /* Load the ftrace_ops into the 3rd parameter */
 145         movq function_trace_op(%rip), %rdx
 146
 147         /* regs go into 4th parameter (but make it NULL) */
 148         movq $0, %rcx
 149
 150 SYM_INNER_LABEL(ftrace_call, SYM_L_GLOBAL)
 151         call ftrace_stub
 152
 153         restore_mcount_regs
 154
 155         /*
 156          * The code up to this label is copied into trampolines so
 157          * think twice before adding any new code or changing the
 158          * layout here.
 159          */
 160 SYM_INNER_LABEL(ftrace_caller_end, SYM_L_GLOBAL)
 161
 162         jmp ftrace_epilogue
 163 SYM_FUNC_END(ftrace_caller);
 164
 165 SYM_FUNC_START(ftrace_epilogue)
 166 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 167 SYM_INNER_LABEL(ftrace_graph_call, SYM_L_GLOBAL)
 168         jmp ftrace_stub
 169 #endif
 170
 171 /*
 172  * This is weak to keep gas from relaxing the jumps.
 173  * It is also used to copy the retq for trampolines.
 174  */
 175 SYM_INNER_LABEL_ALIGN(ftrace_stub, SYM_L_WEAK)
 176         retq
 177 SYM_FUNC_END(ftrace_epilogue)
 178
 179 SYM_FUNC_START(ftrace_regs_caller)
 180         /* Save the current flags before any operations that can change them */
 181         pushfq
 182
 183         /* added 8 bytes to save flags */
 184         save_mcount_regs 8
 185         /* save_mcount_regs fills in first two parameters */
 186
 187 SYM_INNER_LABEL(ftrace_regs_caller_op_ptr, SYM_L_GLOBAL)
 188         /* Load the ftrace_ops into the 3rd parameter */
 189         movq function_trace_op(%rip), %rdx
 190
 191         /* Save the rest of pt_regs */
 192         movq %r15, R15(%rsp)
 193         movq %r14, R14(%rsp)
 194         movq %r13, R13(%rsp)
 195         movq %r12, R12(%rsp)
 196         movq %r11, R11(%rsp)
 197         movq %r10, R10(%rsp)
 198         movq %rbx, RBX(%rsp)
 199         /* Copy saved flags */
 200         movq MCOUNT_REG_SIZE(%rsp), %rcx
 201         movq %rcx, EFLAGS(%rsp)
 202         /* Kernel segments */
 203         movq $__KERNEL_DS, %rcx
 204         movq %rcx, SS(%rsp)
 205         movq $__KERNEL_CS, %rcx
 206         movq %rcx, CS(%rsp)
 207         /* Stack - skipping return address and flags */
 208         leaq MCOUNT_REG_SIZE+8*2(%rsp), %rcx
 209         movq %rcx, RSP(%rsp)
 210
 211         ENCODE_FRAME_POINTER
 212
 213         /* regs go into 4th parameter */
 214         leaq (%rsp), %rcx
 215
 216 SYM_INNER_LABEL(ftrace_regs_call, SYM_L_GLOBAL)
 217         call ftrace_stub
 218
 219         /* Copy flags back to SS, to restore them */
 220         movq EFLAGS(%rsp), %rax
 221         movq %rax, MCOUNT_REG_SIZE(%rsp)
 222
 223         /* Handlers can change the RIP */
 224         movq RIP(%rsp), %rax
 225         movq %rax, MCOUNT_REG_SIZE+8(%rsp)
 226
 227         /* restore the rest of pt_regs */
 228         movq R15(%rsp), %r15
 229         movq R14(%rsp), %r14
 230         movq R13(%rsp), %r13
 231         movq R12(%rsp), %r12
 232         movq R10(%rsp), %r10
 233         movq RBX(%rsp), %rbx
 234
 235         movq ORIG_RAX(%rsp), %rax
 236         movq %rax, MCOUNT_REG_SIZE-8(%rsp)
 237
 238         /*
 239          * If ORIG_RAX is anything but zero, make this a call to that.
 240          * See arch_ftrace_set_direct_caller().
 241          */
 242         movq ORIG_RAX(%rsp), %rax
 243         testq   %rax, %rax
 244 SYM_INNER_LABEL(ftrace_regs_caller_jmp, SYM_L_GLOBAL)
 245         jnz     1f
 246
 247         restore_mcount_regs
 248         /* Restore flags */
 249         popfq
 250
 251         /*
 252          * As this jmp to ftrace_epilogue can be a short jump
 253          * it must not be copied into the trampoline.
 254          * The trampoline will add the code to jump
 255          * to the return.
 256          */
 257 SYM_INNER_LABEL(ftrace_regs_caller_end, SYM_L_GLOBAL)
 258         jmp ftrace_epilogue
 259
 260         /* Swap the flags with orig_rax */
 261 1:      movq MCOUNT_REG_SIZE(%rsp), %rdi
 262         movq %rdi, MCOUNT_REG_SIZE-8(%rsp)
 263         movq %rax, MCOUNT_REG_SIZE(%rsp)
 264
 265         restore_mcount_regs 8
 266         /* Restore flags */
 267         popfq
 268         UNWIND_HINT_RET_OFFSET
 269         jmp     ftrace_epilogue
 270
 271 SYM_FUNC_END(ftrace_regs_caller)
 272
 273
 274 #else /* ! CONFIG_DYNAMIC_FTRACE */
 275
 276 SYM_FUNC_START(__fentry__)
 277         cmpq $ftrace_stub, ftrace_trace_function
 278         jnz trace
 279
 280 fgraph_trace:
 281 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 282         cmpq $ftrace_stub, ftrace_graph_return
 283         jnz ftrace_graph_caller
 284
 285         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 286         jnz ftrace_graph_caller
 287 #endif
 288
 289 SYM_INNER_LABEL(ftrace_stub, SYM_L_GLOBAL)
 290         retq
 291
 292 trace:
 293         /* save_mcount_regs fills in first two parameters */
 294         save_mcount_regs
 295
 296         /*
 297          * When DYNAMIC_FTRACE is not defined, ARCH_SUPPORTS_FTRACE_OPS is not
 298          * set (see include/asm/ftrace.h and include/linux/ftrace.h).  Only the
 299          * ip and parent ip are used and the list function is called when
 300          * function tracing is enabled.
 301          */
 302         movq ftrace_trace_function, %r8
 303         CALL_NOSPEC r8
 304         restore_mcount_regs
 305
 306         jmp fgraph_trace
 307 SYM_FUNC_END(__fentry__)
 308 EXPORT_SYMBOL(__fentry__)
 309 #endif /* CONFIG_DYNAMIC_FTRACE */
 310
 311 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 312 SYM_FUNC_START(ftrace_graph_caller)
 313         /* Saves rbp into %rdx and fills first parameter  */
 314         save_mcount_regs
 315
 316         leaq MCOUNT_REG_SIZE+8(%rsp), %rsi
 317         movq $0, %rdx   /* No framepointers needed */
 318         call    prepare_ftrace_return
 319
 320         restore_mcount_regs
 321
 322         retq
 323 SYM_FUNC_END(ftrace_graph_caller)
 324
 325 SYM_CODE_START(return_to_handler)
 326         UNWIND_HINT_EMPTY
 327         subq  $24, %rsp
 328
 329         /* Save the return values */
 330         movq %rax, (%rsp)
 331         movq %rdx, 8(%rsp)
 332         movq %rbp, %rdi
 333
 334         call ftrace_return_to_handler
 335
 336         movq %rax, %rdi
 337         movq 8(%rsp), %rdx
 338         movq (%rsp), %rax
 339         addq $24, %rsp
 340         JMP_NOSPEC rdi
 341 SYM_CODE_END(return_to_handler)
 342 #endif