2 * linux/arch/x86_64/entry.S
4 * Copyright (C) 1991, 1992 Linus Torvalds
5 * Copyright (C) 2000, 2001, 2002 Andi Kleen SuSE Labs
6 * Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
10 * entry.S contains the system-call and fault low-level handling routines.
12 * Some of this is documented in Documentation/x86/entry_64.txt
14 * NOTE: This code handles signal-recognition, which happens every time
15 * after an interrupt and after each system call.
17 * Normal syscalls and interrupts don't save a full stack frame, this is
18 * only done for syscall tracing, signals or fork/exec et.al.
20 * A note on terminology:
21 * - top of stack: Architecture defined interrupt frame from SS to RIP
22 * at the top of the kernel process stack.
23 * - partial stack frame: partially saved registers up to R11.
24 * - full stack frame: Like partial stack frame, but all register saved.
27 * - CFI macros are used to generate dwarf2 unwind information for better
28 * backtraces. They don't change any code.
29 * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
30 * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
31 * There are unfortunately lots of special cases where some registers
32 * not touched. The macro is a big mess that should be cleaned up.
33 * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
34 * Gives a full stack frame.
35 * - ENTRY/END Define functions in the symbol table.
36 * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
37 * frame that is otherwise undefined after a SYSCALL
38 * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
39 * - errorentry/paranoidentry/zeroentry - Define exception entry points.
42 #include <linux/linkage.h>
43 #include <asm/segment.h>
44 #include <asm/cache.h>
45 #include <asm/errno.h>
46 #include <asm/dwarf2.h>
47 #include <asm/calling.h>
48 #include <asm/asm-offsets.h>
50 #include <asm/unistd.h>
51 #include <asm/thread_info.h>
52 #include <asm/hw_irq.h>
53 #include <asm/page_types.h>
54 #include <asm/irqflags.h>
55 #include <asm/paravirt.h>
56 #include <asm/ftrace.h>
57 #include <asm/percpu.h>
58 #include <linux/err.h>
60 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this. */
61 #include <linux/elf-em.h>
62 #define AUDIT_ARCH_X86_64 (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
63 #define __AUDIT_ARCH_64BIT 0x80000000
64 #define __AUDIT_ARCH_LE 0x40000000
67 .section .entry.text, "ax"
69 #ifdef CONFIG_FUNCTION_TRACER
70 #ifdef CONFIG_DYNAMIC_FTRACE
76 cmpl $0, function_trace_stop
83 subq $MCOUNT_INSN_SIZE, %rdi
90 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
91 GLOBAL(ftrace_graph_call)
99 #else /* ! CONFIG_DYNAMIC_FTRACE */
101 cmpl $0, function_trace_stop
104 cmpq $ftrace_stub, ftrace_trace_function
107 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
108 cmpq $ftrace_stub, ftrace_graph_return
109 jnz ftrace_graph_caller
111 cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
112 jnz ftrace_graph_caller
121 movq 0x38(%rsp), %rdi
123 subq $MCOUNT_INSN_SIZE, %rdi
125 call *ftrace_trace_function
131 #endif /* CONFIG_DYNAMIC_FTRACE */
132 #endif /* CONFIG_FUNCTION_TRACER */
134 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
135 ENTRY(ftrace_graph_caller)
136 cmpl $0, function_trace_stop
142 movq 0x38(%rsp), %rsi
144 subq $MCOUNT_INSN_SIZE, %rsi
146 call prepare_ftrace_return
151 END(ftrace_graph_caller)
153 GLOBAL(return_to_handler)
156 /* Save the return values */
161 call ftrace_return_to_handler
171 #ifndef CONFIG_PREEMPT
172 #define retint_kernel retint_restore_args
175 #ifdef CONFIG_PARAVIRT
176 ENTRY(native_usergs_sysret64)
179 ENDPROC(native_usergs_sysret64)
180 #endif /* CONFIG_PARAVIRT */
183 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
184 #ifdef CONFIG_TRACE_IRQFLAGS
185 bt $9,EFLAGS-\offset(%rsp) /* interrupts off? */
193 * C code is not supposed to know about undefined top of stack. Every time
194 * a C function with an pt_regs argument is called from the SYSCALL based
195 * fast path FIXUP_TOP_OF_STACK is needed.
196 * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
200 /* %rsp:at FRAMEEND */
201 .macro FIXUP_TOP_OF_STACK tmp offset=0
202 movq PER_CPU_VAR(old_rsp),\tmp
203 movq \tmp,RSP+\offset(%rsp)
204 movq $__USER_DS,SS+\offset(%rsp)
205 movq $__USER_CS,CS+\offset(%rsp)
206 movq $-1,RCX+\offset(%rsp)
207 movq R11+\offset(%rsp),\tmp /* get eflags */
208 movq \tmp,EFLAGS+\offset(%rsp)
211 .macro RESTORE_TOP_OF_STACK tmp offset=0
212 movq RSP+\offset(%rsp),\tmp
213 movq \tmp,PER_CPU_VAR(old_rsp)
214 movq EFLAGS+\offset(%rsp),\tmp
215 movq \tmp,R11+\offset(%rsp)
218 .macro FAKE_STACK_FRAME child_rip
219 /* push in order ss, rsp, eflags, cs, rip */
221 pushq_cfi $__KERNEL_DS /* ss */
222 /*CFI_REL_OFFSET ss,0*/
223 pushq_cfi %rax /* rsp */
225 pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_BIT1) /* eflags - interrupts on */
226 /*CFI_REL_OFFSET rflags,0*/
227 pushq_cfi $__KERNEL_CS /* cs */
228 /*CFI_REL_OFFSET cs,0*/
229 pushq_cfi \child_rip /* rip */
231 pushq_cfi %rax /* orig rax */
234 .macro UNFAKE_STACK_FRAME
236 CFI_ADJUST_CFA_OFFSET -(6*8)
240 * initial frame state for interrupts (and exceptions without error code)
242 .macro EMPTY_FRAME start=1 offset=0
246 CFI_DEF_CFA rsp,8+\offset
248 CFI_DEF_CFA_OFFSET 8+\offset
253 * initial frame state for interrupts (and exceptions without error code)
255 .macro INTR_FRAME start=1 offset=0
256 EMPTY_FRAME \start, SS+8+\offset-RIP
257 /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
258 CFI_REL_OFFSET rsp, RSP+\offset-RIP
259 /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
260 /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
261 CFI_REL_OFFSET rip, RIP+\offset-RIP
265 * initial frame state for exceptions with error code (and interrupts
266 * with vector already pushed)
268 .macro XCPT_FRAME start=1 offset=0
269 INTR_FRAME \start, RIP+\offset-ORIG_RAX
270 /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
274 * frame that enables calling into C.
276 .macro PARTIAL_FRAME start=1 offset=0
277 XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
278 CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
279 CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
280 CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
281 CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
282 CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
283 CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
284 CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
285 CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
286 CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
290 * frame that enables passing a complete pt_regs to a C function.
292 .macro DEFAULT_FRAME start=1 offset=0
293 PARTIAL_FRAME \start, R11+\offset-R15
294 CFI_REL_OFFSET rbx, RBX+\offset
295 CFI_REL_OFFSET rbp, RBP+\offset
296 CFI_REL_OFFSET r12, R12+\offset
297 CFI_REL_OFFSET r13, R13+\offset
298 CFI_REL_OFFSET r14, R14+\offset
299 CFI_REL_OFFSET r15, R15+\offset
302 /* save partial stack frame */
305 /* start from rbp in pt_regs and jump over */
306 movq_cfi rdi, RDI-RBP
307 movq_cfi rsi, RSI-RBP
308 movq_cfi rdx, RDX-RBP
309 movq_cfi rcx, RCX-RBP
310 movq_cfi rax, RAX-RBP
313 movq_cfi r10, R10-RBP
314 movq_cfi r11, R11-RBP
316 /* Save rbp so that we can unwind from get_irq_regs() */
319 /* Save previous stack value */
322 leaq -RBP(%rsp),%rdi /* arg1 for handler */
323 testl $3, CS-RBP(%rsi)
327 * irq_count is used to check if a CPU is already on an interrupt stack
328 * or not. While this is essentially redundant with preempt_count it is
329 * a little cheaper to use a separate counter in the PDA (short of
330 * moving irq_enter into assembly, which would be too much work)
332 1: incl PER_CPU_VAR(irq_count)
333 cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
334 CFI_DEF_CFA_REGISTER rsi
336 /* Store previous stack value */
338 CFI_ESCAPE 0x0f /* DW_CFA_def_cfa_expression */, 6, \
339 0x77 /* DW_OP_breg7 */, 0, \
340 0x06 /* DW_OP_deref */, \
341 0x08 /* DW_OP_const1u */, SS+8-RBP, \
342 0x22 /* DW_OP_plus */
343 /* We entered an interrupt context - irqs are off: */
348 PARTIAL_FRAME 1 REST_SKIP+8
349 movq 5*8+16(%rsp), %r11 /* save return address */
356 movq %r11, 8(%rsp) /* return address */
357 FIXUP_TOP_OF_STACK %r11, 16
362 /* save complete stack frame */
363 .pushsection .kprobes.text, "ax"
383 movl $MSR_GS_BASE,%ecx
386 js 1f /* negative -> in kernel */
395 * A newly forked process directly context switches into this address.
397 * rdi: prev task we switched from
402 LOCK ; btr $TIF_FORK,TI_flags(%r8)
404 pushq_cfi kernel_eflags(%rip)
405 popfq_cfi # reset kernel eflags
407 call schedule_tail # rdi: 'prev' task parameter
409 GET_THREAD_INFO(%rcx)
413 testl $3, CS-ARGOFFSET(%rsp) # from kernel_thread?
414 jz retint_restore_args
416 testl $_TIF_IA32, TI_flags(%rcx) # 32-bit compat task needs IRET
417 jnz int_ret_from_sys_call
419 RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
420 jmp ret_from_sys_call # go to the SYSRET fastpath
426 * System call entry. Up to 6 arguments in registers are supported.
428 * SYSCALL does not save anything on the stack and does not change the
434 * rax system call number
436 * rcx return address for syscall/sysret, C arg3
439 * r10 arg3 (--> moved to rcx for C)
442 * r11 eflags for syscall/sysret, temporary for C
443 * r12-r15,rbp,rbx saved by C code, not touched.
445 * Interrupts are off on entry.
446 * Only called from user space.
448 * XXX if we had a free scratch register we could save the RSP into the stack frame
449 * and report it properly in ps. Unfortunately we haven't.
451 * When user can change the frames always force IRET. That is because
452 * it deals with uncanonical addresses better. SYSRET has trouble
453 * with them due to bugs in both AMD and Intel CPUs.
459 CFI_DEF_CFA rsp,KERNEL_STACK_OFFSET
461 /*CFI_REGISTER rflags,r11*/
464 * A hypervisor implementation might want to use a label
465 * after the swapgs, so that it can do the swapgs
466 * for the guest and jump here on syscall.
468 GLOBAL(system_call_after_swapgs)
470 movq %rsp,PER_CPU_VAR(old_rsp)
471 movq PER_CPU_VAR(kernel_stack),%rsp
473 * No need to follow this irqs off/on section - it's straight
476 ENABLE_INTERRUPTS(CLBR_NONE)
478 movq %rax,ORIG_RAX-ARGOFFSET(%rsp)
479 movq %rcx,RIP-ARGOFFSET(%rsp)
480 CFI_REL_OFFSET rip,RIP-ARGOFFSET
481 testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
483 system_call_fastpath:
484 #if __SYSCALL_MASK == ~0
485 cmpq $__NR_syscall_max,%rax
487 andl $__SYSCALL_MASK,%eax
488 cmpl $__NR_syscall_max,%eax
492 call *sys_call_table(,%rax,8) # XXX: rip relative
493 movq %rax,RAX-ARGOFFSET(%rsp)
495 * Syscall return path ending with SYSRET (fast path)
496 * Has incomplete stack frame and undefined top of stack.
499 movl $_TIF_ALLWORK_MASK,%edi
503 DISABLE_INTERRUPTS(CLBR_NONE)
505 movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
510 * sysretq will re-enable interrupts:
513 movq RIP-ARGOFFSET(%rsp),%rcx
515 RESTORE_ARGS 1,-ARG_SKIP,0
516 /*CFI_REGISTER rflags,r11*/
517 movq PER_CPU_VAR(old_rsp), %rsp
521 /* Handle reschedules */
522 /* edx: work, edi: workmask */
524 bt $TIF_NEED_RESCHED,%edx
527 ENABLE_INTERRUPTS(CLBR_NONE)
533 /* Handle a signal */
536 ENABLE_INTERRUPTS(CLBR_NONE)
537 #ifdef CONFIG_AUDITSYSCALL
538 bt $TIF_SYSCALL_AUDIT,%edx
542 * We have a signal, or exit tracing or single-step.
543 * These all wind up with the iret return path anyway,
544 * so just join that path right now.
546 FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
547 jmp int_check_syscall_exit_work
550 movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
551 jmp ret_from_sys_call
553 #ifdef CONFIG_AUDITSYSCALL
555 * Fast path for syscall audit without full syscall trace.
556 * We just call __audit_syscall_entry() directly, and then
557 * jump back to the normal fast path.
560 movq %r10,%r9 /* 6th arg: 4th syscall arg */
561 movq %rdx,%r8 /* 5th arg: 3rd syscall arg */
562 movq %rsi,%rcx /* 4th arg: 2nd syscall arg */
563 movq %rdi,%rdx /* 3rd arg: 1st syscall arg */
564 movq %rax,%rsi /* 2nd arg: syscall number */
565 movl $AUDIT_ARCH_X86_64,%edi /* 1st arg: audit arch */
566 call __audit_syscall_entry
567 LOAD_ARGS 0 /* reload call-clobbered registers */
568 jmp system_call_fastpath
571 * Return fast path for syscall audit. Call __audit_syscall_exit()
572 * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
576 movq RAX-ARGOFFSET(%rsp),%rsi /* second arg, syscall return value */
577 cmpq $-MAX_ERRNO,%rsi /* is it < -MAX_ERRNO? */
578 setbe %al /* 1 if so, 0 if not */
579 movzbl %al,%edi /* zero-extend that into %edi */
580 call __audit_syscall_exit
581 movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
583 #endif /* CONFIG_AUDITSYSCALL */
585 /* Do syscall tracing */
587 #ifdef CONFIG_AUDITSYSCALL
588 testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
592 movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
593 FIXUP_TOP_OF_STACK %rdi
595 call syscall_trace_enter
597 * Reload arg registers from stack in case ptrace changed them.
598 * We don't reload %rax because syscall_trace_enter() returned
599 * the value it wants us to use in the table lookup.
601 LOAD_ARGS ARGOFFSET, 1
603 #if __SYSCALL_MASK == ~0
604 cmpq $__NR_syscall_max,%rax
606 andl $__SYSCALL_MASK,%eax
607 cmpl $__NR_syscall_max,%eax
609 ja int_ret_from_sys_call /* RAX(%rsp) set to -ENOSYS above */
610 movq %r10,%rcx /* fixup for C */
611 call *sys_call_table(,%rax,8)
612 movq %rax,RAX-ARGOFFSET(%rsp)
613 /* Use IRET because user could have changed frame */
616 * Syscall return path ending with IRET.
617 * Has correct top of stack, but partial stack frame.
619 GLOBAL(int_ret_from_sys_call)
620 DISABLE_INTERRUPTS(CLBR_NONE)
622 movl $_TIF_ALLWORK_MASK,%edi
623 /* edi: mask to check */
624 GLOBAL(int_with_check)
626 GET_THREAD_INFO(%rcx)
627 movl TI_flags(%rcx),%edx
630 andl $~TS_COMPAT,TI_status(%rcx)
633 /* Either reschedule or signal or syscall exit tracking needed. */
634 /* First do a reschedule test. */
635 /* edx: work, edi: workmask */
637 bt $TIF_NEED_RESCHED,%edx
640 ENABLE_INTERRUPTS(CLBR_NONE)
644 DISABLE_INTERRUPTS(CLBR_NONE)
648 /* handle signals and tracing -- both require a full stack frame */
651 ENABLE_INTERRUPTS(CLBR_NONE)
652 int_check_syscall_exit_work:
654 /* Check for syscall exit trace */
655 testl $_TIF_WORK_SYSCALL_EXIT,%edx
658 leaq 8(%rsp),%rdi # &ptregs -> arg1
659 call syscall_trace_leave
661 andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
665 testl $_TIF_DO_NOTIFY_MASK,%edx
667 movq %rsp,%rdi # &ptregs -> arg1
668 xorl %esi,%esi # oldset -> arg2
669 call do_notify_resume
670 1: movl $_TIF_WORK_MASK,%edi
673 DISABLE_INTERRUPTS(CLBR_NONE)
680 * Certain special system calls that need to save a complete full stack frame.
682 .macro PTREGSCALL label,func,arg
684 PARTIAL_FRAME 1 8 /* offset 8: return address */
685 subq $REST_SKIP, %rsp
686 CFI_ADJUST_CFA_OFFSET REST_SKIP
688 DEFAULT_FRAME 0 8 /* offset 8: return address */
689 leaq 8(%rsp), \arg /* pt_regs pointer */
691 jmp ptregscall_common
696 PTREGSCALL stub_clone, sys_clone, %r8
697 PTREGSCALL stub_fork, sys_fork, %rdi
698 PTREGSCALL stub_vfork, sys_vfork, %rdi
699 PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
700 PTREGSCALL stub_iopl, sys_iopl, %rsi
702 ENTRY(ptregscall_common)
703 DEFAULT_FRAME 1 8 /* offset 8: return address */
704 RESTORE_TOP_OF_STACK %r11, 8
705 movq_cfi_restore R15+8, r15
706 movq_cfi_restore R14+8, r14
707 movq_cfi_restore R13+8, r13
708 movq_cfi_restore R12+8, r12
709 movq_cfi_restore RBP+8, rbp
710 movq_cfi_restore RBX+8, rbx
711 ret $REST_SKIP /* pop extended registers */
713 END(ptregscall_common)
720 FIXUP_TOP_OF_STACK %r11
723 RESTORE_TOP_OF_STACK %r11
726 jmp int_ret_from_sys_call
731 * sigreturn is special because it needs to restore all registers on return.
732 * This cannot be done with SYSRET, so use the IRET return path instead.
734 ENTRY(stub_rt_sigreturn)
740 FIXUP_TOP_OF_STACK %r11
741 call sys_rt_sigreturn
742 movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
744 jmp int_ret_from_sys_call
746 END(stub_rt_sigreturn)
748 #ifdef CONFIG_X86_X32_ABI
749 PTREGSCALL stub_x32_sigaltstack, sys32_sigaltstack, %rdx
751 ENTRY(stub_x32_rt_sigreturn)
757 FIXUP_TOP_OF_STACK %r11
758 call sys32_x32_rt_sigreturn
759 movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
761 jmp int_ret_from_sys_call
763 END(stub_x32_rt_sigreturn)
765 ENTRY(stub_x32_execve)
770 FIXUP_TOP_OF_STACK %r11
773 RESTORE_TOP_OF_STACK %r11
776 jmp int_ret_from_sys_call
783 * Build the entry stubs and pointer table with some assembler magic.
784 * We pack 7 stubs into a single 32-byte chunk, which will fit in a
785 * single cache line on all modern x86 implementations.
787 .section .init.rodata,"a"
791 .p2align CONFIG_X86_L1_CACHE_SHIFT
792 ENTRY(irq_entries_start)
794 vector=FIRST_EXTERNAL_VECTOR
795 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
798 .if vector < NR_VECTORS
799 .if vector <> FIRST_EXTERNAL_VECTOR
800 CFI_ADJUST_CFA_OFFSET -8
802 1: pushq_cfi $(~vector+0x80) /* Note: always in signed byte range */
803 .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
812 2: jmp common_interrupt
815 END(irq_entries_start)
822 * Interrupt entry/exit.
824 * Interrupt entry points save only callee clobbered registers in fast path.
826 * Entry runs with interrupts off.
829 /* 0(%rsp): ~(interrupt number) */
830 .macro interrupt func
831 /* reserve pt_regs for scratch regs and rbp */
832 subq $ORIG_RAX-RBP, %rsp
833 CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
839 * Interrupt entry/exit should be protected against kprobes
841 .pushsection .kprobes.text, "ax"
843 * The interrupt stubs push (~vector+0x80) onto the stack and
844 * then jump to common_interrupt.
846 .p2align CONFIG_X86_L1_CACHE_SHIFT
849 addq $-0x80,(%rsp) /* Adjust vector to [-256,-1] range */
851 /* 0(%rsp): old_rsp-ARGOFFSET */
853 DISABLE_INTERRUPTS(CLBR_NONE)
855 decl PER_CPU_VAR(irq_count)
857 /* Restore saved previous stack */
859 CFI_DEF_CFA rsi,SS+8-RBP /* reg/off reset after def_cfa_expr */
860 leaq ARGOFFSET-RBP(%rsi), %rsp
861 CFI_DEF_CFA_REGISTER rsp
862 CFI_ADJUST_CFA_OFFSET RBP-ARGOFFSET
865 GET_THREAD_INFO(%rcx)
866 testl $3,CS-ARGOFFSET(%rsp)
869 /* Interrupt came from user space */
871 * Has a correct top of stack, but a partial stack frame
872 * %rcx: thread info. Interrupts off.
874 retint_with_reschedule:
875 movl $_TIF_WORK_MASK,%edi
878 movl TI_flags(%rcx),%edx
883 retint_swapgs: /* return to user-space */
885 * The iretq could re-enable interrupts:
887 DISABLE_INTERRUPTS(CLBR_ANY)
892 retint_restore_args: /* return to kernel space */
893 DISABLE_INTERRUPTS(CLBR_ANY)
895 * The iretq could re-enable interrupts:
904 .section __ex_table, "a"
905 .quad irq_return, bad_iret
908 #ifdef CONFIG_PARAVIRT
912 .section __ex_table,"a"
913 .quad native_iret, bad_iret
920 * The iret traps when the %cs or %ss being restored is bogus.
921 * We've lost the original trap vector and error code.
922 * #GPF is the most likely one to get for an invalid selector.
923 * So pretend we completed the iret and took the #GPF in user mode.
925 * We are now running with the kernel GS after exception recovery.
926 * But error_entry expects us to have user GS to match the user %cs,
932 jmp general_protection
936 /* edi: workmask, edx: work */
939 bt $TIF_NEED_RESCHED,%edx
942 ENABLE_INTERRUPTS(CLBR_NONE)
946 GET_THREAD_INFO(%rcx)
947 DISABLE_INTERRUPTS(CLBR_NONE)
952 testl $_TIF_DO_NOTIFY_MASK,%edx
955 ENABLE_INTERRUPTS(CLBR_NONE)
957 movq $-1,ORIG_RAX(%rsp)
958 xorl %esi,%esi # oldset
959 movq %rsp,%rdi # &pt_regs
960 call do_notify_resume
962 DISABLE_INTERRUPTS(CLBR_NONE)
964 GET_THREAD_INFO(%rcx)
965 jmp retint_with_reschedule
967 #ifdef CONFIG_PREEMPT
968 /* Returning to kernel space. Check if we need preemption */
969 /* rcx: threadinfo. interrupts off. */
971 cmpl $0,TI_preempt_count(%rcx)
972 jnz retint_restore_args
973 bt $TIF_NEED_RESCHED,TI_flags(%rcx)
974 jnc retint_restore_args
975 bt $9,EFLAGS-ARGOFFSET(%rsp) /* interrupts off? */
976 jnc retint_restore_args
977 call preempt_schedule_irq
982 END(common_interrupt)
984 * End of kprobes section
991 .macro apicinterrupt num sym do_sym
1003 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
1004 irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1005 apicinterrupt REBOOT_VECTOR \
1006 reboot_interrupt smp_reboot_interrupt
1009 #ifdef CONFIG_X86_UV
1010 apicinterrupt UV_BAU_MESSAGE \
1011 uv_bau_message_intr1 uv_bau_message_interrupt
1013 apicinterrupt LOCAL_TIMER_VECTOR \
1014 apic_timer_interrupt smp_apic_timer_interrupt
1015 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1016 x86_platform_ipi smp_x86_platform_ipi
1021 .irp idx,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
1022 16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
1023 .if NUM_INVALIDATE_TLB_VECTORS > \idx
1024 ENTRY(invalidate_interrupt\idx)
1025 pushq_cfi $~(INVALIDATE_TLB_VECTOR_START+\idx)
1026 jmp .Lcommon_invalidate_interrupt0
1027 CFI_ADJUST_CFA_OFFSET -8
1028 END(invalidate_interrupt\idx)
1032 apicinterrupt INVALIDATE_TLB_VECTOR_START, \
1033 invalidate_interrupt0, smp_invalidate_interrupt
1036 apicinterrupt THRESHOLD_APIC_VECTOR \
1037 threshold_interrupt smp_threshold_interrupt
1038 apicinterrupt THERMAL_APIC_VECTOR \
1039 thermal_interrupt smp_thermal_interrupt
1042 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1043 call_function_single_interrupt smp_call_function_single_interrupt
1044 apicinterrupt CALL_FUNCTION_VECTOR \
1045 call_function_interrupt smp_call_function_interrupt
1046 apicinterrupt RESCHEDULE_VECTOR \
1047 reschedule_interrupt smp_reschedule_interrupt
1050 apicinterrupt ERROR_APIC_VECTOR \
1051 error_interrupt smp_error_interrupt
1052 apicinterrupt SPURIOUS_APIC_VECTOR \
1053 spurious_interrupt smp_spurious_interrupt
1055 #ifdef CONFIG_IRQ_WORK
1056 apicinterrupt IRQ_WORK_VECTOR \
1057 irq_work_interrupt smp_irq_work_interrupt
1061 * Exception entry points.
1063 .macro zeroentry sym do_sym
1066 PARAVIRT_ADJUST_EXCEPTION_FRAME
1067 pushq_cfi $-1 /* ORIG_RAX: no syscall to restart */
1068 subq $ORIG_RAX-R15, %rsp
1069 CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1072 movq %rsp,%rdi /* pt_regs pointer */
1073 xorl %esi,%esi /* no error code */
1075 jmp error_exit /* %ebx: no swapgs flag */
1080 .macro paranoidzeroentry sym do_sym
1083 PARAVIRT_ADJUST_EXCEPTION_FRAME
1084 pushq_cfi $-1 /* ORIG_RAX: no syscall to restart */
1085 subq $ORIG_RAX-R15, %rsp
1086 CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1089 movq %rsp,%rdi /* pt_regs pointer */
1090 xorl %esi,%esi /* no error code */
1092 jmp paranoid_exit /* %ebx: no swapgs flag */
1097 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1098 .macro paranoidzeroentry_ist sym do_sym ist
1101 PARAVIRT_ADJUST_EXCEPTION_FRAME
1102 pushq_cfi $-1 /* ORIG_RAX: no syscall to restart */
1103 subq $ORIG_RAX-R15, %rsp
1104 CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1107 movq %rsp,%rdi /* pt_regs pointer */
1108 xorl %esi,%esi /* no error code */
1109 subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1111 addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1112 jmp paranoid_exit /* %ebx: no swapgs flag */
1117 .macro errorentry sym do_sym
1120 PARAVIRT_ADJUST_EXCEPTION_FRAME
1121 subq $ORIG_RAX-R15, %rsp
1122 CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1125 movq %rsp,%rdi /* pt_regs pointer */
1126 movq ORIG_RAX(%rsp),%rsi /* get error code */
1127 movq $-1,ORIG_RAX(%rsp) /* no syscall to restart */
1129 jmp error_exit /* %ebx: no swapgs flag */
1134 /* error code is on the stack already */
1135 .macro paranoiderrorentry sym do_sym
1138 PARAVIRT_ADJUST_EXCEPTION_FRAME
1139 subq $ORIG_RAX-R15, %rsp
1140 CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1144 movq %rsp,%rdi /* pt_regs pointer */
1145 movq ORIG_RAX(%rsp),%rsi /* get error code */
1146 movq $-1,ORIG_RAX(%rsp) /* no syscall to restart */
1148 jmp paranoid_exit /* %ebx: no swapgs flag */
1153 zeroentry divide_error do_divide_error
1154 zeroentry overflow do_overflow
1155 zeroentry bounds do_bounds
1156 zeroentry invalid_op do_invalid_op
1157 zeroentry device_not_available do_device_not_available
1158 paranoiderrorentry double_fault do_double_fault
1159 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1160 errorentry invalid_TSS do_invalid_TSS
1161 errorentry segment_not_present do_segment_not_present
1162 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1163 zeroentry coprocessor_error do_coprocessor_error
1164 errorentry alignment_check do_alignment_check
1165 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1168 /* Reload gs selector with exception handling */
1169 /* edi: new selector */
1170 ENTRY(native_load_gs_index)
1173 DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1177 2: mfence /* workaround */
1182 END(native_load_gs_index)
1184 .section __ex_table,"a"
1186 .quad gs_change,bad_gs
1188 .section .fixup,"ax"
1189 /* running with kernelgs */
1191 SWAPGS /* switch back to user gs */
1197 ENTRY(kernel_thread_helper)
1198 pushq $0 # fake return address
1201 * Here we are in the child and the registers are set as they were
1202 * at kernel_thread() invocation in the parent.
1208 ud2 # padding for call trace
1210 END(kernel_thread_helper)
1213 * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1215 * C extern interface:
1216 * extern long execve(const char *name, char **argv, char **envp)
1218 * asm input arguments:
1219 * rdi: name, rsi: argv, rdx: envp
1221 * We want to fallback into:
1222 * extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1224 * do_sys_execve asm fallback arguments:
1225 * rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1227 ENTRY(kernel_execve)
1233 movq %rax, RAX(%rsp)
1236 je int_ret_from_sys_call
1243 /* Call softirq on interrupt stack. Interrupts are off. */
1247 CFI_REL_OFFSET rbp,0
1249 CFI_DEF_CFA_REGISTER rbp
1250 incl PER_CPU_VAR(irq_count)
1251 cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1252 push %rbp # backlink for old unwinder
1256 CFI_DEF_CFA_REGISTER rsp
1257 CFI_ADJUST_CFA_OFFSET -8
1258 decl PER_CPU_VAR(irq_count)
1264 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1267 * A note on the "critical region" in our callback handler.
1268 * We want to avoid stacking callback handlers due to events occurring
1269 * during handling of the last event. To do this, we keep events disabled
1270 * until we've done all processing. HOWEVER, we must enable events before
1271 * popping the stack frame (can't be done atomically) and so it would still
1272 * be possible to get enough handler activations to overflow the stack.
1273 * Although unlikely, bugs of that kind are hard to track down, so we'd
1274 * like to avoid the possibility.
1275 * So, on entry to the handler we detect whether we interrupted an
1276 * existing activation in its critical region -- if so, we pop the current
1277 * activation and restart the handler using the previous one.
1279 ENTRY(xen_do_hypervisor_callback) # do_hypervisor_callback(struct *pt_regs)
1282 * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1283 * see the correct pointer to the pt_regs
1285 movq %rdi, %rsp # we don't return, adjust the stack frame
1288 11: incl PER_CPU_VAR(irq_count)
1290 CFI_DEF_CFA_REGISTER rbp
1291 cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1292 pushq %rbp # backlink for old unwinder
1293 call xen_evtchn_do_upcall
1295 CFI_DEF_CFA_REGISTER rsp
1296 decl PER_CPU_VAR(irq_count)
1299 END(xen_do_hypervisor_callback)
1302 * Hypervisor uses this for application faults while it executes.
1303 * We get here for two reasons:
1304 * 1. Fault while reloading DS, ES, FS or GS
1305 * 2. Fault while executing IRET
1306 * Category 1 we do not need to fix up as Xen has already reloaded all segment
1307 * registers that could be reloaded and zeroed the others.
1308 * Category 2 we fix up by killing the current process. We cannot use the
1309 * normal Linux return path in this case because if we use the IRET hypercall
1310 * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1311 * We distinguish between categories by comparing each saved segment register
1312 * with its current contents: any discrepancy means we in category 1.
1314 ENTRY(xen_failsafe_callback)
1316 /*CFI_REL_OFFSET gs,GS*/
1317 /*CFI_REL_OFFSET fs,FS*/
1318 /*CFI_REL_OFFSET es,ES*/
1319 /*CFI_REL_OFFSET ds,DS*/
1320 CFI_REL_OFFSET r11,8
1321 CFI_REL_OFFSET rcx,0
1335 /* All segments match their saved values => Category 2 (Bad IRET). */
1341 CFI_ADJUST_CFA_OFFSET -0x30
1342 pushq_cfi $0 /* RIP */
1345 jmp general_protection
1347 1: /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1353 CFI_ADJUST_CFA_OFFSET -0x30
1358 END(xen_failsafe_callback)
1360 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1361 xen_hvm_callback_vector xen_evtchn_do_upcall
1363 #endif /* CONFIG_XEN */
1366 * Some functions should be protected against kprobes
1368 .pushsection .kprobes.text, "ax"
1370 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1371 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1372 paranoiderrorentry stack_segment do_stack_segment
1374 zeroentry xen_debug do_debug
1375 zeroentry xen_int3 do_int3
1376 errorentry xen_stack_segment do_stack_segment
1378 errorentry general_protection do_general_protection
1379 errorentry page_fault do_page_fault
1380 #ifdef CONFIG_KVM_GUEST
1381 errorentry async_page_fault do_async_page_fault
1383 #ifdef CONFIG_X86_MCE
1384 paranoidzeroentry machine_check *machine_check_vector(%rip)
1388 * "Paranoid" exit path from exception stack.
1389 * Paranoid because this is used by NMIs and cannot take
1390 * any kernel state for granted.
1391 * We don't do kernel preemption checks here, because only
1392 * NMI should be common and it does not enable IRQs and
1393 * cannot get reschedule ticks.
1395 * "trace" is 0 for the NMI handler only, because irq-tracing
1396 * is fundamentally NMI-unsafe. (we cannot change the soft and
1397 * hard flags at once, atomically)
1400 /* ebx: no swapgs flag */
1401 ENTRY(paranoid_exit)
1403 DISABLE_INTERRUPTS(CLBR_NONE)
1405 testl %ebx,%ebx /* swapgs needed? */
1406 jnz paranoid_restore
1408 jnz paranoid_userspace
1419 GET_THREAD_INFO(%rcx)
1420 movl TI_flags(%rcx),%ebx
1421 andl $_TIF_WORK_MASK,%ebx
1423 movq %rsp,%rdi /* &pt_regs */
1425 movq %rax,%rsp /* switch stack for scheduling */
1426 testl $_TIF_NEED_RESCHED,%ebx
1427 jnz paranoid_schedule
1428 movl %ebx,%edx /* arg3: thread flags */
1430 ENABLE_INTERRUPTS(CLBR_NONE)
1431 xorl %esi,%esi /* arg2: oldset */
1432 movq %rsp,%rdi /* arg1: &pt_regs */
1433 call do_notify_resume
1434 DISABLE_INTERRUPTS(CLBR_NONE)
1436 jmp paranoid_userspace
1439 ENABLE_INTERRUPTS(CLBR_ANY)
1441 DISABLE_INTERRUPTS(CLBR_ANY)
1443 jmp paranoid_userspace
1448 * Exception entry point. This expects an error code/orig_rax on the stack.
1449 * returns in "no swapgs flag" in %ebx.
1453 CFI_ADJUST_CFA_OFFSET 15*8
1454 /* oldrax contains error code */
1473 je error_kernelspace
1481 * There are two places in the kernel that can potentially fault with
1482 * usergs. Handle them here. The exception handlers after iret run with
1483 * kernel gs again, so don't set the user space flag. B stepping K8s
1484 * sometimes report an truncated RIP for IRET exceptions returning to
1485 * compat mode. Check for these here too.
1489 leaq irq_return(%rip),%rcx
1490 cmpq %rcx,RIP+8(%rsp)
1492 movl %ecx,%eax /* zero extend */
1493 cmpq %rax,RIP+8(%rsp)
1495 cmpq $gs_change,RIP+8(%rsp)
1500 /* Fix truncated RIP */
1501 movq %rcx,RIP+8(%rsp)
1507 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1512 DISABLE_INTERRUPTS(CLBR_NONE)
1514 GET_THREAD_INFO(%rcx)
1517 LOCKDEP_SYS_EXIT_IRQ
1518 movl TI_flags(%rcx),%edx
1519 movl $_TIF_WORK_MASK,%edi
1527 * Test if a given stack is an NMI stack or not.
1529 .macro test_in_nmi reg stack nmi_ret normal_ret
1532 subq $EXCEPTION_STKSZ, %\reg
1538 /* runs on exception stack */
1541 PARAVIRT_ADJUST_EXCEPTION_FRAME
1543 * We allow breakpoints in NMIs. If a breakpoint occurs, then
1544 * the iretq it performs will take us out of NMI context.
1545 * This means that we can have nested NMIs where the next
1546 * NMI is using the top of the stack of the previous NMI. We
1547 * can't let it execute because the nested NMI will corrupt the
1548 * stack of the previous NMI. NMI handlers are not re-entrant
1551 * To handle this case we do the following:
1552 * Check the a special location on the stack that contains
1553 * a variable that is set when NMIs are executing.
1554 * The interrupted task's stack is also checked to see if it
1556 * If the variable is not set and the stack is not the NMI
1558 * o Set the special variable on the stack
1559 * o Copy the interrupt frame into a "saved" location on the stack
1560 * o Copy the interrupt frame into a "copy" location on the stack
1561 * o Continue processing the NMI
1562 * If the variable is set or the previous stack is the NMI stack:
1563 * o Modify the "copy" location to jump to the repeate_nmi
1564 * o return back to the first NMI
1566 * Now on exit of the first NMI, we first clear the stack variable
1567 * The NMI stack will tell any nested NMIs at that point that it is
1568 * nested. Then we pop the stack normally with iret, and if there was
1569 * a nested NMI that updated the copy interrupt stack frame, a
1570 * jump will be made to the repeat_nmi code that will handle the second
1574 /* Use %rdx as out temp variable throughout */
1576 CFI_REL_OFFSET rdx, 0
1579 * If %cs was not the kernel segment, then the NMI triggered in user
1580 * space, which means it is definitely not nested.
1582 cmpl $__KERNEL_CS, 16(%rsp)
1586 * Check the special variable on the stack to see if NMIs are
1593 * Now test if the previous stack was an NMI stack.
1594 * We need the double check. We check the NMI stack to satisfy the
1595 * race when the first NMI clears the variable before returning.
1596 * We check the variable because the first NMI could be in a
1597 * breakpoint routine using a breakpoint stack.
1600 test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1605 * Do nothing if we interrupted the fixup in repeat_nmi.
1606 * It's about to repeat the NMI handler, so we are fine
1607 * with ignoring this one.
1609 movq $repeat_nmi, %rdx
1612 movq $end_repeat_nmi, %rdx
1617 /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1618 leaq -6*8(%rsp), %rdx
1620 CFI_ADJUST_CFA_OFFSET 6*8
1621 pushq_cfi $__KERNEL_DS
1624 pushq_cfi $__KERNEL_CS
1625 pushq_cfi $repeat_nmi
1627 /* Put stack back */
1629 CFI_ADJUST_CFA_OFFSET -11*8
1635 /* No need to check faults here */
1641 * Because nested NMIs will use the pushed location that we
1642 * stored in rdx, we must keep that space available.
1643 * Here's what our stack frame will look like:
1644 * +-------------------------+
1646 * | original Return RSP |
1647 * | original RFLAGS |
1650 * +-------------------------+
1651 * | temp storage for rdx |
1652 * +-------------------------+
1653 * | NMI executing variable |
1654 * +-------------------------+
1656 * | Saved Return RSP |
1660 * +-------------------------+
1662 * | copied Return RSP |
1666 * +-------------------------+
1668 * +-------------------------+
1670 * The saved stack frame is used to fix up the copied stack frame
1671 * that a nested NMI may change to make the interrupted NMI iret jump
1672 * to the repeat_nmi. The original stack frame and the temp storage
1673 * is also used by nested NMIs and can not be trusted on exit.
1675 /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1679 /* Set the NMI executing variable on the stack. */
1682 /* Copy the stack frame to the Saved frame */
1686 CFI_DEF_CFA_OFFSET SS+8-RIP
1688 /* Everything up to here is safe from nested NMIs */
1691 * If there was a nested NMI, the first NMI's iret will return
1692 * here. But NMIs are still enabled and we can take another
1693 * nested NMI. The nested NMI checks the interrupted RIP to see
1694 * if it is between repeat_nmi and end_repeat_nmi, and if so
1695 * it will just return, as we are about to repeat an NMI anyway.
1696 * This makes it safe to copy to the stack frame that a nested
1701 * Update the stack variable to say we are still in NMI (the update
1702 * is benign for the non-repeat case, where 1 was pushed just above
1703 * to this very stack slot).
1707 /* Make another copy, this one may be modified by nested NMIs */
1711 CFI_DEF_CFA_OFFSET SS+8-RIP
1715 * Everything below this point can be preempted by a nested
1716 * NMI if the first NMI took an exception and reset our iret stack
1717 * so that we repeat another NMI.
1719 pushq_cfi $-1 /* ORIG_RAX: no syscall to restart */
1720 subq $ORIG_RAX-R15, %rsp
1721 CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1723 * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1724 * as we should not be calling schedule in NMI context.
1725 * Even with normal interrupts enabled. An NMI should not be
1726 * setting NEED_RESCHED or anything that normal interrupts and
1727 * exceptions might do.
1731 /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1735 testl %ebx,%ebx /* swapgs needed? */
1741 /* Clear the NMI executing stack variable */
1747 ENTRY(ignore_sysret)
1755 * End of kprobes section