arch/x86/entry/entry_32.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  *  Copyright (C) 1991,1992  Linus Torvalds
   4  *
   5  * entry_32.S contains the system-call and low-level fault and trap handling routines.
   6  *
   7  * Stack layout while running C code:
   8  *      ptrace needs to have all registers on the stack.
   9  *      If the order here is changed, it needs to be
  10  *      updated in fork.c:copy_process(), signal.c:do_signal(),
  11  *      ptrace.c and ptrace.h
  12  *
  13  *       0(%esp) - %ebx
  14  *       4(%esp) - %ecx
  15  *       8(%esp) - %edx
  16  *       C(%esp) - %esi
  17  *      10(%esp) - %edi
  18  *      14(%esp) - %ebp
  19  *      18(%esp) - %eax
  20  *      1C(%esp) - %ds
  21  *      20(%esp) - %es
  22  *      24(%esp) - %fs
  23  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  24  *      2C(%esp) - orig_eax
  25  *      30(%esp) - %eip
  26  *      34(%esp) - %cs
  27  *      38(%esp) - %eflags
  28  *      3C(%esp) - %oldesp
  29  *      40(%esp) - %oldss
  30  */
  31
  32 #include <linux/linkage.h>
  33 #include <linux/err.h>
  34 #include <asm/thread_info.h>
  35 #include <asm/irqflags.h>
  36 #include <asm/errno.h>
  37 #include <asm/segment.h>
  38 #include <asm/smp.h>
  39 #include <asm/percpu.h>
  40 #include <asm/processor-flags.h>
  41 #include <asm/irq_vectors.h>
  42 #include <asm/cpufeatures.h>
  43 #include <asm/alternative-asm.h>
  44 #include <asm/asm.h>
  45 #include <asm/smap.h>
  46 #include <asm/frame.h>
  47 #include <asm/nospec-branch.h>
  48
  49         .section .entry.text, "ax"
  50
  51 /*
  52  * We use macros for low-level operations which need to be overridden
  53  * for paravirtualization.  The following will never clobber any registers:
  54  *   INTERRUPT_RETURN (aka. "iret")
  55  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  56  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  57  *
  58  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  59  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  60  * Allowing a register to be clobbered can shrink the paravirt replacement
  61  * enough to patch inline, increasing performance.
  62  */
  63
  64 #ifdef CONFIG_PREEMPT
  65 # define preempt_stop(clobbers) DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  66 #else
  67 # define preempt_stop(clobbers)
  68 # define resume_kernel          restore_all
  69 #endif
  70
  71 .macro TRACE_IRQS_IRET
  72 #ifdef CONFIG_TRACE_IRQFLAGS
  73         testl   $X86_EFLAGS_IF, PT_EFLAGS(%esp)     # interrupts off?
  74         jz      1f
  75         TRACE_IRQS_ON
  76 1:
  77 #endif
  78 .endm
  79
  80 /*
  81  * User gs save/restore
  82  *
  83  * %gs is used for userland TLS and kernel only uses it for stack
  84  * canary which is required to be at %gs:20 by gcc.  Read the comment
  85  * at the top of stackprotector.h for more info.
  86  *
  87  * Local labels 98 and 99 are used.
  88  */
  89 #ifdef CONFIG_X86_32_LAZY_GS
  90
  91  /* unfortunately push/pop can't be no-op */
  92 .macro PUSH_GS
  93         pushl   $0
  94 .endm
  95 .macro POP_GS pop=0
  96         addl    $(4 + \pop), %esp
  97 .endm
  98 .macro POP_GS_EX
  99 .endm
 100
 101  /* all the rest are no-op */
 102 .macro PTGS_TO_GS
 103 .endm
 104 .macro PTGS_TO_GS_EX
 105 .endm
 106 .macro GS_TO_REG reg
 107 .endm
 108 .macro REG_TO_PTGS reg
 109 .endm
 110 .macro SET_KERNEL_GS reg
 111 .endm
 112
 113 #else   /* CONFIG_X86_32_LAZY_GS */
 114
 115 .macro PUSH_GS
 116         pushl   %gs
 117 .endm
 118
 119 .macro POP_GS pop=0
 120 98:     popl    %gs
 121   .if \pop <> 0
 122         add     $\pop, %esp
 123   .endif
 124 .endm
 125 .macro POP_GS_EX
 126 .pushsection .fixup, "ax"
 127 99:     movl    $0, (%esp)
 128         jmp     98b
 129 .popsection
 130         _ASM_EXTABLE(98b, 99b)
 131 .endm
 132
 133 .macro PTGS_TO_GS
 134 98:     mov     PT_GS(%esp), %gs
 135 .endm
 136 .macro PTGS_TO_GS_EX
 137 .pushsection .fixup, "ax"
 138 99:     movl    $0, PT_GS(%esp)
 139         jmp     98b
 140 .popsection
 141         _ASM_EXTABLE(98b, 99b)
 142 .endm
 143
 144 .macro GS_TO_REG reg
 145         movl    %gs, \reg
 146 .endm
 147 .macro REG_TO_PTGS reg
 148         movl    \reg, PT_GS(%esp)
 149 .endm
 150 .macro SET_KERNEL_GS reg
 151         movl    $(__KERNEL_STACK_CANARY), \reg
 152         movl    \reg, %gs
 153 .endm
 154
 155 #endif /* CONFIG_X86_32_LAZY_GS */
 156
 157 .macro SAVE_ALL pt_regs_ax=%eax
 158         cld
 159         PUSH_GS
 160         pushl   %fs
 161         pushl   %es
 162         pushl   %ds
 163         pushl   \pt_regs_ax
 164         pushl   %ebp
 165         pushl   %edi
 166         pushl   %esi
 167         pushl   %edx
 168         pushl   %ecx
 169         pushl   %ebx
 170         movl    $(__USER_DS), %edx
 171         movl    %edx, %ds
 172         movl    %edx, %es
 173         movl    $(__KERNEL_PERCPU), %edx
 174         movl    %edx, %fs
 175         SET_KERNEL_GS %edx
 176 .endm
 177
 178 /*
 179  * This is a sneaky trick to help the unwinder find pt_regs on the stack.  The
 180  * frame pointer is replaced with an encoded pointer to pt_regs.  The encoding
 181  * is just clearing the MSB, which makes it an invalid stack address and is also
 182  * a signal to the unwinder that it's a pt_regs pointer in disguise.
 183  *
 184  * NOTE: This macro must be used *after* SAVE_ALL because it corrupts the
 185  * original rbp.
 186  */
 187 .macro ENCODE_FRAME_POINTER
 188 #ifdef CONFIG_FRAME_POINTER
 189         mov %esp, %ebp
 190         andl $0x7fffffff, %ebp
 191 #endif
 192 .endm
 193
 194 .macro RESTORE_INT_REGS
 195         popl    %ebx
 196         popl    %ecx
 197         popl    %edx
 198         popl    %esi
 199         popl    %edi
 200         popl    %ebp
 201         popl    %eax
 202 .endm
 203
 204 .macro RESTORE_REGS pop=0
 205         RESTORE_INT_REGS
 206 1:      popl    %ds
 207 2:      popl    %es
 208 3:      popl    %fs
 209         POP_GS \pop
 210 .pushsection .fixup, "ax"
 211 4:      movl    $0, (%esp)
 212         jmp     1b
 213 5:      movl    $0, (%esp)
 214         jmp     2b
 215 6:      movl    $0, (%esp)
 216         jmp     3b
 217 .popsection
 218         _ASM_EXTABLE(1b, 4b)
 219         _ASM_EXTABLE(2b, 5b)
 220         _ASM_EXTABLE(3b, 6b)
 221         POP_GS_EX
 222 .endm
 223
 224 /*
 225  * %eax: prev task
 226  * %edx: next task
 227  */
 228 ENTRY(__switch_to_asm)
 229         /*
 230          * Save callee-saved registers
 231          * This must match the order in struct inactive_task_frame
 232          */
 233         pushl   %ebp
 234         pushl   %ebx
 235         pushl   %edi
 236         pushl   %esi
 237
 238         /* switch stack */
 239         movl    %esp, TASK_threadsp(%eax)
 240         movl    TASK_threadsp(%edx), %esp
 241
 242 #ifdef CONFIG_CC_STACKPROTECTOR
 243         movl    TASK_stack_canary(%edx), %ebx
 244         movl    %ebx, PER_CPU_VAR(stack_canary)+stack_canary_offset
 245 #endif
 246
 247 #ifdef CONFIG_RETPOLINE
 248         /*
 249          * When switching from a shallower to a deeper call stack
 250          * the RSB may either underflow or use entries populated
 251          * with userspace addresses. On CPUs where those concerns
 252          * exist, overwrite the RSB with entries which capture
 253          * speculative execution to prevent attack.
 254          */
 255         /* Clobbers %ebx */
 256         FILL_RETURN_BUFFER RSB_CLEAR_LOOPS, X86_FEATURE_RSB_CTXSW
 257 #endif
 258
 259         /* restore callee-saved registers */
 260         popl    %esi
 261         popl    %edi
 262         popl    %ebx
 263         popl    %ebp
 264
 265         jmp     __switch_to
 266 END(__switch_to_asm)
 267
 268 /*
 269  * The unwinder expects the last frame on the stack to always be at the same
 270  * offset from the end of the page, which allows it to validate the stack.
 271  * Calling schedule_tail() directly would break that convention because its an
 272  * asmlinkage function so its argument has to be pushed on the stack.  This
 273  * wrapper creates a proper "end of stack" frame header before the call.
 274  */
 275 ENTRY(schedule_tail_wrapper)
 276         FRAME_BEGIN
 277
 278         pushl   %eax
 279         call    schedule_tail
 280         popl    %eax
 281
 282         FRAME_END
 283         ret
 284 ENDPROC(schedule_tail_wrapper)
 285 /*
 286  * A newly forked process directly context switches into this address.
 287  *
 288  * eax: prev task we switched from
 289  * ebx: kernel thread func (NULL for user thread)
 290  * edi: kernel thread arg
 291  */
 292 ENTRY(ret_from_fork)
 293         call    schedule_tail_wrapper
 294
 295         testl   %ebx, %ebx
 296         jnz     1f              /* kernel threads are uncommon */
 297
 298 2:
 299         /* When we fork, we trace the syscall return in the child, too. */
 300         movl    %esp, %eax
 301         call    syscall_return_slowpath
 302         jmp     restore_all
 303
 304         /* kernel thread */
 305 1:      movl    %edi, %eax
 306         CALL_NOSPEC %ebx
 307         /*
 308          * A kernel thread is allowed to return here after successfully
 309          * calling do_execve().  Exit to userspace to complete the execve()
 310          * syscall.
 311          */
 312         movl    $0, PT_EAX(%esp)
 313         jmp     2b
 314 END(ret_from_fork)
 315
 316 /*
 317  * Return to user mode is not as complex as all this looks,
 318  * but we want the default path for a system call return to
 319  * go as quickly as possible which is why some of this is
 320  * less clear than it otherwise should be.
 321  */
 322
 323         # userspace resumption stub bypassing syscall exit tracing
 324         ALIGN
 325 ret_from_exception:
 326         preempt_stop(CLBR_ANY)
 327 ret_from_intr:
 328 #ifdef CONFIG_VM86
 329         movl    PT_EFLAGS(%esp), %eax           # mix EFLAGS and CS
 330         movb    PT_CS(%esp), %al
 331         andl    $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 332 #else
 333         /*
 334          * We can be coming here from child spawned by kernel_thread().
 335          */
 336         movl    PT_CS(%esp), %eax
 337         andl    $SEGMENT_RPL_MASK, %eax
 338 #endif
 339         cmpl    $USER_RPL, %eax
 340         jb      resume_kernel                   # not returning to v8086 or userspace
 341
 342 ENTRY(resume_userspace)
 343         DISABLE_INTERRUPTS(CLBR_ANY)
 344         TRACE_IRQS_OFF
 345         movl    %esp, %eax
 346         call    prepare_exit_to_usermode
 347         jmp     restore_all
 348 END(ret_from_exception)
 349
 350 #ifdef CONFIG_PREEMPT
 351 ENTRY(resume_kernel)
 352         DISABLE_INTERRUPTS(CLBR_ANY)
 353 .Lneed_resched:
 354         cmpl    $0, PER_CPU_VAR(__preempt_count)
 355         jnz     restore_all
 356         testl   $X86_EFLAGS_IF, PT_EFLAGS(%esp) # interrupts off (exception path) ?
 357         jz      restore_all
 358         call    preempt_schedule_irq
 359         jmp     .Lneed_resched
 360 END(resume_kernel)
 361 #endif
 362
 363 GLOBAL(__begin_SYSENTER_singlestep_region)
 364 /*
 365  * All code from here through __end_SYSENTER_singlestep_region is subject
 366  * to being single-stepped if a user program sets TF and executes SYSENTER.
 367  * There is absolutely nothing that we can do to prevent this from happening
 368  * (thanks Intel!).  To keep our handling of this situation as simple as
 369  * possible, we handle TF just like AC and NT, except that our #DB handler
 370  * will ignore all of the single-step traps generated in this range.
 371  */
 372
 373 #ifdef CONFIG_XEN
 374 /*
 375  * Xen doesn't set %esp to be precisely what the normal SYSENTER
 376  * entry point expects, so fix it up before using the normal path.
 377  */
 378 ENTRY(xen_sysenter_target)
 379         addl    $5*4, %esp                      /* remove xen-provided frame */
 380         jmp     .Lsysenter_past_esp
 381 #endif
 382
 383 /*
 384  * 32-bit SYSENTER entry.
 385  *
 386  * 32-bit system calls through the vDSO's __kernel_vsyscall enter here
 387  * if X86_FEATURE_SEP is available.  This is the preferred system call
 388  * entry on 32-bit systems.
 389  *
 390  * The SYSENTER instruction, in principle, should *only* occur in the
 391  * vDSO.  In practice, a small number of Android devices were shipped
 392  * with a copy of Bionic that inlined a SYSENTER instruction.  This
 393  * never happened in any of Google's Bionic versions -- it only happened
 394  * in a narrow range of Intel-provided versions.
 395  *
 396  * SYSENTER loads SS, ESP, CS, and EIP from previously programmed MSRs.
 397  * IF and VM in RFLAGS are cleared (IOW: interrupts are off).
 398  * SYSENTER does not save anything on the stack,
 399  * and does not save old EIP (!!!), ESP, or EFLAGS.
 400  *
 401  * To avoid losing track of EFLAGS.VM (and thus potentially corrupting
 402  * user and/or vm86 state), we explicitly disable the SYSENTER
 403  * instruction in vm86 mode by reprogramming the MSRs.
 404  *
 405  * Arguments:
 406  * eax  system call number
 407  * ebx  arg1
 408  * ecx  arg2
 409  * edx  arg3
 410  * esi  arg4
 411  * edi  arg5
 412  * ebp  user stack
 413  * 0(%ebp) arg6
 414  */
 415 ENTRY(entry_SYSENTER_32)
 416         movl    TSS_sysenter_sp0(%esp), %esp
 417 .Lsysenter_past_esp:
 418         pushl   $__USER_DS              /* pt_regs->ss */
 419         pushl   %ebp                    /* pt_regs->sp (stashed in bp) */
 420         pushfl                          /* pt_regs->flags (except IF = 0) */
 421         orl     $X86_EFLAGS_IF, (%esp)  /* Fix IF */
 422         pushl   $__USER_CS              /* pt_regs->cs */
 423         pushl   $0                      /* pt_regs->ip = 0 (placeholder) */
 424         pushl   %eax                    /* pt_regs->orig_ax */
 425         SAVE_ALL pt_regs_ax=$-ENOSYS    /* save rest */
 426
 427         /*
 428          * SYSENTER doesn't filter flags, so we need to clear NT, AC
 429          * and TF ourselves.  To save a few cycles, we can check whether
 430          * either was set instead of doing an unconditional popfq.
 431          * This needs to happen before enabling interrupts so that
 432          * we don't get preempted with NT set.
 433          *
 434          * If TF is set, we will single-step all the way to here -- do_debug
 435          * will ignore all the traps.  (Yes, this is slow, but so is
 436          * single-stepping in general.  This allows us to avoid having
 437          * a more complicated code to handle the case where a user program
 438          * forces us to single-step through the SYSENTER entry code.)
 439          *
 440          * NB.: .Lsysenter_fix_flags is a label with the code under it moved
 441          * out-of-line as an optimization: NT is unlikely to be set in the
 442          * majority of the cases and instead of polluting the I$ unnecessarily,
 443          * we're keeping that code behind a branch which will predict as
 444          * not-taken and therefore its instructions won't be fetched.
 445          */
 446         testl   $X86_EFLAGS_NT|X86_EFLAGS_AC|X86_EFLAGS_TF, PT_EFLAGS(%esp)
 447         jnz     .Lsysenter_fix_flags
 448 .Lsysenter_flags_fixed:
 449
 450         /*
 451          * User mode is traced as though IRQs are on, and SYSENTER
 452          * turned them off.
 453          */
 454         TRACE_IRQS_OFF
 455
 456         movl    %esp, %eax
 457         call    do_fast_syscall_32
 458         /* XEN PV guests always use IRET path */
 459         ALTERNATIVE "testl %eax, %eax; jz .Lsyscall_32_done", \
 460                     "jmp .Lsyscall_32_done", X86_FEATURE_XENPV
 461
 462 /* Opportunistic SYSEXIT */
 463         TRACE_IRQS_ON                   /* User mode traces as IRQs on. */
 464         movl    PT_EIP(%esp), %edx      /* pt_regs->ip */
 465         movl    PT_OLDESP(%esp), %ecx   /* pt_regs->sp */
 466 1:      mov     PT_FS(%esp), %fs
 467         PTGS_TO_GS
 468         popl    %ebx                    /* pt_regs->bx */
 469         addl    $2*4, %esp              /* skip pt_regs->cx and pt_regs->dx */
 470         popl    %esi                    /* pt_regs->si */
 471         popl    %edi                    /* pt_regs->di */
 472         popl    %ebp                    /* pt_regs->bp */
 473         popl    %eax                    /* pt_regs->ax */
 474
 475         /*
 476          * Restore all flags except IF. (We restore IF separately because
 477          * STI gives a one-instruction window in which we won't be interrupted,
 478          * whereas POPF does not.)
 479          */
 480         addl    $PT_EFLAGS-PT_DS, %esp  /* point esp at pt_regs->flags */
 481         btr     $X86_EFLAGS_IF_BIT, (%esp)
 482         popfl
 483
 484         /*
 485          * Return back to the vDSO, which will pop ecx and edx.
 486          * Don't bother with DS and ES (they already contain __USER_DS).
 487          */
 488         sti
 489         sysexit
 490
 491 .pushsection .fixup, "ax"
 492 2:      movl    $0, PT_FS(%esp)
 493         jmp     1b
 494 .popsection
 495         _ASM_EXTABLE(1b, 2b)
 496         PTGS_TO_GS_EX
 497
 498 .Lsysenter_fix_flags:
 499         pushl   $X86_EFLAGS_FIXED
 500         popfl
 501         jmp     .Lsysenter_flags_fixed
 502 GLOBAL(__end_SYSENTER_singlestep_region)
 503 ENDPROC(entry_SYSENTER_32)
 504
 505 /*
 506  * 32-bit legacy system call entry.
 507  *
 508  * 32-bit x86 Linux system calls traditionally used the INT $0x80
 509  * instruction.  INT $0x80 lands here.
 510  *
 511  * This entry point can be used by any 32-bit perform system calls.
 512  * Instances of INT $0x80 can be found inline in various programs and
 513  * libraries.  It is also used by the vDSO's __kernel_vsyscall
 514  * fallback for hardware that doesn't support a faster entry method.
 515  * Restarted 32-bit system calls also fall back to INT $0x80
 516  * regardless of what instruction was originally used to do the system
 517  * call.  (64-bit programs can use INT $0x80 as well, but they can
 518  * only run on 64-bit kernels and therefore land in
 519  * entry_INT80_compat.)
 520  *
 521  * This is considered a slow path.  It is not used by most libc
 522  * implementations on modern hardware except during process startup.
 523  *
 524  * Arguments:
 525  * eax  system call number
 526  * ebx  arg1
 527  * ecx  arg2
 528  * edx  arg3
 529  * esi  arg4
 530  * edi  arg5
 531  * ebp  arg6
 532  */
 533 ENTRY(entry_INT80_32)
 534         ASM_CLAC
 535         pushl   %eax                    /* pt_regs->orig_ax */
 536         SAVE_ALL pt_regs_ax=$-ENOSYS    /* save rest */
 537
 538         /*
 539          * User mode is traced as though IRQs are on, and the interrupt gate
 540          * turned them off.
 541          */
 542         TRACE_IRQS_OFF
 543
 544         movl    %esp, %eax
 545         call    do_int80_syscall_32
 546 .Lsyscall_32_done:
 547
 548 restore_all:
 549         TRACE_IRQS_IRET
 550 .Lrestore_all_notrace:
 551 #ifdef CONFIG_X86_ESPFIX32
 552         ALTERNATIVE     "jmp .Lrestore_nocheck", "", X86_BUG_ESPFIX
 553
 554         movl    PT_EFLAGS(%esp), %eax           # mix EFLAGS, SS and CS
 555         /*
 556          * Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 557          * are returning to the kernel.
 558          * See comments in process.c:copy_thread() for details.
 559          */
 560         movb    PT_OLDSS(%esp), %ah
 561         movb    PT_CS(%esp), %al
 562         andl    $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 563         cmpl    $((SEGMENT_LDT << 8) | USER_RPL), %eax
 564         je .Lldt_ss                             # returning to user-space with LDT SS
 565 #endif
 566 .Lrestore_nocheck:
 567         RESTORE_REGS 4                          # skip orig_eax/error_code
 568 .Lirq_return:
 569         /*
 570          * ARCH_HAS_MEMBARRIER_SYNC_CORE rely on IRET core serialization
 571          * when returning from IPI handler and when returning from
 572          * scheduler to user-space.
 573          */
 574         INTERRUPT_RETURN
 575
 576 .section .fixup, "ax"
 577 ENTRY(iret_exc  )
 578         pushl   $0                              # no error code
 579         pushl   $do_iret_error
 580         jmp     common_exception
 581 .previous
 582         _ASM_EXTABLE(.Lirq_return, iret_exc)
 583
 584 #ifdef CONFIG_X86_ESPFIX32
 585 .Lldt_ss:
 586 /*
 587  * Setup and switch to ESPFIX stack
 588  *
 589  * We're returning to userspace with a 16 bit stack. The CPU will not
 590  * restore the high word of ESP for us on executing iret... This is an
 591  * "official" bug of all the x86-compatible CPUs, which we can work
 592  * around to make dosemu and wine happy. We do this by preloading the
 593  * high word of ESP with the high word of the userspace ESP while
 594  * compensating for the offset by changing to the ESPFIX segment with
 595  * a base address that matches for the difference.
 596  */
 597 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
 598         mov     %esp, %edx                      /* load kernel esp */
 599         mov     PT_OLDESP(%esp), %eax           /* load userspace esp */
 600         mov     %dx, %ax                        /* eax: new kernel esp */
 601         sub     %eax, %edx                      /* offset (low word is 0) */
 602         shr     $16, %edx
 603         mov     %dl, GDT_ESPFIX_SS + 4          /* bits 16..23 */
 604         mov     %dh, GDT_ESPFIX_SS + 7          /* bits 24..31 */
 605         pushl   $__ESPFIX_SS
 606         pushl   %eax                            /* new kernel esp */
 607         /*
 608          * Disable interrupts, but do not irqtrace this section: we
 609          * will soon execute iret and the tracer was already set to
 610          * the irqstate after the IRET:
 611          */
 612         DISABLE_INTERRUPTS(CLBR_ANY)
 613         lss     (%esp), %esp                    /* switch to espfix segment */
 614         jmp     .Lrestore_nocheck
 615 #endif
 616 ENDPROC(entry_INT80_32)
 617
 618 .macro FIXUP_ESPFIX_STACK
 619 /*
 620  * Switch back for ESPFIX stack to the normal zerobased stack
 621  *
 622  * We can't call C functions using the ESPFIX stack. This code reads
 623  * the high word of the segment base from the GDT and swiches to the
 624  * normal stack and adjusts ESP with the matching offset.
 625  */
 626 #ifdef CONFIG_X86_ESPFIX32
 627         /* fixup the stack */
 628         mov     GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
 629         mov     GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
 630         shl     $16, %eax
 631         addl    %esp, %eax                      /* the adjusted stack pointer */
 632         pushl   $__KERNEL_DS
 633         pushl   %eax
 634         lss     (%esp), %esp                    /* switch to the normal stack segment */
 635 #endif
 636 .endm
 637 .macro UNWIND_ESPFIX_STACK
 638 #ifdef CONFIG_X86_ESPFIX32
 639         movl    %ss, %eax
 640         /* see if on espfix stack */
 641         cmpw    $__ESPFIX_SS, %ax
 642         jne     27f
 643         movl    $__KERNEL_DS, %eax
 644         movl    %eax, %ds
 645         movl    %eax, %es
 646         /* switch to normal stack */
 647         FIXUP_ESPFIX_STACK
 648 27:
 649 #endif
 650 .endm
 651
 652 /*
 653  * Build the entry stubs with some assembler magic.
 654  * We pack 1 stub into every 8-byte block.
 655  */
 656         .align 8
 657 ENTRY(irq_entries_start)
 658     vector=FIRST_EXTERNAL_VECTOR
 659     .rept (FIRST_SYSTEM_VECTOR - FIRST_EXTERNAL_VECTOR)
 660         pushl   $(~vector+0x80)                 /* Note: always in signed byte range */
 661     vector=vector+1
 662         jmp     common_interrupt
 663         .align  8
 664     .endr
 665 END(irq_entries_start)
 666
 667 /*
 668  * the CPU automatically disables interrupts when executing an IRQ vector,
 669  * so IRQ-flags tracing has to follow that:
 670  */
 671         .p2align CONFIG_X86_L1_CACHE_SHIFT
 672 common_interrupt:
 673         ASM_CLAC
 674         addl    $-0x80, (%esp)                  /* Adjust vector into the [-256, -1] range */
 675         SAVE_ALL
 676         ENCODE_FRAME_POINTER
 677         TRACE_IRQS_OFF
 678         movl    %esp, %eax
 679         call    do_IRQ
 680         jmp     ret_from_intr
 681 ENDPROC(common_interrupt)
 682
 683 #define BUILD_INTERRUPT3(name, nr, fn)  \
 684 ENTRY(name)                             \
 685         ASM_CLAC;                       \
 686         pushl   $~(nr);                 \
 687         SAVE_ALL;                       \
 688         ENCODE_FRAME_POINTER;           \
 689         TRACE_IRQS_OFF                  \
 690         movl    %esp, %eax;             \
 691         call    fn;                     \
 692         jmp     ret_from_intr;          \
 693 ENDPROC(name)
 694
 695 #define BUILD_INTERRUPT(name, nr)               \
 696         BUILD_INTERRUPT3(name, nr, smp_##name); \
 697
 698 /* The include is where all of the SMP etc. interrupts come from */
 699 #include <asm/entry_arch.h>
 700
 701 ENTRY(coprocessor_error)
 702         ASM_CLAC
 703         pushl   $0
 704         pushl   $do_coprocessor_error
 705         jmp     common_exception
 706 END(coprocessor_error)
 707
 708 ENTRY(simd_coprocessor_error)
 709         ASM_CLAC
 710         pushl   $0
 711 #ifdef CONFIG_X86_INVD_BUG
 712         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
 713         ALTERNATIVE "pushl      $do_general_protection",        \
 714                     "pushl      $do_simd_coprocessor_error",    \
 715                     X86_FEATURE_XMM
 716 #else
 717         pushl   $do_simd_coprocessor_error
 718 #endif
 719         jmp     common_exception
 720 END(simd_coprocessor_error)
 721
 722 ENTRY(device_not_available)
 723         ASM_CLAC
 724         pushl   $-1                             # mark this as an int
 725         pushl   $do_device_not_available
 726         jmp     common_exception
 727 END(device_not_available)
 728
 729 #ifdef CONFIG_PARAVIRT
 730 ENTRY(native_iret)
 731         iret
 732         _ASM_EXTABLE(native_iret, iret_exc)
 733 END(native_iret)
 734 #endif
 735
 736 ENTRY(overflow)
 737         ASM_CLAC
 738         pushl   $0
 739         pushl   $do_overflow
 740         jmp     common_exception
 741 END(overflow)
 742
 743 ENTRY(bounds)
 744         ASM_CLAC
 745         pushl   $0
 746         pushl   $do_bounds
 747         jmp     common_exception
 748 END(bounds)
 749
 750 ENTRY(invalid_op)
 751         ASM_CLAC
 752         pushl   $0
 753         pushl   $do_invalid_op
 754         jmp     common_exception
 755 END(invalid_op)
 756
 757 ENTRY(coprocessor_segment_overrun)
 758         ASM_CLAC
 759         pushl   $0
 760         pushl   $do_coprocessor_segment_overrun
 761         jmp     common_exception
 762 END(coprocessor_segment_overrun)
 763
 764 ENTRY(invalid_TSS)
 765         ASM_CLAC
 766         pushl   $do_invalid_TSS
 767         jmp     common_exception
 768 END(invalid_TSS)
 769
 770 ENTRY(segment_not_present)
 771         ASM_CLAC
 772         pushl   $do_segment_not_present
 773         jmp     common_exception
 774 END(segment_not_present)
 775
 776 ENTRY(stack_segment)
 777         ASM_CLAC
 778         pushl   $do_stack_segment
 779         jmp     common_exception
 780 END(stack_segment)
 781
 782 ENTRY(alignment_check)
 783         ASM_CLAC
 784         pushl   $do_alignment_check
 785         jmp     common_exception
 786 END(alignment_check)
 787
 788 ENTRY(divide_error)
 789         ASM_CLAC
 790         pushl   $0                              # no error code
 791         pushl   $do_divide_error
 792         jmp     common_exception
 793 END(divide_error)
 794
 795 #ifdef CONFIG_X86_MCE
 796 ENTRY(machine_check)
 797         ASM_CLAC
 798         pushl   $0
 799         pushl   machine_check_vector
 800         jmp     common_exception
 801 END(machine_check)
 802 #endif
 803
 804 ENTRY(spurious_interrupt_bug)
 805         ASM_CLAC
 806         pushl   $0
 807         pushl   $do_spurious_interrupt_bug
 808         jmp     common_exception
 809 END(spurious_interrupt_bug)
 810
 811 #ifdef CONFIG_XEN
 812 ENTRY(xen_hypervisor_callback)
 813         pushl   $-1                             /* orig_ax = -1 => not a system call */
 814         SAVE_ALL
 815         ENCODE_FRAME_POINTER
 816         TRACE_IRQS_OFF
 817
 818         /*
 819          * Check to see if we got the event in the critical
 820          * region in xen_iret_direct, after we've reenabled
 821          * events and checked for pending events.  This simulates
 822          * iret instruction's behaviour where it delivers a
 823          * pending interrupt when enabling interrupts:
 824          */
 825         movl    PT_EIP(%esp), %eax
 826         cmpl    $xen_iret_start_crit, %eax
 827         jb      1f
 828         cmpl    $xen_iret_end_crit, %eax
 829         jae     1f
 830
 831         jmp     xen_iret_crit_fixup
 832
 833 ENTRY(xen_do_upcall)
 834 1:      mov     %esp, %eax
 835         call    xen_evtchn_do_upcall
 836 #ifndef CONFIG_PREEMPT
 837         call    xen_maybe_preempt_hcall
 838 #endif
 839         jmp     ret_from_intr
 840 ENDPROC(xen_hypervisor_callback)
 841
 842 /*
 843  * Hypervisor uses this for application faults while it executes.
 844  * We get here for two reasons:
 845  *  1. Fault while reloading DS, ES, FS or GS
 846  *  2. Fault while executing IRET
 847  * Category 1 we fix up by reattempting the load, and zeroing the segment
 848  * register if the load fails.
 849  * Category 2 we fix up by jumping to do_iret_error. We cannot use the
 850  * normal Linux return path in this case because if we use the IRET hypercall
 851  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
 852  * We distinguish between categories by maintaining a status value in EAX.
 853  */
 854 ENTRY(xen_failsafe_callback)
 855         pushl   %eax
 856         movl    $1, %eax
 857 1:      mov     4(%esp), %ds
 858 2:      mov     8(%esp), %es
 859 3:      mov     12(%esp), %fs
 860 4:      mov     16(%esp), %gs
 861         /* EAX == 0 => Category 1 (Bad segment)
 862            EAX != 0 => Category 2 (Bad IRET) */
 863         testl   %eax, %eax
 864         popl    %eax
 865         lea     16(%esp), %esp
 866         jz      5f
 867         jmp     iret_exc
 868 5:      pushl   $-1                             /* orig_ax = -1 => not a system call */
 869         SAVE_ALL
 870         ENCODE_FRAME_POINTER
 871         jmp     ret_from_exception
 872
 873 .section .fixup, "ax"
 874 6:      xorl    %eax, %eax
 875         movl    %eax, 4(%esp)
 876         jmp     1b
 877 7:      xorl    %eax, %eax
 878         movl    %eax, 8(%esp)
 879         jmp     2b
 880 8:      xorl    %eax, %eax
 881         movl    %eax, 12(%esp)
 882         jmp     3b
 883 9:      xorl    %eax, %eax
 884         movl    %eax, 16(%esp)
 885         jmp     4b
 886 .previous
 887         _ASM_EXTABLE(1b, 6b)
 888         _ASM_EXTABLE(2b, 7b)
 889         _ASM_EXTABLE(3b, 8b)
 890         _ASM_EXTABLE(4b, 9b)
 891 ENDPROC(xen_failsafe_callback)
 892
 893 BUILD_INTERRUPT3(xen_hvm_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
 894                  xen_evtchn_do_upcall)
 895
 896 #endif /* CONFIG_XEN */
 897
 898 #if IS_ENABLED(CONFIG_HYPERV)
 899
 900 BUILD_INTERRUPT3(hyperv_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
 901                  hyperv_vector_handler)
 902
 903 BUILD_INTERRUPT3(hyperv_reenlightenment_vector, HYPERV_REENLIGHTENMENT_VECTOR,
 904                  hyperv_reenlightenment_intr)
 905
 906 #endif /* CONFIG_HYPERV */
 907
 908 ENTRY(page_fault)
 909         ASM_CLAC
 910         pushl   $do_page_fault
 911         ALIGN
 912         jmp common_exception
 913 END(page_fault)
 914
 915 common_exception:
 916         /* the function address is in %gs's slot on the stack */
 917         pushl   %fs
 918         pushl   %es
 919         pushl   %ds
 920         pushl   %eax
 921         pushl   %ebp
 922         pushl   %edi
 923         pushl   %esi
 924         pushl   %edx
 925         pushl   %ecx
 926         pushl   %ebx
 927         ENCODE_FRAME_POINTER
 928         cld
 929         movl    $(__KERNEL_PERCPU), %ecx
 930         movl    %ecx, %fs
 931         UNWIND_ESPFIX_STACK
 932         GS_TO_REG %ecx
 933         movl    PT_GS(%esp), %edi               # get the function address
 934         movl    PT_ORIG_EAX(%esp), %edx         # get the error code
 935         movl    $-1, PT_ORIG_EAX(%esp)          # no syscall to restart
 936         REG_TO_PTGS %ecx
 937         SET_KERNEL_GS %ecx
 938         movl    $(__USER_DS), %ecx
 939         movl    %ecx, %ds
 940         movl    %ecx, %es
 941         TRACE_IRQS_OFF
 942         movl    %esp, %eax                      # pt_regs pointer
 943         CALL_NOSPEC %edi
 944         jmp     ret_from_exception
 945 END(common_exception)
 946
 947 ENTRY(debug)
 948         /*
 949          * #DB can happen at the first instruction of
 950          * entry_SYSENTER_32 or in Xen's SYSENTER prologue.  If this
 951          * happens, then we will be running on a very small stack.  We
 952          * need to detect this condition and switch to the thread
 953          * stack before calling any C code at all.
 954          *
 955          * If you edit this code, keep in mind that NMIs can happen in here.
 956          */
 957         ASM_CLAC
 958         pushl   $-1                             # mark this as an int
 959         SAVE_ALL
 960         ENCODE_FRAME_POINTER
 961         xorl    %edx, %edx                      # error code 0
 962         movl    %esp, %eax                      # pt_regs pointer
 963
 964         /* Are we currently on the SYSENTER stack? */
 965         movl    PER_CPU_VAR(cpu_entry_area), %ecx
 966         addl    $CPU_ENTRY_AREA_entry_stack + SIZEOF_entry_stack, %ecx
 967         subl    %eax, %ecx      /* ecx = (end of entry_stack) - esp */
 968         cmpl    $SIZEOF_entry_stack, %ecx
 969         jb      .Ldebug_from_sysenter_stack
 970
 971         TRACE_IRQS_OFF
 972         call    do_debug
 973         jmp     ret_from_exception
 974
 975 .Ldebug_from_sysenter_stack:
 976         /* We're on the SYSENTER stack.  Switch off. */
 977         movl    %esp, %ebx
 978         movl    PER_CPU_VAR(cpu_current_top_of_stack), %esp
 979         TRACE_IRQS_OFF
 980         call    do_debug
 981         movl    %ebx, %esp
 982         jmp     ret_from_exception
 983 END(debug)
 984
 985 /*
 986  * NMI is doubly nasty.  It can happen on the first instruction of
 987  * entry_SYSENTER_32 (just like #DB), but it can also interrupt the beginning
 988  * of the #DB handler even if that #DB in turn hit before entry_SYSENTER_32
 989  * switched stacks.  We handle both conditions by simply checking whether we
 990  * interrupted kernel code running on the SYSENTER stack.
 991  */
 992 ENTRY(nmi)
 993         ASM_CLAC
 994 #ifdef CONFIG_X86_ESPFIX32
 995         pushl   %eax
 996         movl    %ss, %eax
 997         cmpw    $__ESPFIX_SS, %ax
 998         popl    %eax
 999         je      .Lnmi_espfix_stack
1000 #endif
1001
1002         pushl   %eax                            # pt_regs->orig_ax
1003         SAVE_ALL
1004         ENCODE_FRAME_POINTER
1005         xorl    %edx, %edx                      # zero error code
1006         movl    %esp, %eax                      # pt_regs pointer
1007
1008         /* Are we currently on the SYSENTER stack? */
1009         movl    PER_CPU_VAR(cpu_entry_area), %ecx
1010         addl    $CPU_ENTRY_AREA_entry_stack + SIZEOF_entry_stack, %ecx
1011         subl    %eax, %ecx      /* ecx = (end of entry_stack) - esp */
1012         cmpl    $SIZEOF_entry_stack, %ecx
1013         jb      .Lnmi_from_sysenter_stack
1014
1015         /* Not on SYSENTER stack. */
1016         call    do_nmi
1017         jmp     .Lrestore_all_notrace
1018
1019 .Lnmi_from_sysenter_stack:
1020         /*
1021          * We're on the SYSENTER stack.  Switch off.  No one (not even debug)
1022          * is using the thread stack right now, so it's safe for us to use it.
1023          */
1024         movl    %esp, %ebx
1025         movl    PER_CPU_VAR(cpu_current_top_of_stack), %esp
1026         call    do_nmi
1027         movl    %ebx, %esp
1028         jmp     .Lrestore_all_notrace
1029
1030 #ifdef CONFIG_X86_ESPFIX32
1031 .Lnmi_espfix_stack:
1032         /*
1033          * create the pointer to lss back
1034          */
1035         pushl   %ss
1036         pushl   %esp
1037         addl    $4, (%esp)
1038         /* copy the iret frame of 12 bytes */
1039         .rept 3
1040         pushl   16(%esp)
1041         .endr
1042         pushl   %eax
1043         SAVE_ALL
1044         ENCODE_FRAME_POINTER
1045         FIXUP_ESPFIX_STACK                      # %eax == %esp
1046         xorl    %edx, %edx                      # zero error code
1047         call    do_nmi
1048         RESTORE_REGS
1049         lss     12+4(%esp), %esp                # back to espfix stack
1050         jmp     .Lirq_return
1051 #endif
1052 END(nmi)
1053
1054 ENTRY(int3)
1055         ASM_CLAC
1056         pushl   $-1                             # mark this as an int
1057         SAVE_ALL
1058         ENCODE_FRAME_POINTER
1059         TRACE_IRQS_OFF
1060         xorl    %edx, %edx                      # zero error code
1061         movl    %esp, %eax                      # pt_regs pointer
1062         call    do_int3
1063         jmp     ret_from_exception
1064 END(int3)
1065
1066 ENTRY(general_protection)
1067         pushl   $do_general_protection
1068         jmp     common_exception
1069 END(general_protection)
1070
1071 #ifdef CONFIG_KVM_GUEST
1072 ENTRY(async_page_fault)
1073         ASM_CLAC
1074         pushl   $do_async_page_fault
1075         jmp     common_exception
1076 END(async_page_fault)
1077 #endif
1078
1079 ENTRY(rewind_stack_do_exit)
1080         /* Prevent any naive code from trying to unwind to our caller. */
1081         xorl    %ebp, %ebp
1082
1083         movl    PER_CPU_VAR(cpu_current_top_of_stack), %esi
1084         leal    -TOP_OF_KERNEL_STACK_PADDING-PTREGS_SIZE(%esi), %esp
1085
1086         call    do_exit
1087 1:      jmp 1b
1088 END(rewind_stack_do_exit)