arch/s390/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /* ld script to make s390 Linux kernel
   3  * Written by Martin Schwidefsky (schwidefsky@de.ibm.com)
   4  */
   5
   6 #include <asm/thread_info.h>
   7 #include <asm/page.h>
   8
   9 /*
  10  * Put .bss..swapper_pg_dir as the first thing in .bss. This will
  11  * make sure it has 16k alignment.
  12  */
  13 #define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir)
  14
  15 /* Handle ro_after_init data on our own. */
  16 #define RO_AFTER_INIT_DATA
  17
  18 #include <asm-generic/vmlinux.lds.h>
  19
  20 OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
  21 OUTPUT_ARCH(s390:64-bit)
  22 ENTRY(startup_continue)
  23 jiffies = jiffies_64;
  24
  25 PHDRS {
  26         text PT_LOAD FLAGS(5);  /* R_E */
  27         data PT_LOAD FLAGS(7);  /* RWE */
  28         note PT_NOTE FLAGS(0);  /* ___ */
  29 }
  30
  31 SECTIONS
  32 {
  33         . = 0x100000;
  34         _stext = .;             /* Start of text section */
  35         .text : {
  36                 /* Text and read-only data */
  37                 _text = .;
  38                 HEAD_TEXT
  39                 TEXT_TEXT
  40                 SCHED_TEXT
  41                 CPUIDLE_TEXT
  42                 LOCK_TEXT
  43                 KPROBES_TEXT
  44                 IRQENTRY_TEXT
  45                 SOFTIRQENTRY_TEXT
  46                 *(.text.*_indirect_*)
  47                 *(.fixup)
  48                 *(.gnu.warning)
  49         } :text = 0x0700
  50
  51         . = ALIGN(PAGE_SIZE);
  52         _etext = .;             /* End of text section */
  53
  54         NOTES :text :note
  55
  56         .dummy : { *(.dummy) } :data
  57
  58         RO_DATA_SECTION(PAGE_SIZE)
  59
  60         . = ALIGN(PAGE_SIZE);
  61         _sdata = .;             /* Start of data section */
  62
  63         . = ALIGN(PAGE_SIZE);
  64         __start_ro_after_init = .;
  65         .data..ro_after_init : {
  66                  *(.data..ro_after_init)
  67         }
  68         EXCEPTION_TABLE(16)
  69         . = ALIGN(PAGE_SIZE);
  70         __end_ro_after_init = .;
  71
  72         RW_DATA_SECTION(0x100, PAGE_SIZE, THREAD_SIZE)
  73
  74         _edata = .;             /* End of data section */
  75
  76         /* will be freed after init */
  77         . = ALIGN(PAGE_SIZE);   /* Init code and data */
  78         __init_begin = .;
  79
  80         . = ALIGN(PAGE_SIZE);
  81         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  82                 _sinittext = .;
  83                 INIT_TEXT
  84                 . = ALIGN(PAGE_SIZE);
  85                 _einittext = .;
  86         }
  87
  88         /*
  89          * .exit.text is discarded at runtime, not link time,
  90          * to deal with references from __bug_table
  91         */
  92         .exit.text : {
  93                 EXIT_TEXT
  94         }
  95
  96         .exit.data : {
  97                 EXIT_DATA
  98         }
  99
 100         /*
 101          * struct alt_inst entries. From the header (alternative.h):
 102          * "Alternative instructions for different CPU types or capabilities"
 103          * Think locking instructions on spinlocks.
 104          * Note, that it is a part of __init region.
 105          */
 106         . = ALIGN(8);
 107         .altinstructions : {
 108                 __alt_instructions = .;
 109                 *(.altinstructions)
 110                 __alt_instructions_end = .;
 111         }
 112
 113         /*
 114          * And here are the replacement instructions. The linker sticks
 115          * them as binary blobs. The .altinstructions has enough data to
 116          * get the address and the length of them to patch the kernel safely.
 117          * Note, that it is a part of __init region.
 118          */
 119         .altinstr_replacement : {
 120                 *(.altinstr_replacement)
 121         }
 122
 123         /*
 124          * Table with the patch locations to undo expolines
 125         */
 126         .nospec_call_table : {
 127                 __nospec_call_start = . ;
 128                 *(.s390_indirect*)
 129                 __nospec_call_end = . ;
 130         }
 131         .nospec_return_table : {
 132                 __nospec_return_start = . ;
 133                 *(.s390_return*)
 134                 __nospec_return_end = . ;
 135         }
 136
 137         /* early.c uses stsi, which requires page aligned data. */
 138         . = ALIGN(PAGE_SIZE);
 139         INIT_DATA_SECTION(0x100)
 140
 141         PERCPU_SECTION(0x100)
 142         . = ALIGN(PAGE_SIZE);
 143         __init_end = .;         /* freed after init ends here */
 144
 145         BSS_SECTION(PAGE_SIZE, 4 * PAGE_SIZE, PAGE_SIZE)
 146
 147         _end = . ;
 148
 149         /* Debugging sections.  */
 150         STABS_DEBUG
 151         DWARF_DEBUG
 152
 153         /* Sections to be discarded */
 154         DISCARDS
 155         /DISCARD/ : {
 156                 *(.eh_frame)
 157         }
 158 }