arch/s390/kernel/swsusp.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * S390 64-bit swsusp implementation
   4  *
   5  * Copyright IBM Corp. 2009
   6  *
   7  * Author(s): Hans-Joachim Picht <hans@linux.vnet.ibm.com>
   8  *            Michael Holzheu <holzheu@linux.vnet.ibm.com>
   9  */
  10
  11 #include <linux/linkage.h>
  12 #include <asm/page.h>
  13 #include <asm/ptrace.h>
  14 #include <asm/thread_info.h>
  15 #include <asm/asm-offsets.h>
  16 #include <asm/nospec-insn.h>
  17 #include <asm/sigp.h>
  18
  19 /*
  20  * Save register context in absolute 0 lowcore and call swsusp_save() to
  21  * create in-memory kernel image. The context is saved in the designated
  22  * "store status" memory locations (see POP).
  23  * We return from this function twice. The first time during the suspend to
  24  * disk process. The second time via the swsusp_arch_resume() function
  25  * (see below) in the resume process.
  26  * This function runs with disabled interrupts.
  27  */
  28         GEN_BR_THUNK %r14
  29
  30         .section .text
  31 ENTRY(swsusp_arch_suspend)
  32         lg      %r1,__LC_NODAT_STACK
  33         stmg    %r6,%r15,__SF_GPRS(%r1)
  34         aghi    %r1,-STACK_FRAME_OVERHEAD
  35         stg     %r15,__SF_BACKCHAIN(%r1)
  36         lgr     %r15,%r1
  37
  38         /* Store FPU registers */
  39         brasl   %r14,save_fpu_regs
  40
  41         /* Deactivate DAT */
  42         stnsm   __SF_EMPTY(%r15),0xfb
  43
  44         /* Store prefix register on stack */
  45         stpx    __SF_EMPTY(%r15)
  46
  47         /* Save prefix register contents for lowcore copy */
  48         llgf    %r10,__SF_EMPTY(%r15)
  49
  50         /* Get pointer to save area */
  51         lghi    %r1,0x1000
  52
  53         /* Save CPU address */
  54         stap    __LC_EXT_CPU_ADDR(%r0)
  55
  56         /* Store registers */
  57         mvc     0x318(4,%r1),__SF_EMPTY(%r15)   /* move prefix to lowcore */
  58         stam    %a0,%a15,0x340(%r1)             /* store access registers */
  59         stctg   %c0,%c15,0x380(%r1)             /* store control registers */
  60         stmg    %r0,%r15,0x280(%r1)             /* store general registers */
  61
  62         stpt    0x328(%r1)                      /* store timer */
  63         stck    __SF_EMPTY(%r15)                /* store clock */
  64         stckc   0x330(%r1)                      /* store clock comparator */
  65
  66         /* Update cputime accounting before going to sleep */
  67         lg      %r0,__LC_LAST_UPDATE_TIMER
  68         slg     %r0,0x328(%r1)
  69         alg     %r0,__LC_SYSTEM_TIMER
  70         stg     %r0,__LC_SYSTEM_TIMER
  71         mvc     __LC_LAST_UPDATE_TIMER(8),0x328(%r1)
  72         lg      %r0,__LC_LAST_UPDATE_CLOCK
  73         slg     %r0,__SF_EMPTY(%r15)
  74         alg     %r0,__LC_STEAL_TIMER
  75         stg     %r0,__LC_STEAL_TIMER
  76         mvc     __LC_LAST_UPDATE_CLOCK(8),__SF_EMPTY(%r15)
  77
  78         /* Activate DAT */
  79         stosm   __SF_EMPTY(%r15),0x04
  80
  81         /* Set prefix page to zero */
  82         xc      __SF_EMPTY(4,%r15),__SF_EMPTY(%r15)
  83         spx     __SF_EMPTY(%r15)
  84
  85         /* Save absolute zero pages */
  86         larl    %r2,suspend_zero_pages
  87         lg      %r2,0(%r2)
  88         lghi    %r4,0
  89         lghi    %r3,2*PAGE_SIZE
  90         lghi    %r5,2*PAGE_SIZE
  91 1:      mvcle   %r2,%r4,0
  92         jo      1b
  93
  94         /* Copy lowcore to absolute zero lowcore */
  95         lghi    %r2,0
  96         lgr     %r4,%r10
  97         lghi    %r3,2*PAGE_SIZE
  98         lghi    %r5,2*PAGE_SIZE
  99 1:      mvcle   %r2,%r4,0
 100         jo      1b
 101
 102         /* Save image */
 103         brasl   %r14,swsusp_save
 104
 105         /* Restore prefix register and return */
 106         lghi    %r1,0x1000
 107         spx     0x318(%r1)
 108         lmg     %r6,%r15,STACK_FRAME_OVERHEAD + __SF_GPRS(%r15)
 109         lghi    %r2,0
 110         BR_EX   %r14
 111
 112 /*
 113  * Restore saved memory image to correct place and restore register context.
 114  * Then we return to the function that called swsusp_arch_suspend().
 115  * swsusp_arch_resume() runs with disabled interrupts.
 116  */
 117 ENTRY(swsusp_arch_resume)
 118         stmg    %r6,%r15,__SF_GPRS(%r15)
 119         lgr     %r1,%r15
 120         aghi    %r15,-STACK_FRAME_OVERHEAD
 121         stg     %r1,__SF_BACKCHAIN(%r15)
 122
 123         /* Make all free pages stable */
 124         lghi    %r2,1
 125         brasl   %r14,arch_set_page_states
 126
 127         /* Set prefix page to zero */
 128         xc      __SF_EMPTY(4,%r15),__SF_EMPTY(%r15)
 129         spx     __SF_EMPTY(%r15)
 130
 131         /* Deactivate DAT */
 132         stnsm   __SF_EMPTY(%r15),0xfb
 133
 134         /* Restore saved image */
 135         larl    %r1,restore_pblist
 136         lg      %r1,0(%r1)
 137         ltgr    %r1,%r1
 138         jz      2f
 139 0:
 140         lg      %r2,8(%r1)
 141         lg      %r4,0(%r1)
 142         iske    %r0,%r4
 143         lghi    %r3,PAGE_SIZE
 144         lghi    %r5,PAGE_SIZE
 145 1:
 146         mvcle   %r2,%r4,0
 147         jo      1b
 148         lg      %r2,8(%r1)
 149         sske    %r0,%r2
 150         lg      %r1,16(%r1)
 151         ltgr    %r1,%r1
 152         jnz     0b
 153 2:
 154         ptlb                            /* flush tlb */
 155
 156         /* Reset System */
 157         larl    %r1,restart_entry
 158         larl    %r2,.Lrestart_diag308_psw
 159         og      %r1,0(%r2)
 160         stg     %r1,0(%r0)
 161         larl    %r1,.Lnew_pgm_check_psw
 162         epsw    %r2,%r3
 163         stm     %r2,%r3,0(%r1)
 164         mvc     __LC_PGM_NEW_PSW(16,%r0),0(%r1)
 165         lghi    %r0,0
 166         diag    %r0,%r0,0x308
 167 restart_entry:
 168         lhi     %r1,1
 169         sigp    %r1,%r0,SIGP_SET_ARCHITECTURE
 170         sam64
 171 #ifdef CONFIG_SMP
 172         larl    %r1,smp_cpu_mt_shift
 173         icm     %r1,15,0(%r1)
 174         jz      smt_done
 175         llgfr   %r1,%r1
 176 smt_loop:
 177         sigp    %r1,%r0,SIGP_SET_MULTI_THREADING
 178         brc     8,smt_done                      /* accepted */
 179         brc     2,smt_loop                      /* busy, try again */
 180 smt_done:
 181 #endif
 182         larl    %r1,.Lnew_pgm_check_psw
 183         lpswe   0(%r1)
 184 pgm_check_entry:
 185
 186         /* Switch to original suspend CPU */
 187         larl    %r1,.Lresume_cpu                /* Resume CPU address: r2 */
 188         stap    0(%r1)
 189         llgh    %r2,0(%r1)
 190         llgh    %r1,__LC_EXT_CPU_ADDR(%r0)      /* Suspend CPU address: r1 */
 191         cgr     %r1,%r2
 192         je      restore_registers               /* r1 = r2 -> nothing to do */
 193         larl    %r4,.Lrestart_suspend_psw       /* Set new restart PSW */
 194         mvc     __LC_RST_NEW_PSW(16,%r0),0(%r4)
 195 3:
 196         sigp    %r9,%r1,SIGP_INITIAL_CPU_RESET  /* sigp initial cpu reset */
 197         brc     8,4f                            /* accepted */
 198         brc     2,3b                            /* busy, try again */
 199
 200         /* Suspend CPU not available -> panic */
 201         larl    %r15,init_thread_union+THREAD_SIZE-STACK_FRAME_OVERHEAD
 202         larl    %r2,.Lpanic_string
 203         brasl   %r14,sclp_early_printk_force
 204         larl    %r3,.Ldisabled_wait_31
 205         lpsw    0(%r3)
 206 4:
 207         /* Switch to suspend CPU */
 208         sigp    %r9,%r1,SIGP_RESTART    /* sigp restart to suspend CPU */
 209         brc     2,4b                    /* busy, try again */
 210 5:
 211         sigp    %r9,%r2,SIGP_STOP       /* sigp stop to current resume CPU */
 212         brc     2,5b                    /* busy, try again */
 213 6:      j       6b
 214
 215 restart_suspend:
 216         larl    %r1,.Lresume_cpu
 217         llgh    %r2,0(%r1)
 218 7:
 219         sigp    %r9,%r2,SIGP_SENSE      /* sigp sense, wait for resume CPU */
 220         brc     8,7b                    /* accepted, status 0, still running */
 221         brc     2,7b                    /* busy, try again */
 222         tmll    %r9,0x40                /* Test if resume CPU is stopped */
 223         jz      7b
 224
 225 restore_registers:
 226         /* Restore registers */
 227         lghi    %r13,0x1000             /* %r1 = pointer to save area */
 228
 229         /* Ignore time spent in suspended state. */
 230         llgf    %r1,0x318(%r13)
 231         stck    __LC_LAST_UPDATE_CLOCK(%r1)
 232         spt     0x328(%r13)             /* reprogram timer */
 233         //sckc  0x330(%r13)             /* set clock comparator */
 234
 235         lctlg   %c0,%c15,0x380(%r13)    /* load control registers */
 236         lam     %a0,%a15,0x340(%r13)    /* load access registers */
 237
 238         /* Load old stack */
 239         lg      %r15,0x2f8(%r13)
 240
 241         /* Save prefix register */
 242         mvc __SF_EMPTY(4,%r15),0x318(%r13)
 243
 244         /* Restore absolute zero pages */
 245         lghi    %r2,0
 246         larl    %r4,suspend_zero_pages
 247         lg      %r4,0(%r4)
 248         lghi    %r3,2*PAGE_SIZE
 249         lghi    %r5,2*PAGE_SIZE
 250 1:      mvcle   %r2,%r4,0
 251         jo      1b
 252
 253         /* Restore prefix register */
 254         spx     __SF_EMPTY(%r15)
 255
 256         /* Activate DAT */
 257         stosm   __SF_EMPTY(%r15),0x04
 258
 259         /* Make all free pages unstable */
 260         lghi    %r2,0
 261         brasl   %r14,arch_set_page_states
 262
 263         /* Call arch specific early resume code */
 264         brasl   %r14,s390_early_resume
 265
 266         /* Return 0 */
 267         lmg     %r6,%r15,STACK_FRAME_OVERHEAD + __SF_GPRS(%r15)
 268         lghi    %r2,0
 269         BR_EX   %r14
 270
 271         .section .data..nosave,"aw",@progbits
 272         .align  8
 273 .Ldisabled_wait_31:
 274         .long  0x000a0000,0x00000000
 275 .Lpanic_string:
 276         .asciz  "Resume not possible because suspend CPU is no longer available\n"
 277         .align  8
 278 .Lrestart_diag308_psw:
 279         .long   0x00080000,0x80000000
 280 .Lrestart_suspend_psw:
 281         .quad   0x0000000180000000,restart_suspend
 282 .Lnew_pgm_check_psw:
 283         .quad   0,pgm_check_entry
 284 .Lresume_cpu:
 285         .byte   0,0