arch/s390/kernel/head64.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * Copyright IBM Corp. 1999, 2010
   4  *
   5  *   Author(s): Hartmut Penner <hp@de.ibm.com>
   6  *              Martin Schwidefsky <schwidefsky@de.ibm.com>
   7  *              Rob van der Heij <rvdhei@iae.nl>
   8  *              Heiko Carstens <heiko.carstens@de.ibm.com>
   9  *
  10  */
  11
  12 #include <linux/init.h>
  13 #include <linux/linkage.h>
  14 #include <asm/asm-offsets.h>
  15 #include <asm/thread_info.h>
  16 #include <asm/page.h>
  17 #include <asm/ptrace.h>
  18
  19 __HEAD
  20 ENTRY(startup_continue)
  21         tm      __LC_STFLE_FAC_LIST+5,0x80      # LPP available ?
  22         jz      0f
  23         xc      __LC_LPP+1(7,0),__LC_LPP+1      # clear lpp and current_pid
  24         mvi     __LC_LPP,0x80                   #   and set LPP_MAGIC
  25         .insn   s,0xb2800000,__LC_LPP           # load program parameter
  26 0:      larl    %r1,tod_clock_base
  27         mvc     0(16,%r1),__LC_BOOT_CLOCK
  28         larl    %r13,.LPG1              # get base
  29         larl    %r0,boot_vdso_data
  30         stg     %r0,__LC_VDSO_PER_CPU
  31 #
  32 # Setup stack
  33 #
  34         larl    %r14,init_task
  35         stg     %r14,__LC_CURRENT
  36         larl    %r15,init_thread_union+THREAD_SIZE-STACK_FRAME_OVERHEAD
  37 #ifdef CONFIG_KASAN
  38         brasl   %r14,kasan_early_init
  39 #endif
  40 #
  41 # Early machine initialization and detection functions.
  42 #
  43         brasl   %r14,startup_init
  44
  45 # check control registers
  46         stctg   %c0,%c15,0(%r15)
  47         oi      6(%r15),0x60            # enable sigp emergency & external call
  48         oi      4(%r15),0x10            # switch on low address proctection
  49         lctlg   %c0,%c15,0(%r15)
  50
  51         lam     0,15,.Laregs-.LPG1(%r13)        # load acrs needed by uaccess
  52         brasl   %r14,start_kernel               # go to C code
  53 #
  54 # We returned from start_kernel ?!? PANIK
  55 #
  56         basr    %r13,0
  57         lpswe   .Ldw-.(%r13)            # load disabled wait psw
  58
  59         .align  16
  60 .LPG1:
  61 .Ldw:   .quad   0x0002000180000000,0x0000000000000000
  62 .Laregs:.long   0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0