arch/powerpc/kernel/exceptions-64s.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * This file contains the 64-bit "server" PowerPC variant
   4  * of the low level exception handling including exception
   5  * vectors, exception return, part of the slb and stab
   6  * handling and other fixed offset specific things.
   7  *
   8  * This file is meant to be #included from head_64.S due to
   9  * position dependent assembly.
  10  *
  11  * Most of this originates from head_64.S and thus has the same
  12  * copyright history.
  13  *
  14  */
  15
  16 #include <asm/hw_irq.h>
  17 #include <asm/exception-64s.h>
  18 #include <asm/ptrace.h>
  19 #include <asm/cpuidle.h>
  20 #include <asm/head-64.h>
  21 #include <asm/feature-fixups.h>
  22 #include <asm/kup.h>
  23
  24 /* PACA save area offsets (exgen, exmc, etc) */
  25 #define EX_R9           0
  26 #define EX_R10          8
  27 #define EX_R11          16
  28 #define EX_R12          24
  29 #define EX_R13          32
  30 #define EX_DAR          40
  31 #define EX_DSISR        48
  32 #define EX_CCR          52
  33 #define EX_CFAR         56
  34 #define EX_PPR          64
  35 #define EX_CTR          72
  36 .if EX_SIZE != 10
  37         .error "EX_SIZE is wrong"
  38 .endif
  39
  40 /*
  41  * Following are fixed section helper macros.
  42  *
  43  * EXC_REAL_BEGIN/END  - real, unrelocated exception vectors
  44  * EXC_VIRT_BEGIN/END  - virt (AIL), unrelocated exception vectors
  45  * TRAMP_REAL_BEGIN    - real, unrelocated helpers (virt may call these)
  46  * TRAMP_VIRT_BEGIN    - virt, unreloc helpers (in practice, real can use)
  47  * EXC_COMMON          - After switching to virtual, relocated mode.
  48  */
  49
  50 #define EXC_REAL_BEGIN(name, start, size)                       \
  51         FIXED_SECTION_ENTRY_BEGIN_LOCATION(real_vectors, exc_real_##start##_##name, start, size)
  52
  53 #define EXC_REAL_END(name, start, size)                         \
  54         FIXED_SECTION_ENTRY_END_LOCATION(real_vectors, exc_real_##start##_##name, start, size)
  55
  56 #define EXC_VIRT_BEGIN(name, start, size)                       \
  57         FIXED_SECTION_ENTRY_BEGIN_LOCATION(virt_vectors, exc_virt_##start##_##name, start, size)
  58
  59 #define EXC_VIRT_END(name, start, size)                         \
  60         FIXED_SECTION_ENTRY_END_LOCATION(virt_vectors, exc_virt_##start##_##name, start, size)
  61
  62 #define EXC_COMMON_BEGIN(name)                                  \
  63         USE_TEXT_SECTION();                                     \
  64         .balign IFETCH_ALIGN_BYTES;                             \
  65         .global name;                                           \
  66         _ASM_NOKPROBE_SYMBOL(name);                             \
  67         DEFINE_FIXED_SYMBOL(name);                              \
  68 name:
  69
  70 #define TRAMP_REAL_BEGIN(name)                                  \
  71         FIXED_SECTION_ENTRY_BEGIN(real_trampolines, name)
  72
  73 #define TRAMP_VIRT_BEGIN(name)                                  \
  74         FIXED_SECTION_ENTRY_BEGIN(virt_trampolines, name)
  75
  76 #define EXC_REAL_NONE(start, size)                              \
  77         FIXED_SECTION_ENTRY_BEGIN_LOCATION(real_vectors, exc_real_##start##_##unused, start, size); \
  78         FIXED_SECTION_ENTRY_END_LOCATION(real_vectors, exc_real_##start##_##unused, start, size)
  79
  80 #define EXC_VIRT_NONE(start, size)                              \
  81         FIXED_SECTION_ENTRY_BEGIN_LOCATION(virt_vectors, exc_virt_##start##_##unused, start, size); \
  82         FIXED_SECTION_ENTRY_END_LOCATION(virt_vectors, exc_virt_##start##_##unused, start, size)
  83
  84 /*
  85  * We're short on space and time in the exception prolog, so we can't
  86  * use the normal LOAD_REG_IMMEDIATE macro to load the address of label.
  87  * Instead we get the base of the kernel from paca->kernelbase and or in the low
  88  * part of label. This requires that the label be within 64KB of kernelbase, and
  89  * that kernelbase be 64K aligned.
  90  */
  91 #define LOAD_HANDLER(reg, label)                                        \
  92         ld      reg,PACAKBASE(r13);     /* get high part of &label */   \
  93         ori     reg,reg,FIXED_SYMBOL_ABS_ADDR(label)
  94
  95 #define __LOAD_HANDLER(reg, label)                                      \
  96         ld      reg,PACAKBASE(r13);                                     \
  97         ori     reg,reg,(ABS_ADDR(label))@l
  98
  99 /*
 100  * Branches from unrelocated code (e.g., interrupts) to labels outside
 101  * head-y require >64K offsets.
 102  */
 103 #define __LOAD_FAR_HANDLER(reg, label)                                  \
 104         ld      reg,PACAKBASE(r13);                                     \
 105         ori     reg,reg,(ABS_ADDR(label))@l;                            \
 106         addis   reg,reg,(ABS_ADDR(label))@h
 107
 108 /*
 109  * Branch to label using its 0xC000 address. This results in instruction
 110  * address suitable for MSR[IR]=0 or 1, which allows relocation to be turned
 111  * on using mtmsr rather than rfid.
 112  *
 113  * This could set the 0xc bits for !RELOCATABLE as an immediate, rather than
 114  * load KBASE for a slight optimisation.
 115  */
 116 #define BRANCH_TO_C000(reg, label)                                      \
 117         __LOAD_FAR_HANDLER(reg, label);                                 \
 118         mtctr   reg;                                                    \
 119         bctr
 120
 121 /*
 122  * Interrupt code generation macros
 123  */
 124 #define IVEC            .L_IVEC_\name\()        /* Interrupt vector address */
 125 #define IHSRR           .L_IHSRR_\name\()       /* Sets SRR or HSRR registers */
 126 #define IHSRR_IF_HVMODE .L_IHSRR_IF_HVMODE_\name\() /* HSRR if HV else SRR */
 127 #define IAREA           .L_IAREA_\name\()       /* PACA save area */
 128 #define IVIRT           .L_IVIRT_\name\()       /* Has virt mode entry point */
 129 #define IISIDE          .L_IISIDE_\name\()      /* Uses SRR0/1 not DAR/DSISR */
 130 #define IDAR            .L_IDAR_\name\()        /* Uses DAR (or SRR0) */
 131 #define IDSISR          .L_IDSISR_\name\()      /* Uses DSISR (or SRR1) */
 132 #define ISET_RI         .L_ISET_RI_\name\()     /* Run common code w/ MSR[RI]=1 */
 133 #define IBRANCH_TO_COMMON       .L_IBRANCH_TO_COMMON_\name\() /* ENTRY branch to common */
 134 #define IREALMODE_COMMON        .L_IREALMODE_COMMON_\name\() /* Common runs in realmode */
 135 #define IMASK           .L_IMASK_\name\()       /* IRQ soft-mask bit */
 136 #define IKVM_SKIP       .L_IKVM_SKIP_\name\()   /* Generate KVM skip handler */
 137 #define IKVM_REAL       .L_IKVM_REAL_\name\()   /* Real entry tests KVM */
 138 #define __IKVM_REAL(name)       .L_IKVM_REAL_ ## name
 139 #define IKVM_VIRT       .L_IKVM_VIRT_\name\()   /* Virt entry tests KVM */
 140 #define ISTACK          .L_ISTACK_\name\()      /* Set regular kernel stack */
 141 #define __ISTACK(name)  .L_ISTACK_ ## name
 142 #define IRECONCILE      .L_IRECONCILE_\name\()  /* Do RECONCILE_IRQ_STATE */
 143 #define IKUAP           .L_IKUAP_\name\()       /* Do KUAP lock */
 144
 145 #define INT_DEFINE_BEGIN(n)                                             \
 146 .macro int_define_ ## n name
 147
 148 #define INT_DEFINE_END(n)                                               \
 149 .endm ;                                                                 \
 150 int_define_ ## n n ;                                                    \
 151 do_define_int n
 152
 153 .macro do_define_int name
 154         .ifndef IVEC
 155                 .error "IVEC not defined"
 156         .endif
 157         .ifndef IHSRR
 158                 IHSRR=0
 159         .endif
 160         .ifndef IHSRR_IF_HVMODE
 161                 IHSRR_IF_HVMODE=0
 162         .endif
 163         .ifndef IAREA
 164                 IAREA=PACA_EXGEN
 165         .endif
 166         .ifndef IVIRT
 167                 IVIRT=1
 168         .endif
 169         .ifndef IISIDE
 170                 IISIDE=0
 171         .endif
 172         .ifndef IDAR
 173                 IDAR=0
 174         .endif
 175         .ifndef IDSISR
 176                 IDSISR=0
 177         .endif
 178         .ifndef ISET_RI
 179                 ISET_RI=1
 180         .endif
 181         .ifndef IBRANCH_TO_COMMON
 182                 IBRANCH_TO_COMMON=1
 183         .endif
 184         .ifndef IREALMODE_COMMON
 185                 IREALMODE_COMMON=0
 186         .else
 187                 .if ! IBRANCH_TO_COMMON
 188                         .error "IREALMODE_COMMON=1 but IBRANCH_TO_COMMON=0"
 189                 .endif
 190         .endif
 191         .ifndef IMASK
 192                 IMASK=0
 193         .endif
 194         .ifndef IKVM_SKIP
 195                 IKVM_SKIP=0
 196         .endif
 197         .ifndef IKVM_REAL
 198                 IKVM_REAL=0
 199         .endif
 200         .ifndef IKVM_VIRT
 201                 IKVM_VIRT=0
 202         .endif
 203         .ifndef ISTACK
 204                 ISTACK=1
 205         .endif
 206         .ifndef IRECONCILE
 207                 IRECONCILE=1
 208         .endif
 209         .ifndef IKUAP
 210                 IKUAP=1
 211         .endif
 212 .endm
 213
 214 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
 215 #ifdef CONFIG_KVM_BOOK3S_HV_POSSIBLE
 216 /*
 217  * All interrupts which set HSRR registers, as well as SRESET and MCE and
 218  * syscall when invoked with "sc 1" switch to MSR[HV]=1 (HVMODE) to be taken,
 219  * so they all generally need to test whether they were taken in guest context.
 220  *
 221  * Note: SRESET and MCE may also be sent to the guest by the hypervisor, and be
 222  * taken with MSR[HV]=0.
 223  *
 224  * Interrupts which set SRR registers (with the above exceptions) do not
 225  * elevate to MSR[HV]=1 mode, though most can be taken when running with
 226  * MSR[HV]=1  (e.g., bare metal kernel and userspace). So these interrupts do
 227  * not need to test whether a guest is running because they get delivered to
 228  * the guest directly, including nested HV KVM guests.
 229  *
 230  * The exception is PR KVM, where the guest runs with MSR[PR]=1 and the host
 231  * runs with MSR[HV]=0, so the host takes all interrupts on behalf of the
 232  * guest. PR KVM runs with LPCR[AIL]=0 which causes interrupts to always be
 233  * delivered to the real-mode entry point, therefore such interrupts only test
 234  * KVM in their real mode handlers, and only when PR KVM is possible.
 235  *
 236  * Interrupts that are taken in MSR[HV]=0 and escalate to MSR[HV]=1 are always
 237  * delivered in real-mode when the MMU is in hash mode because the MMU
 238  * registers are not set appropriately to translate host addresses. In nested
 239  * radix mode these can be delivered in virt-mode as the host translations are
 240  * used implicitly (see: effective LPID, effective PID).
 241  */
 242
 243 /*
 244  * If an interrupt is taken while a guest is running, it is immediately routed
 245  * to KVM to handle. If both HV and PR KVM arepossible, KVM interrupts go first
 246  * to kvmppc_interrupt_hv, which handles the PR guest case.
 247  */
 248 #define kvmppc_interrupt kvmppc_interrupt_hv
 249 #else
 250 #define kvmppc_interrupt kvmppc_interrupt_pr
 251 #endif
 252
 253 .macro KVMTEST name
 254         lbz     r10,HSTATE_IN_GUEST(r13)
 255         cmpwi   r10,0
 256         bne     \name\()_kvm
 257 .endm
 258
 259 .macro GEN_KVM name
 260         .balign IFETCH_ALIGN_BYTES
 261 \name\()_kvm:
 262
 263         .if IKVM_SKIP
 264         cmpwi   r10,KVM_GUEST_MODE_SKIP
 265         beq     89f
 266         .else
 267 BEGIN_FTR_SECTION
 268         ld      r10,IAREA+EX_CFAR(r13)
 269         std     r10,HSTATE_CFAR(r13)
 270 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
 271         .endif
 272
 273         ld      r10,IAREA+EX_CTR(r13)
 274         mtctr   r10
 275 BEGIN_FTR_SECTION
 276         ld      r10,IAREA+EX_PPR(r13)
 277         std     r10,HSTATE_PPR(r13)
 278 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 279         ld      r11,IAREA+EX_R11(r13)
 280         ld      r12,IAREA+EX_R12(r13)
 281         std     r12,HSTATE_SCRATCH0(r13)
 282         sldi    r12,r9,32
 283         ld      r9,IAREA+EX_R9(r13)
 284         ld      r10,IAREA+EX_R10(r13)
 285         /* HSRR variants have the 0x2 bit added to their trap number */
 286         .if IHSRR_IF_HVMODE
 287         BEGIN_FTR_SECTION
 288         ori     r12,r12,(IVEC + 0x2)
 289         FTR_SECTION_ELSE
 290         ori     r12,r12,(IVEC)
 291         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 292         .elseif IHSRR
 293         ori     r12,r12,(IVEC+ 0x2)
 294         .else
 295         ori     r12,r12,(IVEC)
 296         .endif
 297         b       kvmppc_interrupt
 298
 299         .if IKVM_SKIP
 300 89:     mtocrf  0x80,r9
 301         ld      r10,IAREA+EX_CTR(r13)
 302         mtctr   r10
 303         ld      r9,IAREA+EX_R9(r13)
 304         ld      r10,IAREA+EX_R10(r13)
 305         ld      r11,IAREA+EX_R11(r13)
 306         ld      r12,IAREA+EX_R12(r13)
 307         .if IHSRR_IF_HVMODE
 308         BEGIN_FTR_SECTION
 309         b       kvmppc_skip_Hinterrupt
 310         FTR_SECTION_ELSE
 311         b       kvmppc_skip_interrupt
 312         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 313         .elseif IHSRR
 314         b       kvmppc_skip_Hinterrupt
 315         .else
 316         b       kvmppc_skip_interrupt
 317         .endif
 318         .endif
 319 .endm
 320
 321 #else
 322 .macro KVMTEST name
 323 .endm
 324 .macro GEN_KVM name
 325 .endm
 326 #endif
 327
 328 /*
 329  * This is the BOOK3S interrupt entry code macro.
 330  *
 331  * This can result in one of several things happening:
 332  * - Branch to the _common handler, relocated, in virtual mode.
 333  *   These are normal interrupts (synchronous and asynchronous) handled by
 334  *   the kernel.
 335  * - Branch to KVM, relocated but real mode interrupts remain in real mode.
 336  *   These occur when HSTATE_IN_GUEST is set. The interrupt may be caused by
 337  *   / intended for host or guest kernel, but KVM must always be involved
 338  *   because the machine state is set for guest execution.
 339  * - Branch to the masked handler, unrelocated.
 340  *   These occur when maskable asynchronous interrupts are taken with the
 341  *   irq_soft_mask set.
 342  * - Branch to an "early" handler in real mode but relocated.
 343  *   This is done if early=1. MCE and HMI use these to handle errors in real
 344  *   mode.
 345  * - Fall through and continue executing in real, unrelocated mode.
 346  *   This is done if early=2.
 347  */
 348
 349 .macro GEN_BRANCH_TO_COMMON name, virt
 350         .if IREALMODE_COMMON
 351         LOAD_HANDLER(r10, \name\()_common)
 352         mtctr   r10
 353         bctr
 354         .else
 355         .if \virt
 356 #ifndef CONFIG_RELOCATABLE
 357         b       \name\()_common_virt
 358 #else
 359         LOAD_HANDLER(r10, \name\()_common_virt)
 360         mtctr   r10
 361         bctr
 362 #endif
 363         .else
 364         LOAD_HANDLER(r10, \name\()_common_real)
 365         mtctr   r10
 366         bctr
 367         .endif
 368         .endif
 369 .endm
 370
 371 .macro GEN_INT_ENTRY name, virt, ool=0
 372         SET_SCRATCH0(r13)                       /* save r13 */
 373         GET_PACA(r13)
 374         std     r9,IAREA+EX_R9(r13)             /* save r9 */
 375 BEGIN_FTR_SECTION
 376         mfspr   r9,SPRN_PPR
 377 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 378         HMT_MEDIUM
 379         std     r10,IAREA+EX_R10(r13)           /* save r10 - r12 */
 380 BEGIN_FTR_SECTION
 381         mfspr   r10,SPRN_CFAR
 382 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
 383         .if \ool
 384         .if !\virt
 385         b       tramp_real_\name
 386         .pushsection .text
 387         TRAMP_REAL_BEGIN(tramp_real_\name)
 388         .else
 389         b       tramp_virt_\name
 390         .pushsection .text
 391         TRAMP_VIRT_BEGIN(tramp_virt_\name)
 392         .endif
 393         .endif
 394
 395 BEGIN_FTR_SECTION
 396         std     r9,IAREA+EX_PPR(r13)
 397 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 398 BEGIN_FTR_SECTION
 399         std     r10,IAREA+EX_CFAR(r13)
 400 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
 401         INTERRUPT_TO_KERNEL
 402         mfctr   r10
 403         std     r10,IAREA+EX_CTR(r13)
 404         mfcr    r9
 405         std     r11,IAREA+EX_R11(r13)
 406         std     r12,IAREA+EX_R12(r13)
 407
 408         /*
 409          * DAR/DSISR, SCRATCH0 must be read before setting MSR[RI],
 410          * because a d-side MCE will clobber those registers so is
 411          * not recoverable if they are live.
 412          */
 413         GET_SCRATCH0(r10)
 414         std     r10,IAREA+EX_R13(r13)
 415         .if IDAR && !IISIDE
 416         .if IHSRR
 417         mfspr   r10,SPRN_HDAR
 418         .else
 419         mfspr   r10,SPRN_DAR
 420         .endif
 421         std     r10,IAREA+EX_DAR(r13)
 422         .endif
 423         .if IDSISR && !IISIDE
 424         .if IHSRR
 425         mfspr   r10,SPRN_HDSISR
 426         .else
 427         mfspr   r10,SPRN_DSISR
 428         .endif
 429         stw     r10,IAREA+EX_DSISR(r13)
 430         .endif
 431
 432         .if IHSRR_IF_HVMODE
 433         BEGIN_FTR_SECTION
 434         mfspr   r11,SPRN_HSRR0          /* save HSRR0 */
 435         mfspr   r12,SPRN_HSRR1          /* and HSRR1 */
 436         FTR_SECTION_ELSE
 437         mfspr   r11,SPRN_SRR0           /* save SRR0 */
 438         mfspr   r12,SPRN_SRR1           /* and SRR1 */
 439         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 440         .elseif IHSRR
 441         mfspr   r11,SPRN_HSRR0          /* save HSRR0 */
 442         mfspr   r12,SPRN_HSRR1          /* and HSRR1 */
 443         .else
 444         mfspr   r11,SPRN_SRR0           /* save SRR0 */
 445         mfspr   r12,SPRN_SRR1           /* and SRR1 */
 446         .endif
 447
 448         .if IBRANCH_TO_COMMON
 449         GEN_BRANCH_TO_COMMON \name \virt
 450         .endif
 451
 452         .if \ool
 453         .popsection
 454         .endif
 455 .endm
 456
 457 /*
 458  * __GEN_COMMON_ENTRY is required to receive the branch from interrupt
 459  * entry, except in the case of the real-mode handlers which require
 460  * __GEN_REALMODE_COMMON_ENTRY.
 461  *
 462  * This switches to virtual mode and sets MSR[RI].
 463  */
 464 .macro __GEN_COMMON_ENTRY name
 465 DEFINE_FIXED_SYMBOL(\name\()_common_real)
 466 \name\()_common_real:
 467         .if IKVM_REAL
 468                 KVMTEST \name
 469         .endif
 470
 471         ld      r10,PACAKMSR(r13)       /* get MSR value for kernel */
 472         /* MSR[RI] is clear iff using SRR regs */
 473         .if IHSRR == EXC_HV_OR_STD
 474         BEGIN_FTR_SECTION
 475         xori    r10,r10,MSR_RI
 476         END_FTR_SECTION_IFCLR(CPU_FTR_HVMODE)
 477         .elseif ! IHSRR
 478         xori    r10,r10,MSR_RI
 479         .endif
 480         mtmsrd  r10
 481
 482         .if IVIRT
 483         .if IKVM_VIRT
 484         b       1f /* skip the virt test coming from real */
 485         .endif
 486
 487         .balign IFETCH_ALIGN_BYTES
 488 DEFINE_FIXED_SYMBOL(\name\()_common_virt)
 489 \name\()_common_virt:
 490         .if IKVM_VIRT
 491                 KVMTEST \name
 492 1:
 493         .endif
 494         .endif /* IVIRT */
 495 .endm
 496
 497 /*
 498  * Don't switch to virt mode. Used for early MCE and HMI handlers that
 499  * want to run in real mode.
 500  */
 501 .macro __GEN_REALMODE_COMMON_ENTRY name
 502 DEFINE_FIXED_SYMBOL(\name\()_common_real)
 503 \name\()_common_real:
 504         .if IKVM_REAL
 505                 KVMTEST \name
 506         .endif
 507 .endm
 508
 509 .macro __GEN_COMMON_BODY name
 510         .if IMASK
 511                 .if ! ISTACK
 512                 .error "No support for masked interrupt to use custom stack"
 513                 .endif
 514
 515                 /* If coming from user, skip soft-mask tests. */
 516                 andi.   r10,r12,MSR_PR
 517                 bne     2f
 518
 519                 /* Kernel code running below __end_interrupts is implicitly
 520                  * soft-masked */
 521                 LOAD_HANDLER(r10, __end_interrupts)
 522                 cmpld   r11,r10
 523                 li      r10,IMASK
 524                 blt-    1f
 525
 526                 /* Test the soft mask state against our interrupt's bit */
 527                 lbz     r10,PACAIRQSOFTMASK(r13)
 528 1:              andi.   r10,r10,IMASK
 529                 /* Associate vector numbers with bits in paca->irq_happened */
 530                 .if IVEC == 0x500 || IVEC == 0xea0
 531                 li      r10,PACA_IRQ_EE
 532                 .elseif IVEC == 0x900
 533                 li      r10,PACA_IRQ_DEC
 534                 .elseif IVEC == 0xa00 || IVEC == 0xe80
 535                 li      r10,PACA_IRQ_DBELL
 536                 .elseif IVEC == 0xe60
 537                 li      r10,PACA_IRQ_HMI
 538                 .elseif IVEC == 0xf00
 539                 li      r10,PACA_IRQ_PMI
 540                 .else
 541                 .abort "Bad maskable vector"
 542                 .endif
 543
 544                 .if IHSRR_IF_HVMODE
 545                 BEGIN_FTR_SECTION
 546                 bne     masked_Hinterrupt
 547                 FTR_SECTION_ELSE
 548                 bne     masked_interrupt
 549                 ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 550                 .elseif IHSRR
 551                 bne     masked_Hinterrupt
 552                 .else
 553                 bne     masked_interrupt
 554                 .endif
 555         .endif
 556
 557         .if ISTACK
 558         andi.   r10,r12,MSR_PR          /* See if coming from user      */
 559 2:      mr      r10,r1                  /* Save r1                      */
 560         subi    r1,r1,INT_FRAME_SIZE    /* alloc frame on kernel stack  */
 561         beq-    100f
 562         ld      r1,PACAKSAVE(r13)       /* kernel stack to use          */
 563 100:    tdgei   r1,-INT_FRAME_SIZE      /* trap if r1 is in userspace   */
 564         EMIT_BUG_ENTRY 100b,__FILE__,__LINE__,0
 565         .endif
 566
 567         std     r9,_CCR(r1)             /* save CR in stackframe        */
 568         std     r11,_NIP(r1)            /* save SRR0 in stackframe      */
 569         std     r12,_MSR(r1)            /* save SRR1 in stackframe      */
 570         std     r10,0(r1)               /* make stack chain pointer     */
 571         std     r0,GPR0(r1)             /* save r0 in stackframe        */
 572         std     r10,GPR1(r1)            /* save r1 in stackframe        */
 573
 574         .if ISET_RI
 575         li      r10,MSR_RI
 576         mtmsrd  r10,1                   /* Set MSR_RI */
 577         .endif
 578
 579         .if ISTACK
 580         .if IKUAP
 581         kuap_save_amr_and_lock r9, r10, cr1, cr0
 582         .endif
 583         beq     101f                    /* if from kernel mode          */
 584         ACCOUNT_CPU_USER_ENTRY(r13, r9, r10)
 585 BEGIN_FTR_SECTION
 586         ld      r9,IAREA+EX_PPR(r13)    /* Read PPR from paca           */
 587         std     r9,_PPR(r1)
 588 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
 589 101:
 590         .else
 591         .if IKUAP
 592         kuap_save_amr_and_lock r9, r10, cr1
 593         .endif
 594         .endif
 595
 596         /* Save original regs values from save area to stack frame. */
 597         ld      r9,IAREA+EX_R9(r13)     /* move r9, r10 to stackframe   */
 598         ld      r10,IAREA+EX_R10(r13)
 599         std     r9,GPR9(r1)
 600         std     r10,GPR10(r1)
 601         ld      r9,IAREA+EX_R11(r13)    /* move r11 - r13 to stackframe */
 602         ld      r10,IAREA+EX_R12(r13)
 603         ld      r11,IAREA+EX_R13(r13)
 604         std     r9,GPR11(r1)
 605         std     r10,GPR12(r1)
 606         std     r11,GPR13(r1)
 607
 608         SAVE_NVGPRS(r1)
 609
 610         .if IDAR
 611         .if IISIDE
 612         ld      r10,_NIP(r1)
 613         .else
 614         ld      r10,IAREA+EX_DAR(r13)
 615         .endif
 616         std     r10,_DAR(r1)
 617         .endif
 618
 619         .if IDSISR
 620         .if IISIDE
 621         ld      r10,_MSR(r1)
 622         lis     r11,DSISR_SRR1_MATCH_64S@h
 623         and     r10,r10,r11
 624         .else
 625         lwz     r10,IAREA+EX_DSISR(r13)
 626         .endif
 627         std     r10,_DSISR(r1)
 628         .endif
 629
 630 BEGIN_FTR_SECTION
 631         ld      r10,IAREA+EX_CFAR(r13)
 632         std     r10,ORIG_GPR3(r1)
 633 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
 634         ld      r10,IAREA+EX_CTR(r13)
 635         std     r10,_CTR(r1)
 636         std     r2,GPR2(r1)             /* save r2 in stackframe        */
 637         SAVE_4GPRS(3, r1)               /* save r3 - r6 in stackframe   */
 638         SAVE_2GPRS(7, r1)               /* save r7, r8 in stackframe    */
 639         mflr    r9                      /* Get LR, later save to stack  */
 640         ld      r2,PACATOC(r13)         /* get kernel TOC into r2       */
 641         std     r9,_LINK(r1)
 642         lbz     r10,PACAIRQSOFTMASK(r13)
 643         mfspr   r11,SPRN_XER            /* save XER in stackframe       */
 644         std     r10,SOFTE(r1)
 645         std     r11,_XER(r1)
 646         li      r9,IVEC
 647         std     r9,_TRAP(r1)            /* set trap number              */
 648         li      r10,0
 649         ld      r11,exception_marker@toc(r2)
 650         std     r10,RESULT(r1)          /* clear regs->result           */
 651         std     r11,STACK_FRAME_OVERHEAD-16(r1) /* mark the frame       */
 652
 653         .if ISTACK
 654         ACCOUNT_STOLEN_TIME
 655         .endif
 656
 657         .if IRECONCILE
 658         RECONCILE_IRQ_STATE(r10, r11)
 659         .endif
 660 .endm
 661
 662 /*
 663  * On entry r13 points to the paca, r9-r13 are saved in the paca,
 664  * r9 contains the saved CR, r11 and r12 contain the saved SRR0 and
 665  * SRR1, and relocation is on.
 666  *
 667  * If stack=0, then the stack is already set in r1, and r1 is saved in r10.
 668  * PPR save and CPU accounting is not done for the !stack case (XXX why not?)
 669  */
 670 .macro GEN_COMMON name
 671         __GEN_COMMON_ENTRY \name
 672         __GEN_COMMON_BODY \name
 673 .endm
 674
 675 /*
 676  * Restore all registers including H/SRR0/1 saved in a stack frame of a
 677  * standard exception.
 678  */
 679 .macro EXCEPTION_RESTORE_REGS hsrr=0
 680         /* Move original SRR0 and SRR1 into the respective regs */
 681         ld      r9,_MSR(r1)
 682         .if \hsrr
 683         mtspr   SPRN_HSRR1,r9
 684         .else
 685         mtspr   SPRN_SRR1,r9
 686         .endif
 687         ld      r9,_NIP(r1)
 688         .if \hsrr
 689         mtspr   SPRN_HSRR0,r9
 690         .else
 691         mtspr   SPRN_SRR0,r9
 692         .endif
 693         ld      r9,_CTR(r1)
 694         mtctr   r9
 695         ld      r9,_XER(r1)
 696         mtxer   r9
 697         ld      r9,_LINK(r1)
 698         mtlr    r9
 699         ld      r9,_CCR(r1)
 700         mtcr    r9
 701         REST_8GPRS(2, r1)
 702         REST_4GPRS(10, r1)
 703         REST_GPR(0, r1)
 704         /* restore original r1. */
 705         ld      r1,GPR1(r1)
 706 .endm
 707
 708 #define RUNLATCH_ON                             \
 709 BEGIN_FTR_SECTION                               \
 710         ld      r3, PACA_THREAD_INFO(r13);      \
 711         ld      r4,TI_LOCAL_FLAGS(r3);          \
 712         andi.   r0,r4,_TLF_RUNLATCH;            \
 713         beql    ppc64_runlatch_on_trampoline;   \
 714 END_FTR_SECTION_IFSET(CPU_FTR_CTRL)
 715
 716 /*
 717  * When the idle code in power4_idle puts the CPU into NAP mode,
 718  * it has to do so in a loop, and relies on the external interrupt
 719  * and decrementer interrupt entry code to get it out of the loop.
 720  * It sets the _TLF_NAPPING bit in current_thread_info()->local_flags
 721  * to signal that it is in the loop and needs help to get out.
 722  */
 723 #ifdef CONFIG_PPC_970_NAP
 724 #define FINISH_NAP                              \
 725 BEGIN_FTR_SECTION                               \
 726         ld      r11, PACA_THREAD_INFO(r13);     \
 727         ld      r9,TI_LOCAL_FLAGS(r11);         \
 728         andi.   r10,r9,_TLF_NAPPING;            \
 729         bnel    power4_fixup_nap;               \
 730 END_FTR_SECTION_IFSET(CPU_FTR_CAN_NAP)
 731 #else
 732 #define FINISH_NAP
 733 #endif
 734
 735 /*
 736  * There are a few constraints to be concerned with.
 737  * - Real mode exceptions code/data must be located at their physical location.
 738  * - Virtual mode exceptions must be mapped at their 0xc000... location.
 739  * - Fixed location code must not call directly beyond the __end_interrupts
 740  *   area when built with CONFIG_RELOCATABLE. LOAD_HANDLER / bctr sequence
 741  *   must be used.
 742  * - LOAD_HANDLER targets must be within first 64K of physical 0 /
 743  *   virtual 0xc00...
 744  * - Conditional branch targets must be within +/-32K of caller.
 745  *
 746  * "Virtual exceptions" run with relocation on (MSR_IR=1, MSR_DR=1), and
 747  * therefore don't have to run in physically located code or rfid to
 748  * virtual mode kernel code. However on relocatable kernels they do have
 749  * to branch to KERNELBASE offset because the rest of the kernel (outside
 750  * the exception vectors) may be located elsewhere.
 751  *
 752  * Virtual exceptions correspond with physical, except their entry points
 753  * are offset by 0xc000000000000000 and also tend to get an added 0x4000
 754  * offset applied. Virtual exceptions are enabled with the Alternate
 755  * Interrupt Location (AIL) bit set in the LPCR. However this does not
 756  * guarantee they will be delivered virtually. Some conditions (see the ISA)
 757  * cause exceptions to be delivered in real mode.
 758  *
 759  * The scv instructions are a special case. They get a 0x3000 offset applied.
 760  * scv exceptions have unique reentrancy properties, see below.
 761  *
 762  * It's impossible to receive interrupts below 0x300 via AIL.
 763  *
 764  * KVM: None of the virtual exceptions are from the guest. Anything that
 765  * escalated to HV=1 from HV=0 is delivered via real mode handlers.
 766  *
 767  *
 768  * We layout physical memory as follows:
 769  * 0x0000 - 0x00ff : Secondary processor spin code
 770  * 0x0100 - 0x18ff : Real mode pSeries interrupt vectors
 771  * 0x1900 - 0x2fff : Real mode trampolines
 772  * 0x3000 - 0x58ff : Relon (IR=1,DR=1) mode pSeries interrupt vectors
 773  * 0x5900 - 0x6fff : Relon mode trampolines
 774  * 0x7000 - 0x7fff : FWNMI data area
 775  * 0x8000 -   .... : Common interrupt handlers, remaining early
 776  *                   setup code, rest of kernel.
 777  *
 778  * We could reclaim 0x4000-0x42ff for real mode trampolines if the space
 779  * is necessary. Until then it's more consistent to explicitly put VIRT_NONE
 780  * vectors there.
 781  */
 782 OPEN_FIXED_SECTION(real_vectors,        0x0100, 0x1900)
 783 OPEN_FIXED_SECTION(real_trampolines,    0x1900, 0x3000)
 784 OPEN_FIXED_SECTION(virt_vectors,        0x3000, 0x5900)
 785 OPEN_FIXED_SECTION(virt_trampolines,    0x5900, 0x7000)
 786
 787 #ifdef CONFIG_PPC_POWERNV
 788         .globl start_real_trampolines
 789         .globl end_real_trampolines
 790         .globl start_virt_trampolines
 791         .globl end_virt_trampolines
 792 #endif
 793
 794 #if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
 795 /*
 796  * Data area reserved for FWNMI option.
 797  * This address (0x7000) is fixed by the RPA.
 798  * pseries and powernv need to keep the whole page from
 799  * 0x7000 to 0x8000 free for use by the firmware
 800  */
 801 ZERO_FIXED_SECTION(fwnmi_page,          0x7000, 0x8000)
 802 OPEN_TEXT_SECTION(0x8000)
 803 #else
 804 OPEN_TEXT_SECTION(0x7000)
 805 #endif
 806
 807 USE_FIXED_SECTION(real_vectors)
 808
 809 /*
 810  * This is the start of the interrupt handlers for pSeries
 811  * This code runs with relocation off.
 812  * Code from here to __end_interrupts gets copied down to real
 813  * address 0x100 when we are running a relocatable kernel.
 814  * Therefore any relative branches in this section must only
 815  * branch to labels in this section.
 816  */
 817         .globl __start_interrupts
 818 __start_interrupts:
 819
 820 /**
 821  * Interrupt 0x3000 - System Call Vectored Interrupt (syscall).
 822  * This is a synchronous interrupt invoked with the "scv" instruction. The
 823  * system call does not alter the HV bit, so it is directed to the OS.
 824  *
 825  * Handling:
 826  * scv instructions enter the kernel without changing EE, RI, ME, or HV.
 827  * In particular, this means we can take a maskable interrupt at any point
 828  * in the scv handler, which is unlike any other interrupt. This is solved
 829  * by treating the instruction addresses below __end_interrupts as being
 830  * soft-masked.
 831  *
 832  * AIL-0 mode scv exceptions go to 0x17000-0x17fff, but we set AIL-3 and
 833  * ensure scv is never executed with relocation off, which means AIL-0
 834  * should never happen.
 835  *
 836  * Before leaving the below __end_interrupts text, at least of the following
 837  * must be true:
 838  * - MSR[PR]=1 (i.e., return to userspace)
 839  * - MSR_EE|MSR_RI is set (no reentrant exceptions)
 840  * - Standard kernel environment is set up (stack, paca, etc)
 841  *
 842  * Call convention:
 843  *
 844  * syscall register convention is in Documentation/powerpc/syscall64-abi.rst
 845  */
 846 EXC_VIRT_BEGIN(system_call_vectored, 0x3000, 0x1000)
 847         /* SCV 0 */
 848         mr      r9,r13
 849         GET_PACA(r13)
 850         mflr    r11
 851         mfctr   r12
 852         li      r10,IRQS_ALL_DISABLED
 853         stb     r10,PACAIRQSOFTMASK(r13)
 854 #ifdef CONFIG_RELOCATABLE
 855         b       system_call_vectored_tramp
 856 #else
 857         b       system_call_vectored_common
 858 #endif
 859         nop
 860
 861         /* SCV 1 - 127 */
 862         .rept   127
 863         mr      r9,r13
 864         GET_PACA(r13)
 865         mflr    r11
 866         mfctr   r12
 867         li      r10,IRQS_ALL_DISABLED
 868         stb     r10,PACAIRQSOFTMASK(r13)
 869         li      r0,-1 /* cause failure */
 870 #ifdef CONFIG_RELOCATABLE
 871         b       system_call_vectored_sigill_tramp
 872 #else
 873         b       system_call_vectored_sigill
 874 #endif
 875         .endr
 876 EXC_VIRT_END(system_call_vectored, 0x3000, 0x1000)
 877
 878 #ifdef CONFIG_RELOCATABLE
 879 TRAMP_VIRT_BEGIN(system_call_vectored_tramp)
 880         __LOAD_HANDLER(r10, system_call_vectored_common)
 881         mtctr   r10
 882         bctr
 883
 884 TRAMP_VIRT_BEGIN(system_call_vectored_sigill_tramp)
 885         __LOAD_HANDLER(r10, system_call_vectored_sigill)
 886         mtctr   r10
 887         bctr
 888 #endif
 889
 890
 891 /* No virt vectors corresponding with 0x0..0x100 */
 892 EXC_VIRT_NONE(0x4000, 0x100)
 893
 894
 895 /**
 896  * Interrupt 0x100 - System Reset Interrupt (SRESET aka NMI).
 897  * This is a non-maskable, asynchronous interrupt always taken in real-mode.
 898  * It is caused by:
 899  * - Wake from power-saving state, on powernv.
 900  * - An NMI from another CPU, triggered by firmware or hypercall.
 901  * - As crash/debug signal injected from BMC, firmware or hypervisor.
 902  *
 903  * Handling:
 904  * Power-save wakeup is the only performance critical path, so this is
 905  * determined quickly as possible first. In this case volatile registers
 906  * can be discarded and SPRs like CFAR don't need to be read.
 907  *
 908  * If not a powersave wakeup, then it's run as a regular interrupt, however
 909  * it uses its own stack and PACA save area to preserve the regular kernel
 910  * environment for debugging.
 911  *
 912  * This interrupt is not maskable, so triggering it when MSR[RI] is clear,
 913  * or SCRATCH0 is in use, etc. may cause a crash. It's also not entirely
 914  * correct to switch to virtual mode to run the regular interrupt handler
 915  * because it might be interrupted when the MMU is in a bad state (e.g., SLB
 916  * is clear).
 917  *
 918  * FWNMI:
 919  * PAPR specifies a "fwnmi" facility which sends the sreset to a different
 920  * entry point with a different register set up. Some hypervisors will
 921  * send the sreset to 0x100 in the guest if it is not fwnmi capable.
 922  *
 923  * KVM:
 924  * Unlike most SRR interrupts, this may be taken by the host while executing
 925  * in a guest, so a KVM test is required. KVM will pull the CPU out of guest
 926  * mode and then raise the sreset.
 927  */
 928 INT_DEFINE_BEGIN(system_reset)
 929         IVEC=0x100
 930         IAREA=PACA_EXNMI
 931         IVIRT=0 /* no virt entry point */
 932         /*
 933          * MSR_RI is not enabled, because PACA_EXNMI and nmi stack is
 934          * being used, so a nested NMI exception would corrupt it.
 935          */
 936         ISET_RI=0
 937         ISTACK=0
 938         IRECONCILE=0
 939         IKVM_REAL=1
 940 INT_DEFINE_END(system_reset)
 941
 942 EXC_REAL_BEGIN(system_reset, 0x100, 0x100)
 943 #ifdef CONFIG_PPC_P7_NAP
 944         /*
 945          * If running native on arch 2.06 or later, check if we are waking up
 946          * from nap/sleep/winkle, and branch to idle handler. This tests SRR1
 947          * bits 46:47. A non-0 value indicates that we are coming from a power
 948          * saving state. The idle wakeup handler initially runs in real mode,
 949          * but we branch to the 0xc000... address so we can turn on relocation
 950          * with mtmsrd later, after SPRs are restored.
 951          *
 952          * Careful to minimise cost for the fast path (idle wakeup) while
 953          * also avoiding clobbering CFAR for the debug path (non-idle).
 954          *
 955          * For the idle wake case volatile registers can be clobbered, which
 956          * is why we use those initially. If it turns out to not be an idle
 957          * wake, carefully put everything back the way it was, so we can use
 958          * common exception macros to handle it.
 959          */
 960 BEGIN_FTR_SECTION
 961         SET_SCRATCH0(r13)
 962         GET_PACA(r13)
 963         std     r3,PACA_EXNMI+0*8(r13)
 964         std     r4,PACA_EXNMI+1*8(r13)
 965         std     r5,PACA_EXNMI+2*8(r13)
 966         mfspr   r3,SPRN_SRR1
 967         mfocrf  r4,0x80
 968         rlwinm. r5,r3,47-31,30,31
 969         bne+    system_reset_idle_wake
 970         /* Not powersave wakeup. Restore regs for regular interrupt handler. */
 971         mtocrf  0x80,r4
 972         ld      r3,PACA_EXNMI+0*8(r13)
 973         ld      r4,PACA_EXNMI+1*8(r13)
 974         ld      r5,PACA_EXNMI+2*8(r13)
 975         GET_SCRATCH0(r13)
 976 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 977 #endif
 978
 979         GEN_INT_ENTRY system_reset, virt=0
 980         /*
 981          * In theory, we should not enable relocation here if it was disabled
 982          * in SRR1, because the MMU may not be configured to support it (e.g.,
 983          * SLB may have been cleared). In practice, there should only be a few
 984          * small windows where that's the case, and sreset is considered to
 985          * be dangerous anyway.
 986          */
 987 EXC_REAL_END(system_reset, 0x100, 0x100)
 988 EXC_VIRT_NONE(0x4100, 0x100)
 989
 990 #ifdef CONFIG_PPC_P7_NAP
 991 TRAMP_REAL_BEGIN(system_reset_idle_wake)
 992         /* We are waking up from idle, so may clobber any volatile register */
 993         cmpwi   cr1,r5,2
 994         bltlr   cr1     /* no state loss, return to idle caller with r3=SRR1 */
 995         BRANCH_TO_C000(r12, DOTSYM(idle_return_gpr_loss))
 996 #endif
 997
 998 #ifdef CONFIG_PPC_PSERIES
 999 /*
1000  * Vectors for the FWNMI option.  Share common code.
1001  */
1002 TRAMP_REAL_BEGIN(system_reset_fwnmi)
1003         GEN_INT_ENTRY system_reset, virt=0
1004
1005 #endif /* CONFIG_PPC_PSERIES */
1006
1007 EXC_COMMON_BEGIN(system_reset_common)
1008         __GEN_COMMON_ENTRY system_reset
1009         /*
1010          * Increment paca->in_nmi then enable MSR_RI. SLB or MCE will be able
1011          * to recover, but nested NMI will notice in_nmi and not recover
1012          * because of the use of the NMI stack. in_nmi reentrancy is tested in
1013          * system_reset_exception.
1014          */
1015         lhz     r10,PACA_IN_NMI(r13)
1016         addi    r10,r10,1
1017         sth     r10,PACA_IN_NMI(r13)
1018         li      r10,MSR_RI
1019         mtmsrd  r10,1
1020
1021         mr      r10,r1
1022         ld      r1,PACA_NMI_EMERG_SP(r13)
1023         subi    r1,r1,INT_FRAME_SIZE
1024         __GEN_COMMON_BODY system_reset
1025         /*
1026          * Set IRQS_ALL_DISABLED unconditionally so irqs_disabled() does
1027          * the right thing. We do not want to reconcile because that goes
1028          * through irq tracing which we don't want in NMI.
1029          *
1030          * Save PACAIRQHAPPENED to RESULT (otherwise unused), and set HARD_DIS
1031          * as we are running with MSR[EE]=0.
1032          */
1033         li      r10,IRQS_ALL_DISABLED
1034         stb     r10,PACAIRQSOFTMASK(r13)
1035         lbz     r10,PACAIRQHAPPENED(r13)
1036         std     r10,RESULT(r1)
1037         ori     r10,r10,PACA_IRQ_HARD_DIS
1038         stb     r10,PACAIRQHAPPENED(r13)
1039
1040         addi    r3,r1,STACK_FRAME_OVERHEAD
1041         bl      system_reset_exception
1042
1043         /* Clear MSR_RI before setting SRR0 and SRR1. */
1044         li      r9,0
1045         mtmsrd  r9,1
1046
1047         /*
1048          * MSR_RI is clear, now we can decrement paca->in_nmi.
1049          */
1050         lhz     r10,PACA_IN_NMI(r13)
1051         subi    r10,r10,1
1052         sth     r10,PACA_IN_NMI(r13)
1053
1054         /*
1055          * Restore soft mask settings.
1056          */
1057         ld      r10,RESULT(r1)
1058         stb     r10,PACAIRQHAPPENED(r13)
1059         ld      r10,SOFTE(r1)
1060         stb     r10,PACAIRQSOFTMASK(r13)
1061
1062         kuap_kernel_restore r9, r10
1063         EXCEPTION_RESTORE_REGS
1064         RFI_TO_USER_OR_KERNEL
1065
1066         GEN_KVM system_reset
1067
1068
1069 /**
1070  * Interrupt 0x200 - Machine Check Interrupt (MCE).
1071  * This is a non-maskable interrupt always taken in real-mode. It can be
1072  * synchronous or asynchronous, caused by hardware or software, and it may be
1073  * taken in a power-saving state.
1074  *
1075  * Handling:
1076  * Similarly to system reset, this uses its own stack and PACA save area,
1077  * the difference is re-entrancy is allowed on the machine check stack.
1078  *
1079  * machine_check_early is run in real mode, and carefully decodes the
1080  * machine check and tries to handle it (e.g., flush the SLB if there was an
1081  * error detected there), determines if it was recoverable and logs the
1082  * event.
1083  *
1084  * This early code does not "reconcile" irq soft-mask state like SRESET or
1085  * regular interrupts do, so irqs_disabled() among other things may not work
1086  * properly (irq disable/enable already doesn't work because irq tracing can
1087  * not work in real mode).
1088  *
1089  * Then, depending on the execution context when the interrupt is taken, there
1090  * are 3 main actions:
1091  * - Executing in kernel mode. The event is queued with irq_work, which means
1092  *   it is handled when it is next safe to do so (i.e., the kernel has enabled
1093  *   interrupts), which could be immediately when the interrupt returns. This
1094  *   avoids nasty issues like switching to virtual mode when the MMU is in a
1095  *   bad state, or when executing OPAL code. (SRESET is exposed to such issues,
1096  *   but it has different priorities). Check to see if the CPU was in power
1097  *   save, and return via the wake up code if it was.
1098  *
1099  * - Executing in user mode. machine_check_exception is run like a normal
1100  *   interrupt handler, which processes the data generated by the early handler.
1101  *
1102  * - Executing in guest mode. The interrupt is run with its KVM test, and
1103  *   branches to KVM to deal with. KVM may queue the event for the host
1104  *   to report later.
1105  *
1106  * This interrupt is not maskable, so if it triggers when MSR[RI] is clear,
1107  * or SCRATCH0 is in use, it may cause a crash.
1108  *
1109  * KVM:
1110  * See SRESET.
1111  */
1112 INT_DEFINE_BEGIN(machine_check_early)
1113         IVEC=0x200
1114         IAREA=PACA_EXMC
1115         IVIRT=0 /* no virt entry point */
1116         IREALMODE_COMMON=1
1117         /*
1118          * MSR_RI is not enabled, because PACA_EXMC is being used, so a
1119          * nested machine check corrupts it. machine_check_common enables
1120          * MSR_RI.
1121          */
1122         ISET_RI=0
1123         ISTACK=0
1124         IDAR=1
1125         IDSISR=1
1126         IRECONCILE=0
1127         IKUAP=0 /* We don't touch AMR here, we never go to virtual mode */
1128 INT_DEFINE_END(machine_check_early)
1129
1130 INT_DEFINE_BEGIN(machine_check)
1131         IVEC=0x200
1132         IAREA=PACA_EXMC
1133         IVIRT=0 /* no virt entry point */
1134         ISET_RI=0
1135         IDAR=1
1136         IDSISR=1
1137         IKVM_SKIP=1
1138         IKVM_REAL=1
1139 INT_DEFINE_END(machine_check)
1140
1141 EXC_REAL_BEGIN(machine_check, 0x200, 0x100)
1142         GEN_INT_ENTRY machine_check_early, virt=0
1143 EXC_REAL_END(machine_check, 0x200, 0x100)
1144 EXC_VIRT_NONE(0x4200, 0x100)
1145
1146 #ifdef CONFIG_PPC_PSERIES
1147 TRAMP_REAL_BEGIN(machine_check_fwnmi)
1148         /* See comment at machine_check exception, don't turn on RI */
1149         GEN_INT_ENTRY machine_check_early, virt=0
1150 #endif
1151
1152 #define MACHINE_CHECK_HANDLER_WINDUP                    \
1153         /* Clear MSR_RI before setting SRR0 and SRR1. */\
1154         li      r9,0;                                   \
1155         mtmsrd  r9,1;           /* Clear MSR_RI */      \
1156         /* Decrement paca->in_mce now RI is clear. */   \
1157         lhz     r12,PACA_IN_MCE(r13);                   \
1158         subi    r12,r12,1;                              \
1159         sth     r12,PACA_IN_MCE(r13);                   \
1160         EXCEPTION_RESTORE_REGS
1161
1162 EXC_COMMON_BEGIN(machine_check_early_common)
1163         __GEN_REALMODE_COMMON_ENTRY machine_check_early
1164
1165         /*
1166          * Switch to mc_emergency stack and handle re-entrancy (we limit
1167          * the nested MCE upto level 4 to avoid stack overflow).
1168          * Save MCE registers srr1, srr0, dar and dsisr and then set ME=1
1169          *
1170          * We use paca->in_mce to check whether this is the first entry or
1171          * nested machine check. We increment paca->in_mce to track nested
1172          * machine checks.
1173          *
1174          * If this is the first entry then set stack pointer to
1175          * paca->mc_emergency_sp, otherwise r1 is already pointing to
1176          * stack frame on mc_emergency stack.
1177          *
1178          * NOTE: We are here with MSR_ME=0 (off), which means we risk a
1179          * checkstop if we get another machine check exception before we do
1180          * rfid with MSR_ME=1.
1181          *
1182          * This interrupt can wake directly from idle. If that is the case,
1183          * the machine check is handled then the idle wakeup code is called
1184          * to restore state.
1185          */
1186         lhz     r10,PACA_IN_MCE(r13)
1187         cmpwi   r10,0                   /* Are we in nested machine check */
1188         cmpwi   cr1,r10,MAX_MCE_DEPTH   /* Are we at maximum nesting */
1189         addi    r10,r10,1               /* increment paca->in_mce */
1190         sth     r10,PACA_IN_MCE(r13)
1191
1192         mr      r10,r1                  /* Save r1 */
1193         bne     1f
1194         /* First machine check entry */
1195         ld      r1,PACAMCEMERGSP(r13)   /* Use MC emergency stack */
1196 1:      /* Limit nested MCE to level 4 to avoid stack overflow */
1197         bgt     cr1,unrecoverable_mce   /* Check if we hit limit of 4 */
1198         subi    r1,r1,INT_FRAME_SIZE    /* alloc stack frame */
1199
1200         __GEN_COMMON_BODY machine_check_early
1201
1202 BEGIN_FTR_SECTION
1203         bl      enable_machine_check
1204 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE)
1205         li      r10,MSR_RI
1206         mtmsrd  r10,1
1207
1208         /*
1209          * Set IRQS_ALL_DISABLED and save PACAIRQHAPPENED (see
1210          * system_reset_common)
1211          */
1212         li      r10,IRQS_ALL_DISABLED
1213         stb     r10,PACAIRQSOFTMASK(r13)
1214         lbz     r10,PACAIRQHAPPENED(r13)
1215         std     r10,RESULT(r1)
1216         ori     r10,r10,PACA_IRQ_HARD_DIS
1217         stb     r10,PACAIRQHAPPENED(r13)
1218
1219         addi    r3,r1,STACK_FRAME_OVERHEAD
1220         bl      machine_check_early
1221         std     r3,RESULT(r1)   /* Save result */
1222         ld      r12,_MSR(r1)
1223
1224         /*
1225          * Restore soft mask settings.
1226          */
1227         ld      r10,RESULT(r1)
1228         stb     r10,PACAIRQHAPPENED(r13)
1229         ld      r10,SOFTE(r1)
1230         stb     r10,PACAIRQSOFTMASK(r13)
1231
1232 #ifdef CONFIG_PPC_P7_NAP
1233         /*
1234          * Check if thread was in power saving mode. We come here when any
1235          * of the following is true:
1236          * a. thread wasn't in power saving mode
1237          * b. thread was in power saving mode with no state loss,
1238          *    supervisor state loss or hypervisor state loss.
1239          *
1240          * Go back to nap/sleep/winkle mode again if (b) is true.
1241          */
1242 BEGIN_FTR_SECTION
1243         rlwinm. r11,r12,47-31,30,31
1244         bne     machine_check_idle_common
1245 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
1246 #endif
1247
1248 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
1249         /*
1250          * Check if we are coming from guest. If yes, then run the normal
1251          * exception handler which will take the
1252          * machine_check_kvm->kvmppc_interrupt branch to deliver the MC event
1253          * to guest.
1254          */
1255         lbz     r11,HSTATE_IN_GUEST(r13)
1256         cmpwi   r11,0                   /* Check if coming from guest */
1257         bne     mce_deliver             /* continue if we are. */
1258 #endif
1259
1260         /*
1261          * Check if we are coming from userspace. If yes, then run the normal
1262          * exception handler which will deliver the MC event to this kernel.
1263          */
1264         andi.   r11,r12,MSR_PR          /* See if coming from user. */
1265         bne     mce_deliver             /* continue in V mode if we are. */
1266
1267         /*
1268          * At this point we are coming from kernel context.
1269          * Queue up the MCE event and return from the interrupt.
1270          * But before that, check if this is an un-recoverable exception.
1271          * If yes, then stay on emergency stack and panic.
1272          */
1273         andi.   r11,r12,MSR_RI
1274         beq     unrecoverable_mce
1275
1276         /*
1277          * Check if we have successfully handled/recovered from error, if not
1278          * then stay on emergency stack and panic.
1279          */
1280         ld      r3,RESULT(r1)   /* Load result */
1281         cmpdi   r3,0            /* see if we handled MCE successfully */
1282         beq     unrecoverable_mce /* if !handled then panic */
1283
1284         /*
1285          * Return from MC interrupt.
1286          * Queue up the MCE event so that we can log it later, while
1287          * returning from kernel or opal call.
1288          */
1289         bl      machine_check_queue_event
1290         MACHINE_CHECK_HANDLER_WINDUP
1291         RFI_TO_KERNEL
1292
1293 mce_deliver:
1294         /*
1295          * This is a host user or guest MCE. Restore all registers, then
1296          * run the "late" handler. For host user, this will run the
1297          * machine_check_exception handler in virtual mode like a normal
1298          * interrupt handler. For guest, this will trigger the KVM test
1299          * and branch to the KVM interrupt similarly to other interrupts.
1300          */
1301 BEGIN_FTR_SECTION
1302         ld      r10,ORIG_GPR3(r1)
1303         mtspr   SPRN_CFAR,r10
1304 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
1305         MACHINE_CHECK_HANDLER_WINDUP
1306         GEN_INT_ENTRY machine_check, virt=0
1307
1308 EXC_COMMON_BEGIN(machine_check_common)
1309         /*
1310          * Machine check is different because we use a different
1311          * save area: PACA_EXMC instead of PACA_EXGEN.
1312          */
1313         GEN_COMMON machine_check
1314
1315         FINISH_NAP
1316         /* Enable MSR_RI when finished with PACA_EXMC */
1317         li      r10,MSR_RI
1318         mtmsrd  r10,1
1319         addi    r3,r1,STACK_FRAME_OVERHEAD
1320         bl      machine_check_exception
1321         b       interrupt_return
1322
1323         GEN_KVM machine_check
1324
1325
1326 #ifdef CONFIG_PPC_P7_NAP
1327 /*
1328  * This is an idle wakeup. Low level machine check has already been
1329  * done. Queue the event then call the idle code to do the wake up.
1330  */
1331 EXC_COMMON_BEGIN(machine_check_idle_common)
1332         bl      machine_check_queue_event
1333
1334         /*
1335          * GPR-loss wakeups are relatively straightforward, because the
1336          * idle sleep code has saved all non-volatile registers on its
1337          * own stack, and r1 in PACAR1.
1338          *
1339          * For no-loss wakeups the r1 and lr registers used by the
1340          * early machine check handler have to be restored first. r2 is
1341          * the kernel TOC, so no need to restore it.
1342          *
1343          * Then decrement MCE nesting after finishing with the stack.
1344          */
1345         ld      r3,_MSR(r1)
1346         ld      r4,_LINK(r1)
1347         ld      r1,GPR1(r1)
1348
1349         lhz     r11,PACA_IN_MCE(r13)
1350         subi    r11,r11,1
1351         sth     r11,PACA_IN_MCE(r13)
1352
1353         mtlr    r4
1354         rlwinm  r10,r3,47-31,30,31
1355         cmpwi   cr1,r10,2
1356         bltlr   cr1     /* no state loss, return to idle caller with r3=SRR1 */
1357         b       idle_return_gpr_loss
1358 #endif
1359
1360 EXC_COMMON_BEGIN(unrecoverable_mce)
1361         /*
1362          * We are going down. But there are chances that we might get hit by
1363          * another MCE during panic path and we may run into unstable state
1364          * with no way out. Hence, turn ME bit off while going down, so that
1365          * when another MCE is hit during panic path, system will checkstop
1366          * and hypervisor will get restarted cleanly by SP.
1367          */
1368 BEGIN_FTR_SECTION
1369         li      r10,0 /* clear MSR_RI */
1370         mtmsrd  r10,1
1371         bl      disable_machine_check
1372 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE)
1373         ld      r10,PACAKMSR(r13)
1374         li      r3,MSR_ME
1375         andc    r10,r10,r3
1376         mtmsrd  r10
1377
1378         lhz     r12,PACA_IN_MCE(r13)
1379         subi    r12,r12,1
1380         sth     r12,PACA_IN_MCE(r13)
1381
1382         /* Invoke machine_check_exception to print MCE event and panic. */
1383         addi    r3,r1,STACK_FRAME_OVERHEAD
1384         bl      machine_check_exception
1385
1386         /*
1387          * We will not reach here. Even if we did, there is no way out.
1388          * Call unrecoverable_exception and die.
1389          */
1390         addi    r3,r1,STACK_FRAME_OVERHEAD
1391         bl      unrecoverable_exception
1392         b       .
1393
1394
1395 /**
1396  * Interrupt 0x300 - Data Storage Interrupt (DSI).
1397  * This is a synchronous interrupt generated due to a data access exception,
1398  * e.g., a load orstore which does not have a valid page table entry with
1399  * permissions. DAWR matches also fault here, as do RC updates, and minor misc
1400  * errors e.g., copy/paste, AMO, certain invalid CI accesses, etc.
1401  *
1402  * Handling:
1403  * - Hash MMU
1404  *   Go to do_hash_fault, which attempts to fill the HPT from an entry in the
1405  *   Linux page table. Hash faults can hit in kernel mode in a fairly
1406  *   arbitrary state (e.g., interrupts disabled, locks held) when accessing
1407  *   "non-bolted" regions, e.g., vmalloc space. However these should always be
1408  *   backed by Linux page table entries.
1409  *
1410  *   If no entry is found the Linux page fault handler is invoked (by
1411  *   do_hash_fault). Linux page faults can happen in kernel mode due to user
1412  *   copy operations of course.
1413  *
1414  *   KVM: The KVM HDSI handler may perform a load with MSR[DR]=1 in guest
1415  *   MMU context, which may cause a DSI in the host, which must go to the
1416  *   KVM handler. MSR[IR] is not enabled, so the real-mode handler will
1417  *   always be used regardless of AIL setting.
1418  *
1419  * - Radix MMU
1420  *   The hardware loads from the Linux page table directly, so a fault goes
1421  *   immediately to Linux page fault.
1422  *
1423  * Conditions like DAWR match are handled on the way in to Linux page fault.
1424  */
1425 INT_DEFINE_BEGIN(data_access)
1426         IVEC=0x300
1427         IDAR=1
1428         IDSISR=1
1429         IKVM_SKIP=1
1430         IKVM_REAL=1
1431 INT_DEFINE_END(data_access)
1432
1433 EXC_REAL_BEGIN(data_access, 0x300, 0x80)
1434         GEN_INT_ENTRY data_access, virt=0
1435 EXC_REAL_END(data_access, 0x300, 0x80)
1436 EXC_VIRT_BEGIN(data_access, 0x4300, 0x80)
1437         GEN_INT_ENTRY data_access, virt=1
1438 EXC_VIRT_END(data_access, 0x4300, 0x80)
1439 EXC_COMMON_BEGIN(data_access_common)
1440         GEN_COMMON data_access
1441         ld      r4,_DAR(r1)
1442         ld      r5,_DSISR(r1)
1443         addi    r3,r1,STACK_FRAME_OVERHEAD
1444         andis.  r0,r5,DSISR_DABRMATCH@h
1445         bne-    1f
1446 BEGIN_MMU_FTR_SECTION
1447         bl      do_hash_fault
1448 MMU_FTR_SECTION_ELSE
1449         bl      do_page_fault
1450 ALT_MMU_FTR_SECTION_END_IFCLR(MMU_FTR_TYPE_RADIX)
1451         cmpdi   r3,0
1452         beq+    interrupt_return
1453         mr      r5,r3
1454         addi    r3,r1,STACK_FRAME_OVERHEAD
1455         ld      r4,_DAR(r1)
1456         bl      __bad_page_fault
1457         b       interrupt_return
1458
1459 1:      bl      do_break
1460         /*
1461          * do_break() may have changed the NV GPRS while handling a breakpoint.
1462          * If so, we need to restore them with their updated values.
1463          */
1464         REST_NVGPRS(r1)
1465         b       interrupt_return
1466
1467         GEN_KVM data_access
1468
1469
1470 /**
1471  * Interrupt 0x380 - Data Segment Interrupt (DSLB).
1472  * This is a synchronous interrupt in response to an MMU fault missing SLB
1473  * entry for HPT, or an address outside RPT translation range.
1474  *
1475  * Handling:
1476  * - HPT:
1477  *   This refills the SLB, or reports an access fault similarly to a bad page
1478  *   fault. When coming from user-mode, the SLB handler may access any kernel
1479  *   data, though it may itself take a DSLB. When coming from kernel mode,
1480  *   recursive faults must be avoided so access is restricted to the kernel
1481  *   image text/data, kernel stack, and any data allocated below
1482  *   ppc64_bolted_size (first segment). The kernel handler must avoid stomping
1483  *   on user-handler data structures.
1484  *
1485  *   KVM: Same as 0x300, DSLB must test for KVM guest.
1486  *
1487  * A dedicated save area EXSLB is used (XXX: but it actually need not be
1488  * these days, we could use EXGEN).
1489  */
1490 INT_DEFINE_BEGIN(data_access_slb)
1491         IVEC=0x380
1492         IAREA=PACA_EXSLB
1493         IRECONCILE=0
1494         IDAR=1
1495         IKVM_SKIP=1
1496         IKVM_REAL=1
1497 INT_DEFINE_END(data_access_slb)
1498
1499 EXC_REAL_BEGIN(data_access_slb, 0x380, 0x80)
1500         GEN_INT_ENTRY data_access_slb, virt=0
1501 EXC_REAL_END(data_access_slb, 0x380, 0x80)
1502 EXC_VIRT_BEGIN(data_access_slb, 0x4380, 0x80)
1503         GEN_INT_ENTRY data_access_slb, virt=1
1504 EXC_VIRT_END(data_access_slb, 0x4380, 0x80)
1505 EXC_COMMON_BEGIN(data_access_slb_common)
1506         GEN_COMMON data_access_slb
1507         ld      r4,_DAR(r1)
1508         addi    r3,r1,STACK_FRAME_OVERHEAD
1509 BEGIN_MMU_FTR_SECTION
1510         /* HPT case, do SLB fault */
1511         bl      do_slb_fault
1512         cmpdi   r3,0
1513         bne-    1f
1514         b       fast_interrupt_return
1515 1:      /* Error case */
1516 MMU_FTR_SECTION_ELSE
1517         /* Radix case, access is outside page table range */
1518         li      r3,-EFAULT
1519 ALT_MMU_FTR_SECTION_END_IFCLR(MMU_FTR_TYPE_RADIX)
1520         std     r3,RESULT(r1)
1521         RECONCILE_IRQ_STATE(r10, r11)
1522         ld      r4,_DAR(r1)
1523         ld      r5,RESULT(r1)
1524         addi    r3,r1,STACK_FRAME_OVERHEAD
1525         bl      do_bad_slb_fault
1526         b       interrupt_return
1527
1528         GEN_KVM data_access_slb
1529
1530
1531 /**
1532  * Interrupt 0x400 - Instruction Storage Interrupt (ISI).
1533  * This is a synchronous interrupt in response to an MMU fault due to an
1534  * instruction fetch.
1535  *
1536  * Handling:
1537  * Similar to DSI, though in response to fetch. The faulting address is found
1538  * in SRR0 (rather than DAR), and status in SRR1 (rather than DSISR).
1539  */
1540 INT_DEFINE_BEGIN(instruction_access)
1541         IVEC=0x400
1542         IISIDE=1
1543         IDAR=1
1544         IDSISR=1
1545 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1546         IKVM_REAL=1
1547 #endif
1548 INT_DEFINE_END(instruction_access)
1549
1550 EXC_REAL_BEGIN(instruction_access, 0x400, 0x80)
1551         GEN_INT_ENTRY instruction_access, virt=0
1552 EXC_REAL_END(instruction_access, 0x400, 0x80)
1553 EXC_VIRT_BEGIN(instruction_access, 0x4400, 0x80)
1554         GEN_INT_ENTRY instruction_access, virt=1
1555 EXC_VIRT_END(instruction_access, 0x4400, 0x80)
1556 EXC_COMMON_BEGIN(instruction_access_common)
1557         GEN_COMMON instruction_access
1558         ld      r4,_DAR(r1)
1559         ld      r5,_DSISR(r1)
1560         addi    r3,r1,STACK_FRAME_OVERHEAD
1561 BEGIN_MMU_FTR_SECTION
1562         bl      do_hash_fault
1563 MMU_FTR_SECTION_ELSE
1564         bl      do_page_fault
1565 ALT_MMU_FTR_SECTION_END_IFCLR(MMU_FTR_TYPE_RADIX)
1566         cmpdi   r3,0
1567         beq+    interrupt_return
1568         mr      r5,r3
1569         addi    r3,r1,STACK_FRAME_OVERHEAD
1570         ld      r4,_DAR(r1)
1571         bl      __bad_page_fault
1572         b       interrupt_return
1573
1574         GEN_KVM instruction_access
1575
1576
1577 /**
1578  * Interrupt 0x480 - Instruction Segment Interrupt (ISLB).
1579  * This is a synchronous interrupt in response to an MMU fault due to an
1580  * instruction fetch.
1581  *
1582  * Handling:
1583  * Similar to DSLB, though in response to fetch. The faulting address is found
1584  * in SRR0 (rather than DAR).
1585  */
1586 INT_DEFINE_BEGIN(instruction_access_slb)
1587         IVEC=0x480
1588         IAREA=PACA_EXSLB
1589         IRECONCILE=0
1590         IISIDE=1
1591         IDAR=1
1592 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1593         IKVM_REAL=1
1594 #endif
1595 INT_DEFINE_END(instruction_access_slb)
1596
1597 EXC_REAL_BEGIN(instruction_access_slb, 0x480, 0x80)
1598         GEN_INT_ENTRY instruction_access_slb, virt=0
1599 EXC_REAL_END(instruction_access_slb, 0x480, 0x80)
1600 EXC_VIRT_BEGIN(instruction_access_slb, 0x4480, 0x80)
1601         GEN_INT_ENTRY instruction_access_slb, virt=1
1602 EXC_VIRT_END(instruction_access_slb, 0x4480, 0x80)
1603 EXC_COMMON_BEGIN(instruction_access_slb_common)
1604         GEN_COMMON instruction_access_slb
1605         ld      r4,_DAR(r1)
1606         addi    r3,r1,STACK_FRAME_OVERHEAD
1607 BEGIN_MMU_FTR_SECTION
1608         /* HPT case, do SLB fault */
1609         bl      do_slb_fault
1610         cmpdi   r3,0
1611         bne-    1f
1612         b       fast_interrupt_return
1613 1:      /* Error case */
1614 MMU_FTR_SECTION_ELSE
1615         /* Radix case, access is outside page table range */
1616         li      r3,-EFAULT
1617 ALT_MMU_FTR_SECTION_END_IFCLR(MMU_FTR_TYPE_RADIX)
1618         std     r3,RESULT(r1)
1619         RECONCILE_IRQ_STATE(r10, r11)
1620         ld      r4,_DAR(r1)
1621         ld      r5,RESULT(r1)
1622         addi    r3,r1,STACK_FRAME_OVERHEAD
1623         bl      do_bad_slb_fault
1624         b       interrupt_return
1625
1626         GEN_KVM instruction_access_slb
1627
1628
1629 /**
1630  * Interrupt 0x500 - External Interrupt.
1631  * This is an asynchronous maskable interrupt in response to an "external
1632  * exception" from the interrupt controller or hypervisor (e.g., device
1633  * interrupt). It is maskable in hardware by clearing MSR[EE], and
1634  * soft-maskable with IRQS_DISABLED mask (i.e., local_irq_disable()).
1635  *
1636  * When running in HV mode, Linux sets up the LPCR[LPES] bit such that
1637  * interrupts are delivered with HSRR registers, guests use SRRs, which
1638  * reqiures IHSRR_IF_HVMODE.
1639  *
1640  * On bare metal POWER9 and later, Linux sets the LPCR[HVICE] bit such that
1641  * external interrupts are delivered as Hypervisor Virtualization Interrupts
1642  * rather than External Interrupts.
1643  *
1644  * Handling:
1645  * This calls into Linux IRQ handler. NVGPRs are not saved to reduce overhead,
1646  * because registers at the time of the interrupt are not so important as it is
1647  * asynchronous.
1648  *
1649  * If soft masked, the masked handler will note the pending interrupt for
1650  * replay, and clear MSR[EE] in the interrupted context.
1651  */
1652 INT_DEFINE_BEGIN(hardware_interrupt)
1653         IVEC=0x500
1654         IHSRR_IF_HVMODE=1
1655         IMASK=IRQS_DISABLED
1656         IKVM_REAL=1
1657         IKVM_VIRT=1
1658 INT_DEFINE_END(hardware_interrupt)
1659
1660 EXC_REAL_BEGIN(hardware_interrupt, 0x500, 0x100)
1661         GEN_INT_ENTRY hardware_interrupt, virt=0
1662 EXC_REAL_END(hardware_interrupt, 0x500, 0x100)
1663 EXC_VIRT_BEGIN(hardware_interrupt, 0x4500, 0x100)
1664         GEN_INT_ENTRY hardware_interrupt, virt=1
1665 EXC_VIRT_END(hardware_interrupt, 0x4500, 0x100)
1666 EXC_COMMON_BEGIN(hardware_interrupt_common)
1667         GEN_COMMON hardware_interrupt
1668         FINISH_NAP
1669         RUNLATCH_ON
1670         addi    r3,r1,STACK_FRAME_OVERHEAD
1671         bl      do_IRQ
1672         b       interrupt_return
1673
1674         GEN_KVM hardware_interrupt
1675
1676
1677 /**
1678  * Interrupt 0x600 - Alignment Interrupt
1679  * This is a synchronous interrupt in response to data alignment fault.
1680  */
1681 INT_DEFINE_BEGIN(alignment)
1682         IVEC=0x600
1683         IDAR=1
1684         IDSISR=1
1685 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1686         IKVM_REAL=1
1687 #endif
1688 INT_DEFINE_END(alignment)
1689
1690 EXC_REAL_BEGIN(alignment, 0x600, 0x100)
1691         GEN_INT_ENTRY alignment, virt=0
1692 EXC_REAL_END(alignment, 0x600, 0x100)
1693 EXC_VIRT_BEGIN(alignment, 0x4600, 0x100)
1694         GEN_INT_ENTRY alignment, virt=1
1695 EXC_VIRT_END(alignment, 0x4600, 0x100)
1696 EXC_COMMON_BEGIN(alignment_common)
1697         GEN_COMMON alignment
1698         addi    r3,r1,STACK_FRAME_OVERHEAD
1699         bl      alignment_exception
1700         REST_NVGPRS(r1) /* instruction emulation may change GPRs */
1701         b       interrupt_return
1702
1703         GEN_KVM alignment
1704
1705
1706 /**
1707  * Interrupt 0x700 - Program Interrupt (program check).
1708  * This is a synchronous interrupt in response to various instruction faults:
1709  * traps, privilege errors, TM errors, floating point exceptions.
1710  *
1711  * Handling:
1712  * This interrupt may use the "emergency stack" in some cases when being taken
1713  * from kernel context, which complicates handling.
1714  */
1715 INT_DEFINE_BEGIN(program_check)
1716         IVEC=0x700
1717 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1718         IKVM_REAL=1
1719 #endif
1720 INT_DEFINE_END(program_check)
1721
1722 EXC_REAL_BEGIN(program_check, 0x700, 0x100)
1723         GEN_INT_ENTRY program_check, virt=0
1724 EXC_REAL_END(program_check, 0x700, 0x100)
1725 EXC_VIRT_BEGIN(program_check, 0x4700, 0x100)
1726         GEN_INT_ENTRY program_check, virt=1
1727 EXC_VIRT_END(program_check, 0x4700, 0x100)
1728 EXC_COMMON_BEGIN(program_check_common)
1729         __GEN_COMMON_ENTRY program_check
1730
1731         /*
1732          * It's possible to receive a TM Bad Thing type program check with
1733          * userspace register values (in particular r1), but with SRR1 reporting
1734          * that we came from the kernel. Normally that would confuse the bad
1735          * stack logic, and we would report a bad kernel stack pointer. Instead
1736          * we switch to the emergency stack if we're taking a TM Bad Thing from
1737          * the kernel.
1738          */
1739
1740         andi.   r10,r12,MSR_PR
1741         bne     2f                      /* If userspace, go normal path */
1742
1743         andis.  r10,r12,(SRR1_PROGTM)@h
1744         bne     1f                      /* If TM, emergency             */
1745
1746         cmpdi   r1,-INT_FRAME_SIZE      /* check if r1 is in userspace  */
1747         blt     2f                      /* normal path if not           */
1748
1749         /* Use the emergency stack                                      */
1750 1:      andi.   r10,r12,MSR_PR          /* Set CR0 correctly for label  */
1751                                         /* 3 in EXCEPTION_PROLOG_COMMON */
1752         mr      r10,r1                  /* Save r1                      */
1753         ld      r1,PACAEMERGSP(r13)     /* Use emergency stack          */
1754         subi    r1,r1,INT_FRAME_SIZE    /* alloc stack frame            */
1755         __ISTACK(program_check)=0
1756         __GEN_COMMON_BODY program_check
1757         b 3f
1758 2:
1759         __ISTACK(program_check)=1
1760         __GEN_COMMON_BODY program_check
1761 3:
1762         addi    r3,r1,STACK_FRAME_OVERHEAD
1763         bl      program_check_exception
1764         REST_NVGPRS(r1) /* instruction emulation may change GPRs */
1765         b       interrupt_return
1766
1767         GEN_KVM program_check
1768
1769
1770 /*
1771  * Interrupt 0x800 - Floating-Point Unavailable Interrupt.
1772  * This is a synchronous interrupt in response to executing an fp instruction
1773  * with MSR[FP]=0.
1774  *
1775  * Handling:
1776  * This will load FP registers and enable the FP bit if coming from userspace,
1777  * otherwise report a bad kernel use of FP.
1778  */
1779 INT_DEFINE_BEGIN(fp_unavailable)
1780         IVEC=0x800
1781         IRECONCILE=0
1782 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1783         IKVM_REAL=1
1784 #endif
1785 INT_DEFINE_END(fp_unavailable)
1786
1787 EXC_REAL_BEGIN(fp_unavailable, 0x800, 0x100)
1788         GEN_INT_ENTRY fp_unavailable, virt=0
1789 EXC_REAL_END(fp_unavailable, 0x800, 0x100)
1790 EXC_VIRT_BEGIN(fp_unavailable, 0x4800, 0x100)
1791         GEN_INT_ENTRY fp_unavailable, virt=1
1792 EXC_VIRT_END(fp_unavailable, 0x4800, 0x100)
1793 EXC_COMMON_BEGIN(fp_unavailable_common)
1794         GEN_COMMON fp_unavailable
1795         bne     1f                      /* if from user, just load it up */
1796         RECONCILE_IRQ_STATE(r10, r11)
1797         addi    r3,r1,STACK_FRAME_OVERHEAD
1798         bl      kernel_fp_unavailable_exception
1799 0:      trap
1800         EMIT_BUG_ENTRY 0b, __FILE__, __LINE__, 0
1801 1:
1802 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1803 BEGIN_FTR_SECTION
1804         /* Test if 2 TM state bits are zero.  If non-zero (ie. userspace was in
1805          * transaction), go do TM stuff
1806          */
1807         rldicl. r0, r12, (64-MSR_TS_LG), (64-2)
1808         bne-    2f
1809 END_FTR_SECTION_IFSET(CPU_FTR_TM)
1810 #endif
1811         bl      load_up_fpu
1812         b       fast_interrupt_return
1813 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1814 2:      /* User process was in a transaction */
1815         RECONCILE_IRQ_STATE(r10, r11)
1816         addi    r3,r1,STACK_FRAME_OVERHEAD
1817         bl      fp_unavailable_tm
1818         b       interrupt_return
1819 #endif
1820
1821         GEN_KVM fp_unavailable
1822
1823
1824 /**
1825  * Interrupt 0x900 - Decrementer Interrupt.
1826  * This is an asynchronous interrupt in response to a decrementer exception
1827  * (e.g., DEC has wrapped below zero). It is maskable in hardware by clearing
1828  * MSR[EE], and soft-maskable with IRQS_DISABLED mask (i.e.,
1829  * local_irq_disable()).
1830  *
1831  * Handling:
1832  * This calls into Linux timer handler. NVGPRs are not saved (see 0x500).
1833  *
1834  * If soft masked, the masked handler will note the pending interrupt for
1835  * replay, and bump the decrementer to a high value, leaving MSR[EE] enabled
1836  * in the interrupted context.
1837  * If PPC_WATCHDOG is configured, the soft masked handler will actually set
1838  * things back up to run soft_nmi_interrupt as a regular interrupt handler
1839  * on the emergency stack.
1840  */
1841 INT_DEFINE_BEGIN(decrementer)
1842         IVEC=0x900
1843         IMASK=IRQS_DISABLED
1844 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1845         IKVM_REAL=1
1846 #endif
1847 INT_DEFINE_END(decrementer)
1848
1849 EXC_REAL_BEGIN(decrementer, 0x900, 0x80)
1850         GEN_INT_ENTRY decrementer, virt=0
1851 EXC_REAL_END(decrementer, 0x900, 0x80)
1852 EXC_VIRT_BEGIN(decrementer, 0x4900, 0x80)
1853         GEN_INT_ENTRY decrementer, virt=1
1854 EXC_VIRT_END(decrementer, 0x4900, 0x80)
1855 EXC_COMMON_BEGIN(decrementer_common)
1856         GEN_COMMON decrementer
1857         FINISH_NAP
1858         RUNLATCH_ON
1859         addi    r3,r1,STACK_FRAME_OVERHEAD
1860         bl      timer_interrupt
1861         b       interrupt_return
1862
1863         GEN_KVM decrementer
1864
1865
1866 /**
1867  * Interrupt 0x980 - Hypervisor Decrementer Interrupt.
1868  * This is an asynchronous interrupt, similar to 0x900 but for the HDEC
1869  * register.
1870  *
1871  * Handling:
1872  * Linux does not use this outside KVM where it's used to keep a host timer
1873  * while the guest is given control of DEC. It should normally be caught by
1874  * the KVM test and routed there.
1875  */
1876 INT_DEFINE_BEGIN(hdecrementer)
1877         IVEC=0x980
1878         IHSRR=1
1879         ISTACK=0
1880         IRECONCILE=0
1881         IKVM_REAL=1
1882         IKVM_VIRT=1
1883 INT_DEFINE_END(hdecrementer)
1884
1885 EXC_REAL_BEGIN(hdecrementer, 0x980, 0x80)
1886         GEN_INT_ENTRY hdecrementer, virt=0
1887 EXC_REAL_END(hdecrementer, 0x980, 0x80)
1888 EXC_VIRT_BEGIN(hdecrementer, 0x4980, 0x80)
1889         GEN_INT_ENTRY hdecrementer, virt=1
1890 EXC_VIRT_END(hdecrementer, 0x4980, 0x80)
1891 EXC_COMMON_BEGIN(hdecrementer_common)
1892         __GEN_COMMON_ENTRY hdecrementer
1893         /*
1894          * Hypervisor decrementer interrupts not caught by the KVM test
1895          * shouldn't occur but are sometimes left pending on exit from a KVM
1896          * guest.  We don't need to do anything to clear them, as they are
1897          * edge-triggered.
1898          *
1899          * Be careful to avoid touching the kernel stack.
1900          */
1901         ld      r10,PACA_EXGEN+EX_CTR(r13)
1902         mtctr   r10
1903         mtcrf   0x80,r9
1904         ld      r9,PACA_EXGEN+EX_R9(r13)
1905         ld      r10,PACA_EXGEN+EX_R10(r13)
1906         ld      r11,PACA_EXGEN+EX_R11(r13)
1907         ld      r12,PACA_EXGEN+EX_R12(r13)
1908         ld      r13,PACA_EXGEN+EX_R13(r13)
1909         HRFI_TO_KERNEL
1910
1911         GEN_KVM hdecrementer
1912
1913
1914 /**
1915  * Interrupt 0xa00 - Directed Privileged Doorbell Interrupt.
1916  * This is an asynchronous interrupt in response to a msgsndp doorbell.
1917  * It is maskable in hardware by clearing MSR[EE], and soft-maskable with
1918  * IRQS_DISABLED mask (i.e., local_irq_disable()).
1919  *
1920  * Handling:
1921  * Guests may use this for IPIs between threads in a core if the
1922  * hypervisor supports it. NVGPRS are not saved (see 0x500).
1923  *
1924  * If soft masked, the masked handler will note the pending interrupt for
1925  * replay, leaving MSR[EE] enabled in the interrupted context because the
1926  * doorbells are edge triggered.
1927  */
1928 INT_DEFINE_BEGIN(doorbell_super)
1929         IVEC=0xa00
1930         IMASK=IRQS_DISABLED
1931 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1932         IKVM_REAL=1
1933 #endif
1934 INT_DEFINE_END(doorbell_super)
1935
1936 EXC_REAL_BEGIN(doorbell_super, 0xa00, 0x100)
1937         GEN_INT_ENTRY doorbell_super, virt=0
1938 EXC_REAL_END(doorbell_super, 0xa00, 0x100)
1939 EXC_VIRT_BEGIN(doorbell_super, 0x4a00, 0x100)
1940         GEN_INT_ENTRY doorbell_super, virt=1
1941 EXC_VIRT_END(doorbell_super, 0x4a00, 0x100)
1942 EXC_COMMON_BEGIN(doorbell_super_common)
1943         GEN_COMMON doorbell_super
1944         FINISH_NAP
1945         RUNLATCH_ON
1946         addi    r3,r1,STACK_FRAME_OVERHEAD
1947 #ifdef CONFIG_PPC_DOORBELL
1948         bl      doorbell_exception
1949 #else
1950         bl      unknown_exception
1951 #endif
1952         b       interrupt_return
1953
1954         GEN_KVM doorbell_super
1955
1956
1957 EXC_REAL_NONE(0xb00, 0x100)
1958 EXC_VIRT_NONE(0x4b00, 0x100)
1959
1960 /**
1961  * Interrupt 0xc00 - System Call Interrupt (syscall, hcall).
1962  * This is a synchronous interrupt invoked with the "sc" instruction. The
1963  * system call is invoked with "sc 0" and does not alter the HV bit, so it
1964  * is directed to the currently running OS. The hypercall is invoked with
1965  * "sc 1" and it sets HV=1, so it elevates to hypervisor.
1966  *
1967  * In HPT, sc 1 always goes to 0xc00 real mode. In RADIX, sc 1 can go to
1968  * 0x4c00 virtual mode.
1969  *
1970  * Handling:
1971  * If the KVM test fires then it was due to a hypercall and is accordingly
1972  * routed to KVM. Otherwise this executes a normal Linux system call.
1973  *
1974  * Call convention:
1975  *
1976  * syscall and hypercalls register conventions are documented in
1977  * Documentation/powerpc/syscall64-abi.rst and
1978  * Documentation/powerpc/papr_hcalls.rst respectively.
1979  *
1980  * The intersection of volatile registers that don't contain possible
1981  * inputs is: cr0, xer, ctr. We may use these as scratch regs upon entry
1982  * without saving, though xer is not a good idea to use, as hardware may
1983  * interpret some bits so it may be costly to change them.
1984  */
1985 INT_DEFINE_BEGIN(system_call)
1986         IVEC=0xc00
1987         IKVM_REAL=1
1988         IKVM_VIRT=1
1989 INT_DEFINE_END(system_call)
1990
1991 .macro SYSTEM_CALL virt
1992 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
1993         /*
1994          * There is a little bit of juggling to get syscall and hcall
1995          * working well. Save r13 in ctr to avoid using SPRG scratch
1996          * register.
1997          *
1998          * Userspace syscalls have already saved the PPR, hcalls must save
1999          * it before setting HMT_MEDIUM.
2000          */
2001         mtctr   r13
2002         GET_PACA(r13)
2003         std     r10,PACA_EXGEN+EX_R10(r13)
2004         INTERRUPT_TO_KERNEL
2005         KVMTEST system_call /* uses r10, branch to system_call_kvm */
2006         mfctr   r9
2007 #else
2008         mr      r9,r13
2009         GET_PACA(r13)
2010         INTERRUPT_TO_KERNEL
2011 #endif
2012
2013 #ifdef CONFIG_PPC_FAST_ENDIAN_SWITCH
2014 BEGIN_FTR_SECTION
2015         cmpdi   r0,0x1ebe
2016         beq-    1f
2017 END_FTR_SECTION_IFSET(CPU_FTR_REAL_LE)
2018 #endif
2019
2020         /* We reach here with PACA in r13, r13 in r9. */
2021         mfspr   r11,SPRN_SRR0
2022         mfspr   r12,SPRN_SRR1
2023
2024         HMT_MEDIUM
2025
2026         .if ! \virt
2027         __LOAD_HANDLER(r10, system_call_common)
2028         mtspr   SPRN_SRR0,r10
2029         ld      r10,PACAKMSR(r13)
2030         mtspr   SPRN_SRR1,r10
2031         RFI_TO_KERNEL
2032         b       .       /* prevent speculative execution */
2033         .else
2034         li      r10,MSR_RI
2035         mtmsrd  r10,1                   /* Set RI (EE=0) */
2036 #ifdef CONFIG_RELOCATABLE
2037         __LOAD_HANDLER(r10, system_call_common)
2038         mtctr   r10
2039         bctr
2040 #else
2041         b       system_call_common
2042 #endif
2043         .endif
2044
2045 #ifdef CONFIG_PPC_FAST_ENDIAN_SWITCH
2046         /* Fast LE/BE switch system call */
2047 1:      mfspr   r12,SPRN_SRR1
2048         xori    r12,r12,MSR_LE
2049         mtspr   SPRN_SRR1,r12
2050         mr      r13,r9
2051         RFI_TO_USER     /* return to userspace */
2052         b       .       /* prevent speculative execution */
2053 #endif
2054 .endm
2055
2056 EXC_REAL_BEGIN(system_call, 0xc00, 0x100)
2057         SYSTEM_CALL 0
2058 EXC_REAL_END(system_call, 0xc00, 0x100)
2059 EXC_VIRT_BEGIN(system_call, 0x4c00, 0x100)
2060         SYSTEM_CALL 1
2061 EXC_VIRT_END(system_call, 0x4c00, 0x100)
2062
2063 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
2064 TRAMP_REAL_BEGIN(system_call_kvm)
2065         /*
2066          * This is a hcall, so register convention is as above, with these
2067          * differences:
2068          * r13 = PACA
2069          * ctr = orig r13
2070          * orig r10 saved in PACA
2071          */
2072          /*
2073           * Save the PPR (on systems that support it) before changing to
2074           * HMT_MEDIUM. That allows the KVM code to save that value into the
2075           * guest state (it is the guest's PPR value).
2076           */
2077 BEGIN_FTR_SECTION
2078         mfspr   r10,SPRN_PPR
2079         std     r10,HSTATE_PPR(r13)
2080 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
2081         HMT_MEDIUM
2082         mfctr   r10
2083         SET_SCRATCH0(r10)
2084         mfcr    r10
2085         std     r12,HSTATE_SCRATCH0(r13)
2086         sldi    r12,r10,32
2087         ori     r12,r12,0xc00
2088 #ifdef CONFIG_RELOCATABLE
2089         /*
2090          * Requires __LOAD_FAR_HANDLER beause kvmppc_interrupt lives
2091          * outside the head section.
2092          */
2093         __LOAD_FAR_HANDLER(r10, kvmppc_interrupt)
2094         mtctr   r10
2095         ld      r10,PACA_EXGEN+EX_R10(r13)
2096         bctr
2097 #else
2098         ld      r10,PACA_EXGEN+EX_R10(r13)
2099         b       kvmppc_interrupt
2100 #endif
2101 #endif
2102
2103
2104 /**
2105  * Interrupt 0xd00 - Trace Interrupt.
2106  * This is a synchronous interrupt in response to instruction step or
2107  * breakpoint faults.
2108  */
2109 INT_DEFINE_BEGIN(single_step)
2110         IVEC=0xd00
2111 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
2112         IKVM_REAL=1
2113 #endif
2114 INT_DEFINE_END(single_step)
2115
2116 EXC_REAL_BEGIN(single_step, 0xd00, 0x100)
2117         GEN_INT_ENTRY single_step, virt=0
2118 EXC_REAL_END(single_step, 0xd00, 0x100)
2119 EXC_VIRT_BEGIN(single_step, 0x4d00, 0x100)
2120         GEN_INT_ENTRY single_step, virt=1
2121 EXC_VIRT_END(single_step, 0x4d00, 0x100)
2122 EXC_COMMON_BEGIN(single_step_common)
2123         GEN_COMMON single_step
2124         addi    r3,r1,STACK_FRAME_OVERHEAD
2125         bl      single_step_exception
2126         b       interrupt_return
2127
2128         GEN_KVM single_step
2129
2130
2131 /**
2132  * Interrupt 0xe00 - Hypervisor Data Storage Interrupt (HDSI).
2133  * This is a synchronous interrupt in response to an MMU fault caused by a
2134  * guest data access.
2135  *
2136  * Handling:
2137  * This should always get routed to KVM. In radix MMU mode, this is caused
2138  * by a guest nested radix access that can't be performed due to the
2139  * partition scope page table. In hash mode, this can be caused by guests
2140  * running with translation disabled (virtual real mode) or with VPM enabled.
2141  * KVM will update the page table structures or disallow the access.
2142  */
2143 INT_DEFINE_BEGIN(h_data_storage)
2144         IVEC=0xe00
2145         IHSRR=1
2146         IDAR=1
2147         IDSISR=1
2148         IKVM_SKIP=1
2149         IKVM_REAL=1
2150         IKVM_VIRT=1
2151 INT_DEFINE_END(h_data_storage)
2152
2153 EXC_REAL_BEGIN(h_data_storage, 0xe00, 0x20)
2154         GEN_INT_ENTRY h_data_storage, virt=0, ool=1
2155 EXC_REAL_END(h_data_storage, 0xe00, 0x20)
2156 EXC_VIRT_BEGIN(h_data_storage, 0x4e00, 0x20)
2157         GEN_INT_ENTRY h_data_storage, virt=1, ool=1
2158 EXC_VIRT_END(h_data_storage, 0x4e00, 0x20)
2159 EXC_COMMON_BEGIN(h_data_storage_common)
2160         GEN_COMMON h_data_storage
2161         addi    r3,r1,STACK_FRAME_OVERHEAD
2162 BEGIN_MMU_FTR_SECTION
2163         ld      r4,_DAR(r1)
2164         li      r5,SIGSEGV
2165         bl      bad_page_fault
2166 MMU_FTR_SECTION_ELSE
2167         bl      unknown_exception
2168 ALT_MMU_FTR_SECTION_END_IFSET(MMU_FTR_TYPE_RADIX)
2169         b       interrupt_return
2170
2171         GEN_KVM h_data_storage
2172
2173
2174 /**
2175  * Interrupt 0xe20 - Hypervisor Instruction Storage Interrupt (HISI).
2176  * This is a synchronous interrupt in response to an MMU fault caused by a
2177  * guest instruction fetch, similar to HDSI.
2178  */
2179 INT_DEFINE_BEGIN(h_instr_storage)
2180         IVEC=0xe20
2181         IHSRR=1
2182         IKVM_REAL=1
2183         IKVM_VIRT=1
2184 INT_DEFINE_END(h_instr_storage)
2185
2186 EXC_REAL_BEGIN(h_instr_storage, 0xe20, 0x20)
2187         GEN_INT_ENTRY h_instr_storage, virt=0, ool=1
2188 EXC_REAL_END(h_instr_storage, 0xe20, 0x20)
2189 EXC_VIRT_BEGIN(h_instr_storage, 0x4e20, 0x20)
2190         GEN_INT_ENTRY h_instr_storage, virt=1, ool=1
2191 EXC_VIRT_END(h_instr_storage, 0x4e20, 0x20)
2192 EXC_COMMON_BEGIN(h_instr_storage_common)
2193         GEN_COMMON h_instr_storage
2194         addi    r3,r1,STACK_FRAME_OVERHEAD
2195         bl      unknown_exception
2196         b       interrupt_return
2197
2198         GEN_KVM h_instr_storage
2199
2200
2201 /**
2202  * Interrupt 0xe40 - Hypervisor Emulation Assistance Interrupt.
2203  */
2204 INT_DEFINE_BEGIN(emulation_assist)
2205         IVEC=0xe40
2206         IHSRR=1
2207         IKVM_REAL=1
2208         IKVM_VIRT=1
2209 INT_DEFINE_END(emulation_assist)
2210
2211 EXC_REAL_BEGIN(emulation_assist, 0xe40, 0x20)
2212         GEN_INT_ENTRY emulation_assist, virt=0, ool=1
2213 EXC_REAL_END(emulation_assist, 0xe40, 0x20)
2214 EXC_VIRT_BEGIN(emulation_assist, 0x4e40, 0x20)
2215         GEN_INT_ENTRY emulation_assist, virt=1, ool=1
2216 EXC_VIRT_END(emulation_assist, 0x4e40, 0x20)
2217 EXC_COMMON_BEGIN(emulation_assist_common)
2218         GEN_COMMON emulation_assist
2219         addi    r3,r1,STACK_FRAME_OVERHEAD
2220         bl      emulation_assist_interrupt
2221         REST_NVGPRS(r1) /* instruction emulation may change GPRs */
2222         b       interrupt_return
2223
2224         GEN_KVM emulation_assist
2225
2226
2227 /**
2228  * Interrupt 0xe60 - Hypervisor Maintenance Interrupt (HMI).
2229  * This is an asynchronous interrupt caused by a Hypervisor Maintenance
2230  * Exception. It is always taken in real mode but uses HSRR registers
2231  * unlike SRESET and MCE.
2232  *
2233  * It is maskable in hardware by clearing MSR[EE], and partially soft-maskable
2234  * with IRQS_DISABLED mask (i.e., local_irq_disable()).
2235  *
2236  * Handling:
2237  * This is a special case, this is handled similarly to machine checks, with an
2238  * initial real mode handler that is not soft-masked, which attempts to fix the
2239  * problem. Then a regular handler which is soft-maskable and reports the
2240  * problem.
2241  *
2242  * The emergency stack is used for the early real mode handler.
2243  *
2244  * XXX: unclear why MCE and HMI schemes could not be made common, e.g.,
2245  * either use soft-masking for the MCE, or use irq_work for the HMI.
2246  *
2247  * KVM:
2248  * Unlike MCE, this calls into KVM without calling the real mode handler
2249  * first.
2250  */
2251 INT_DEFINE_BEGIN(hmi_exception_early)
2252         IVEC=0xe60
2253         IHSRR=1
2254         IREALMODE_COMMON=1
2255         ISTACK=0
2256         IRECONCILE=0
2257         IKUAP=0 /* We don't touch AMR here, we never go to virtual mode */
2258         IKVM_REAL=1
2259 INT_DEFINE_END(hmi_exception_early)
2260
2261 INT_DEFINE_BEGIN(hmi_exception)
2262         IVEC=0xe60
2263         IHSRR=1
2264         IMASK=IRQS_DISABLED
2265         IKVM_REAL=1
2266 INT_DEFINE_END(hmi_exception)
2267
2268 EXC_REAL_BEGIN(hmi_exception, 0xe60, 0x20)
2269         GEN_INT_ENTRY hmi_exception_early, virt=0, ool=1
2270 EXC_REAL_END(hmi_exception, 0xe60, 0x20)
2271 EXC_VIRT_NONE(0x4e60, 0x20)
2272
2273 EXC_COMMON_BEGIN(hmi_exception_early_common)
2274         __GEN_REALMODE_COMMON_ENTRY hmi_exception_early
2275
2276         mr      r10,r1                  /* Save r1 */
2277         ld      r1,PACAEMERGSP(r13)     /* Use emergency stack for realmode */
2278         subi    r1,r1,INT_FRAME_SIZE    /* alloc stack frame            */
2279
2280         __GEN_COMMON_BODY hmi_exception_early
2281
2282         addi    r3,r1,STACK_FRAME_OVERHEAD
2283         bl      hmi_exception_realmode
2284         cmpdi   cr0,r3,0
2285         bne     1f
2286
2287         EXCEPTION_RESTORE_REGS hsrr=1
2288         HRFI_TO_USER_OR_KERNEL
2289
2290 1:
2291         /*
2292          * Go to virtual mode and pull the HMI event information from
2293          * firmware.
2294          */
2295         EXCEPTION_RESTORE_REGS hsrr=1
2296         GEN_INT_ENTRY hmi_exception, virt=0
2297
2298         GEN_KVM hmi_exception_early
2299
2300 EXC_COMMON_BEGIN(hmi_exception_common)
2301         GEN_COMMON hmi_exception
2302         FINISH_NAP
2303         RUNLATCH_ON
2304         addi    r3,r1,STACK_FRAME_OVERHEAD
2305         bl      handle_hmi_exception
2306         b       interrupt_return
2307
2308         GEN_KVM hmi_exception
2309
2310
2311 /**
2312  * Interrupt 0xe80 - Directed Hypervisor Doorbell Interrupt.
2313  * This is an asynchronous interrupt in response to a msgsnd doorbell.
2314  * Similar to the 0xa00 doorbell but for host rather than guest.
2315  */
2316 INT_DEFINE_BEGIN(h_doorbell)
2317         IVEC=0xe80
2318         IHSRR=1
2319         IMASK=IRQS_DISABLED
2320         IKVM_REAL=1
2321         IKVM_VIRT=1
2322 INT_DEFINE_END(h_doorbell)
2323
2324 EXC_REAL_BEGIN(h_doorbell, 0xe80, 0x20)
2325         GEN_INT_ENTRY h_doorbell, virt=0, ool=1
2326 EXC_REAL_END(h_doorbell, 0xe80, 0x20)
2327 EXC_VIRT_BEGIN(h_doorbell, 0x4e80, 0x20)
2328         GEN_INT_ENTRY h_doorbell, virt=1, ool=1
2329 EXC_VIRT_END(h_doorbell, 0x4e80, 0x20)
2330 EXC_COMMON_BEGIN(h_doorbell_common)
2331         GEN_COMMON h_doorbell
2332         FINISH_NAP
2333         RUNLATCH_ON
2334         addi    r3,r1,STACK_FRAME_OVERHEAD
2335 #ifdef CONFIG_PPC_DOORBELL
2336         bl      doorbell_exception
2337 #else
2338         bl      unknown_exception
2339 #endif
2340         b       interrupt_return
2341
2342         GEN_KVM h_doorbell
2343
2344
2345 /**
2346  * Interrupt 0xea0 - Hypervisor Virtualization Interrupt.
2347  * This is an asynchronous interrupt in response to an "external exception".
2348  * Similar to 0x500 but for host only.
2349  */
2350 INT_DEFINE_BEGIN(h_virt_irq)
2351         IVEC=0xea0
2352         IHSRR=1
2353         IMASK=IRQS_DISABLED
2354         IKVM_REAL=1
2355         IKVM_VIRT=1
2356 INT_DEFINE_END(h_virt_irq)
2357
2358 EXC_REAL_BEGIN(h_virt_irq, 0xea0, 0x20)
2359         GEN_INT_ENTRY h_virt_irq, virt=0, ool=1
2360 EXC_REAL_END(h_virt_irq, 0xea0, 0x20)
2361 EXC_VIRT_BEGIN(h_virt_irq, 0x4ea0, 0x20)
2362         GEN_INT_ENTRY h_virt_irq, virt=1, ool=1
2363 EXC_VIRT_END(h_virt_irq, 0x4ea0, 0x20)
2364 EXC_COMMON_BEGIN(h_virt_irq_common)
2365         GEN_COMMON h_virt_irq
2366         FINISH_NAP
2367         RUNLATCH_ON
2368         addi    r3,r1,STACK_FRAME_OVERHEAD
2369         bl      do_IRQ
2370         b       interrupt_return
2371
2372         GEN_KVM h_virt_irq
2373
2374
2375 EXC_REAL_NONE(0xec0, 0x20)
2376 EXC_VIRT_NONE(0x4ec0, 0x20)
2377 EXC_REAL_NONE(0xee0, 0x20)
2378 EXC_VIRT_NONE(0x4ee0, 0x20)
2379
2380
2381 /*
2382  * Interrupt 0xf00 - Performance Monitor Interrupt (PMI, PMU).
2383  * This is an asynchronous interrupt in response to a PMU exception.
2384  * It is maskable in hardware by clearing MSR[EE], and soft-maskable with
2385  * IRQS_PMI_DISABLED mask (NOTE: NOT local_irq_disable()).
2386  *
2387  * Handling:
2388  * This calls into the perf subsystem.
2389  *
2390  * Like the watchdog soft-nmi, it appears an NMI interrupt to Linux, in that it
2391  * runs under local_irq_disable. However it may be soft-masked in
2392  * powerpc-specific code.
2393  *
2394  * If soft masked, the masked handler will note the pending interrupt for
2395  * replay, and clear MSR[EE] in the interrupted context.
2396  */
2397 INT_DEFINE_BEGIN(performance_monitor)
2398         IVEC=0xf00
2399         IMASK=IRQS_PMI_DISABLED
2400 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
2401         IKVM_REAL=1
2402 #endif
2403 INT_DEFINE_END(performance_monitor)
2404
2405 EXC_REAL_BEGIN(performance_monitor, 0xf00, 0x20)
2406         GEN_INT_ENTRY performance_monitor, virt=0, ool=1
2407 EXC_REAL_END(performance_monitor, 0xf00, 0x20)
2408 EXC_VIRT_BEGIN(performance_monitor, 0x4f00, 0x20)
2409         GEN_INT_ENTRY performance_monitor, virt=1, ool=1
2410 EXC_VIRT_END(performance_monitor, 0x4f00, 0x20)
2411 EXC_COMMON_BEGIN(performance_monitor_common)
2412         GEN_COMMON performance_monitor
2413         FINISH_NAP
2414         RUNLATCH_ON
2415         addi    r3,r1,STACK_FRAME_OVERHEAD
2416         bl      performance_monitor_exception
2417         b       interrupt_return
2418
2419         GEN_KVM performance_monitor
2420
2421
2422 /**
2423  * Interrupt 0xf20 - Vector Unavailable Interrupt.
2424  * This is a synchronous interrupt in response to
2425  * executing a vector (or altivec) instruction with MSR[VEC]=0.
2426  * Similar to FP unavailable.
2427  */
2428 INT_DEFINE_BEGIN(altivec_unavailable)
2429         IVEC=0xf20
2430         IRECONCILE=0
2431 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
2432         IKVM_REAL=1
2433 #endif
2434 INT_DEFINE_END(altivec_unavailable)
2435
2436 EXC_REAL_BEGIN(altivec_unavailable, 0xf20, 0x20)
2437         GEN_INT_ENTRY altivec_unavailable, virt=0, ool=1
2438 EXC_REAL_END(altivec_unavailable, 0xf20, 0x20)
2439 EXC_VIRT_BEGIN(altivec_unavailable, 0x4f20, 0x20)
2440         GEN_INT_ENTRY altivec_unavailable, virt=1, ool=1
2441 EXC_VIRT_END(altivec_unavailable, 0x4f20, 0x20)
2442 EXC_COMMON_BEGIN(altivec_unavailable_common)
2443         GEN_COMMON altivec_unavailable
2444 #ifdef CONFIG_ALTIVEC
2445 BEGIN_FTR_SECTION
2446         beq     1f
2447 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2448   BEGIN_FTR_SECTION_NESTED(69)
2449         /* Test if 2 TM state bits are zero.  If non-zero (ie. userspace was in
2450          * transaction), go do TM stuff
2451          */
2452         rldicl. r0, r12, (64-MSR_TS_LG), (64-2)
2453         bne-    2f
2454   END_FTR_SECTION_NESTED(CPU_FTR_TM, CPU_FTR_TM, 69)
2455 #endif
2456         bl      load_up_altivec
2457         b       fast_interrupt_return
2458 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2459 2:      /* User process was in a transaction */
2460         RECONCILE_IRQ_STATE(r10, r11)
2461         addi    r3,r1,STACK_FRAME_OVERHEAD
2462         bl      altivec_unavailable_tm
2463         b       interrupt_return
2464 #endif
2465 1:
2466 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
2467 #endif
2468         RECONCILE_IRQ_STATE(r10, r11)
2469         addi    r3,r1,STACK_FRAME_OVERHEAD
2470         bl      altivec_unavailable_exception
2471         b       interrupt_return
2472
2473         GEN_KVM altivec_unavailable
2474
2475
2476 /**
2477  * Interrupt 0xf40 - VSX Unavailable Interrupt.
2478  * This is a synchronous interrupt in response to
2479  * executing a VSX instruction with MSR[VSX]=0.
2480  * Similar to FP unavailable.
2481  */
2482 INT_DEFINE_BEGIN(vsx_unavailable)
2483         IVEC=0xf40
2484         IRECONCILE=0
2485 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
2486         IKVM_REAL=1
2487 #endif
2488 INT_DEFINE_END(vsx_unavailable)
2489
2490 EXC_REAL_BEGIN(vsx_unavailable, 0xf40, 0x20)
2491         GEN_INT_ENTRY vsx_unavailable, virt=0, ool=1
2492 EXC_REAL_END(vsx_unavailable, 0xf40, 0x20)
2493 EXC_VIRT_BEGIN(vsx_unavailable, 0x4f40, 0x20)
2494         GEN_INT_ENTRY vsx_unavailable, virt=1, ool=1
2495 EXC_VIRT_END(vsx_unavailable, 0x4f40, 0x20)
2496 EXC_COMMON_BEGIN(vsx_unavailable_common)
2497         GEN_COMMON vsx_unavailable
2498 #ifdef CONFIG_VSX
2499 BEGIN_FTR_SECTION
2500         beq     1f
2501 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2502   BEGIN_FTR_SECTION_NESTED(69)
2503         /* Test if 2 TM state bits are zero.  If non-zero (ie. userspace was in
2504          * transaction), go do TM stuff
2505          */
2506         rldicl. r0, r12, (64-MSR_TS_LG), (64-2)
2507         bne-    2f
2508   END_FTR_SECTION_NESTED(CPU_FTR_TM, CPU_FTR_TM, 69)
2509 #endif
2510         b       load_up_vsx
2511 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2512 2:      /* User process was in a transaction */
2513         RECONCILE_IRQ_STATE(r10, r11)
2514         addi    r3,r1,STACK_FRAME_OVERHEAD
2515         bl      vsx_unavailable_tm
2516         b       interrupt_return
2517 #endif
2518 1:
2519 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
2520 #endif
2521         RECONCILE_IRQ_STATE(r10, r11)
2522         addi    r3,r1,STACK_FRAME_OVERHEAD
2523         bl      vsx_unavailable_exception
2524         b       interrupt_return
2525
2526         GEN_KVM vsx_unavailable
2527
2528
2529 /**
2530  * Interrupt 0xf60 - Facility Unavailable Interrupt.
2531  * This is a synchronous interrupt in response to
2532  * executing an instruction without access to the facility that can be
2533  * resolved by the OS (e.g., FSCR, MSR).
2534  * Similar to FP unavailable.
2535  */
2536 INT_DEFINE_BEGIN(facility_unavailable)
2537         IVEC=0xf60
2538 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
2539         IKVM_REAL=1
2540 #endif
2541 INT_DEFINE_END(facility_unavailable)
2542
2543 EXC_REAL_BEGIN(facility_unavailable, 0xf60, 0x20)
2544         GEN_INT_ENTRY facility_unavailable, virt=0, ool=1
2545 EXC_REAL_END(facility_unavailable, 0xf60, 0x20)
2546 EXC_VIRT_BEGIN(facility_unavailable, 0x4f60, 0x20)
2547         GEN_INT_ENTRY facility_unavailable, virt=1, ool=1
2548 EXC_VIRT_END(facility_unavailable, 0x4f60, 0x20)
2549 EXC_COMMON_BEGIN(facility_unavailable_common)
2550         GEN_COMMON facility_unavailable
2551         addi    r3,r1,STACK_FRAME_OVERHEAD
2552         bl      facility_unavailable_exception
2553         REST_NVGPRS(r1) /* instruction emulation may change GPRs */
2554         b       interrupt_return
2555
2556         GEN_KVM facility_unavailable
2557
2558
2559 /**
2560  * Interrupt 0xf60 - Hypervisor Facility Unavailable Interrupt.
2561  * This is a synchronous interrupt in response to
2562  * executing an instruction without access to the facility that can only
2563  * be resolved in HV mode (e.g., HFSCR).
2564  * Similar to FP unavailable.
2565  */
2566 INT_DEFINE_BEGIN(h_facility_unavailable)
2567         IVEC=0xf80
2568         IHSRR=1
2569         IKVM_REAL=1
2570         IKVM_VIRT=1
2571 INT_DEFINE_END(h_facility_unavailable)
2572
2573 EXC_REAL_BEGIN(h_facility_unavailable, 0xf80, 0x20)
2574         GEN_INT_ENTRY h_facility_unavailable, virt=0, ool=1
2575 EXC_REAL_END(h_facility_unavailable, 0xf80, 0x20)
2576 EXC_VIRT_BEGIN(h_facility_unavailable, 0x4f80, 0x20)
2577         GEN_INT_ENTRY h_facility_unavailable, virt=1, ool=1
2578 EXC_VIRT_END(h_facility_unavailable, 0x4f80, 0x20)
2579 EXC_COMMON_BEGIN(h_facility_unavailable_common)
2580         GEN_COMMON h_facility_unavailable
2581         addi    r3,r1,STACK_FRAME_OVERHEAD
2582         bl      facility_unavailable_exception
2583         REST_NVGPRS(r1) /* XXX Shouldn't be necessary in practice */
2584         b       interrupt_return
2585
2586         GEN_KVM h_facility_unavailable
2587
2588
2589 EXC_REAL_NONE(0xfa0, 0x20)
2590 EXC_VIRT_NONE(0x4fa0, 0x20)
2591 EXC_REAL_NONE(0xfc0, 0x20)
2592 EXC_VIRT_NONE(0x4fc0, 0x20)
2593 EXC_REAL_NONE(0xfe0, 0x20)
2594 EXC_VIRT_NONE(0x4fe0, 0x20)
2595
2596 EXC_REAL_NONE(0x1000, 0x100)
2597 EXC_VIRT_NONE(0x5000, 0x100)
2598 EXC_REAL_NONE(0x1100, 0x100)
2599 EXC_VIRT_NONE(0x5100, 0x100)
2600
2601 #ifdef CONFIG_CBE_RAS
2602 INT_DEFINE_BEGIN(cbe_system_error)
2603         IVEC=0x1200
2604         IHSRR=1
2605         IKVM_SKIP=1
2606         IKVM_REAL=1
2607 INT_DEFINE_END(cbe_system_error)
2608
2609 EXC_REAL_BEGIN(cbe_system_error, 0x1200, 0x100)
2610         GEN_INT_ENTRY cbe_system_error, virt=0
2611 EXC_REAL_END(cbe_system_error, 0x1200, 0x100)
2612 EXC_VIRT_NONE(0x5200, 0x100)
2613 EXC_COMMON_BEGIN(cbe_system_error_common)
2614         GEN_COMMON cbe_system_error
2615         addi    r3,r1,STACK_FRAME_OVERHEAD
2616         bl      cbe_system_error_exception
2617         b       interrupt_return
2618
2619         GEN_KVM cbe_system_error
2620
2621 #else /* CONFIG_CBE_RAS */
2622 EXC_REAL_NONE(0x1200, 0x100)
2623 EXC_VIRT_NONE(0x5200, 0x100)
2624 #endif
2625
2626
2627 INT_DEFINE_BEGIN(instruction_breakpoint)
2628         IVEC=0x1300
2629 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
2630         IKVM_SKIP=1
2631         IKVM_REAL=1
2632 #endif
2633 INT_DEFINE_END(instruction_breakpoint)
2634
2635 EXC_REAL_BEGIN(instruction_breakpoint, 0x1300, 0x100)
2636         GEN_INT_ENTRY instruction_breakpoint, virt=0
2637 EXC_REAL_END(instruction_breakpoint, 0x1300, 0x100)
2638 EXC_VIRT_BEGIN(instruction_breakpoint, 0x5300, 0x100)
2639         GEN_INT_ENTRY instruction_breakpoint, virt=1
2640 EXC_VIRT_END(instruction_breakpoint, 0x5300, 0x100)
2641 EXC_COMMON_BEGIN(instruction_breakpoint_common)
2642         GEN_COMMON instruction_breakpoint
2643         addi    r3,r1,STACK_FRAME_OVERHEAD
2644         bl      instruction_breakpoint_exception
2645         b       interrupt_return
2646
2647         GEN_KVM instruction_breakpoint
2648
2649
2650 EXC_REAL_NONE(0x1400, 0x100)
2651 EXC_VIRT_NONE(0x5400, 0x100)
2652
2653 /**
2654  * Interrupt 0x1500 - Soft Patch Interrupt
2655  *
2656  * Handling:
2657  * This is an implementation specific interrupt which can be used for a
2658  * range of exceptions.
2659  *
2660  * This interrupt handler is unique in that it runs the denormal assist
2661  * code even for guests (and even in guest context) without going to KVM,
2662  * for speed. POWER9 does not raise denorm exceptions, so this special case
2663  * could be phased out in future to reduce special cases.
2664  */
2665 INT_DEFINE_BEGIN(denorm_exception)
2666         IVEC=0x1500
2667         IHSRR=1
2668         IBRANCH_TO_COMMON=0
2669         IKVM_REAL=1
2670 INT_DEFINE_END(denorm_exception)
2671
2672 EXC_REAL_BEGIN(denorm_exception, 0x1500, 0x100)
2673         GEN_INT_ENTRY denorm_exception, virt=0
2674 #ifdef CONFIG_PPC_DENORMALISATION
2675         andis.  r10,r12,(HSRR1_DENORM)@h /* denorm? */
2676         bne+    denorm_assist
2677 #endif
2678         GEN_BRANCH_TO_COMMON denorm_exception, virt=0
2679 EXC_REAL_END(denorm_exception, 0x1500, 0x100)
2680 #ifdef CONFIG_PPC_DENORMALISATION
2681 EXC_VIRT_BEGIN(denorm_exception, 0x5500, 0x100)
2682         GEN_INT_ENTRY denorm_exception, virt=1
2683         andis.  r10,r12,(HSRR1_DENORM)@h /* denorm? */
2684         bne+    denorm_assist
2685         GEN_BRANCH_TO_COMMON denorm_exception, virt=1
2686 EXC_VIRT_END(denorm_exception, 0x5500, 0x100)
2687 #else
2688 EXC_VIRT_NONE(0x5500, 0x100)
2689 #endif
2690
2691 #ifdef CONFIG_PPC_DENORMALISATION
2692 TRAMP_REAL_BEGIN(denorm_assist)
2693 BEGIN_FTR_SECTION
2694 /*
2695  * To denormalise we need to move a copy of the register to itself.
2696  * For POWER6 do that here for all FP regs.
2697  */
2698         mfmsr   r10
2699         ori     r10,r10,(MSR_FP|MSR_FE0|MSR_FE1)
2700         xori    r10,r10,(MSR_FE0|MSR_FE1)
2701         mtmsrd  r10
2702         sync
2703
2704         .Lreg=0
2705         .rept 32
2706         fmr     .Lreg,.Lreg
2707         .Lreg=.Lreg+1
2708         .endr
2709
2710 FTR_SECTION_ELSE
2711 /*
2712  * To denormalise we need to move a copy of the register to itself.
2713  * For POWER7 do that here for the first 32 VSX registers only.
2714  */
2715         mfmsr   r10
2716         oris    r10,r10,MSR_VSX@h
2717         mtmsrd  r10
2718         sync
2719
2720         .Lreg=0
2721         .rept 32
2722         XVCPSGNDP(.Lreg,.Lreg,.Lreg)
2723         .Lreg=.Lreg+1
2724         .endr
2725
2726 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_ARCH_206)
2727
2728 BEGIN_FTR_SECTION
2729         b       denorm_done
2730 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
2731 /*
2732  * To denormalise we need to move a copy of the register to itself.
2733  * For POWER8 we need to do that for all 64 VSX registers
2734  */
2735         .Lreg=32
2736         .rept 32
2737         XVCPSGNDP(.Lreg,.Lreg,.Lreg)
2738         .Lreg=.Lreg+1
2739         .endr
2740
2741 denorm_done:
2742         mfspr   r11,SPRN_HSRR0
2743         subi    r11,r11,4
2744         mtspr   SPRN_HSRR0,r11
2745         mtcrf   0x80,r9
2746         ld      r9,PACA_EXGEN+EX_R9(r13)
2747 BEGIN_FTR_SECTION
2748         ld      r10,PACA_EXGEN+EX_PPR(r13)
2749         mtspr   SPRN_PPR,r10
2750 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
2751 BEGIN_FTR_SECTION
2752         ld      r10,PACA_EXGEN+EX_CFAR(r13)
2753         mtspr   SPRN_CFAR,r10
2754 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
2755         ld      r10,PACA_EXGEN+EX_R10(r13)
2756         ld      r11,PACA_EXGEN+EX_R11(r13)
2757         ld      r12,PACA_EXGEN+EX_R12(r13)
2758         ld      r13,PACA_EXGEN+EX_R13(r13)
2759         HRFI_TO_UNKNOWN
2760         b       .
2761 #endif
2762
2763 EXC_COMMON_BEGIN(denorm_exception_common)
2764         GEN_COMMON denorm_exception
2765         addi    r3,r1,STACK_FRAME_OVERHEAD
2766         bl      unknown_exception
2767         b       interrupt_return
2768
2769         GEN_KVM denorm_exception
2770
2771
2772 #ifdef CONFIG_CBE_RAS
2773 INT_DEFINE_BEGIN(cbe_maintenance)
2774         IVEC=0x1600
2775         IHSRR=1
2776         IKVM_SKIP=1
2777         IKVM_REAL=1
2778 INT_DEFINE_END(cbe_maintenance)
2779
2780 EXC_REAL_BEGIN(cbe_maintenance, 0x1600, 0x100)
2781         GEN_INT_ENTRY cbe_maintenance, virt=0
2782 EXC_REAL_END(cbe_maintenance, 0x1600, 0x100)
2783 EXC_VIRT_NONE(0x5600, 0x100)
2784 EXC_COMMON_BEGIN(cbe_maintenance_common)
2785         GEN_COMMON cbe_maintenance
2786         addi    r3,r1,STACK_FRAME_OVERHEAD
2787         bl      cbe_maintenance_exception
2788         b       interrupt_return
2789
2790         GEN_KVM cbe_maintenance
2791
2792 #else /* CONFIG_CBE_RAS */
2793 EXC_REAL_NONE(0x1600, 0x100)
2794 EXC_VIRT_NONE(0x5600, 0x100)
2795 #endif
2796
2797
2798 INT_DEFINE_BEGIN(altivec_assist)
2799         IVEC=0x1700
2800 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
2801         IKVM_REAL=1
2802 #endif
2803 INT_DEFINE_END(altivec_assist)
2804
2805 EXC_REAL_BEGIN(altivec_assist, 0x1700, 0x100)
2806         GEN_INT_ENTRY altivec_assist, virt=0
2807 EXC_REAL_END(altivec_assist, 0x1700, 0x100)
2808 EXC_VIRT_BEGIN(altivec_assist, 0x5700, 0x100)
2809         GEN_INT_ENTRY altivec_assist, virt=1
2810 EXC_VIRT_END(altivec_assist, 0x5700, 0x100)
2811 EXC_COMMON_BEGIN(altivec_assist_common)
2812         GEN_COMMON altivec_assist
2813         addi    r3,r1,STACK_FRAME_OVERHEAD
2814 #ifdef CONFIG_ALTIVEC
2815         bl      altivec_assist_exception
2816         REST_NVGPRS(r1) /* instruction emulation may change GPRs */
2817 #else
2818         bl      unknown_exception
2819 #endif
2820         b       interrupt_return
2821
2822         GEN_KVM altivec_assist
2823
2824
2825 #ifdef CONFIG_CBE_RAS
2826 INT_DEFINE_BEGIN(cbe_thermal)
2827         IVEC=0x1800
2828         IHSRR=1
2829         IKVM_SKIP=1
2830         IKVM_REAL=1
2831 INT_DEFINE_END(cbe_thermal)
2832
2833 EXC_REAL_BEGIN(cbe_thermal, 0x1800, 0x100)
2834         GEN_INT_ENTRY cbe_thermal, virt=0
2835 EXC_REAL_END(cbe_thermal, 0x1800, 0x100)
2836 EXC_VIRT_NONE(0x5800, 0x100)
2837 EXC_COMMON_BEGIN(cbe_thermal_common)
2838         GEN_COMMON cbe_thermal
2839         addi    r3,r1,STACK_FRAME_OVERHEAD
2840         bl      cbe_thermal_exception
2841         b       interrupt_return
2842
2843         GEN_KVM cbe_thermal
2844
2845 #else /* CONFIG_CBE_RAS */
2846 EXC_REAL_NONE(0x1800, 0x100)
2847 EXC_VIRT_NONE(0x5800, 0x100)
2848 #endif
2849
2850
2851 #ifdef CONFIG_PPC_WATCHDOG
2852
2853 INT_DEFINE_BEGIN(soft_nmi)
2854         IVEC=0x900
2855         ISTACK=0
2856         IRECONCILE=0    /* Soft-NMI may fire under local_irq_disable */
2857 INT_DEFINE_END(soft_nmi)
2858
2859 /*
2860  * Branch to soft_nmi_interrupt using the emergency stack. The emergency
2861  * stack is one that is usable by maskable interrupts so long as MSR_EE
2862  * remains off. It is used for recovery when something has corrupted the
2863  * normal kernel stack, for example. The "soft NMI" must not use the process
2864  * stack because we want irq disabled sections to avoid touching the stack
2865  * at all (other than PMU interrupts), so use the emergency stack for this,
2866  * and run it entirely with interrupts hard disabled.
2867  */
2868 EXC_COMMON_BEGIN(soft_nmi_common)
2869         mfspr   r11,SPRN_SRR0
2870         mr      r10,r1
2871         ld      r1,PACAEMERGSP(r13)
2872         subi    r1,r1,INT_FRAME_SIZE
2873         __GEN_COMMON_BODY soft_nmi
2874
2875         /*
2876          * Set IRQS_ALL_DISABLED and save PACAIRQHAPPENED (see
2877          * system_reset_common)
2878          */
2879         li      r10,IRQS_ALL_DISABLED
2880         stb     r10,PACAIRQSOFTMASK(r13)
2881         lbz     r10,PACAIRQHAPPENED(r13)
2882         std     r10,RESULT(r1)
2883         ori     r10,r10,PACA_IRQ_HARD_DIS
2884         stb     r10,PACAIRQHAPPENED(r13)
2885
2886         addi    r3,r1,STACK_FRAME_OVERHEAD
2887         bl      soft_nmi_interrupt
2888
2889         /* Clear MSR_RI before setting SRR0 and SRR1. */
2890         li      r9,0
2891         mtmsrd  r9,1
2892
2893         /*
2894          * Restore soft mask settings.
2895          */
2896         ld      r10,RESULT(r1)
2897         stb     r10,PACAIRQHAPPENED(r13)
2898         ld      r10,SOFTE(r1)
2899         stb     r10,PACAIRQSOFTMASK(r13)
2900
2901         kuap_kernel_restore r9, r10
2902         EXCEPTION_RESTORE_REGS hsrr=0
2903         RFI_TO_KERNEL
2904
2905 #endif /* CONFIG_PPC_WATCHDOG */
2906
2907 /*
2908  * An interrupt came in while soft-disabled. We set paca->irq_happened, then:
2909  * - If it was a decrementer interrupt, we bump the dec to max and and return.
2910  * - If it was a doorbell we return immediately since doorbells are edge
2911  *   triggered and won't automatically refire.
2912  * - If it was a HMI we return immediately since we handled it in realmode
2913  *   and it won't refire.
2914  * - Else it is one of PACA_IRQ_MUST_HARD_MASK, so hard disable and return.
2915  * This is called with r10 containing the value to OR to the paca field.
2916  */
2917 .macro MASKED_INTERRUPT hsrr=0
2918         .if \hsrr
2919 masked_Hinterrupt:
2920         .else
2921 masked_interrupt:
2922         .endif
2923         lbz     r11,PACAIRQHAPPENED(r13)
2924         or      r11,r11,r10
2925         stb     r11,PACAIRQHAPPENED(r13)
2926         cmpwi   r10,PACA_IRQ_DEC
2927         bne     1f
2928         lis     r10,0x7fff
2929         ori     r10,r10,0xffff
2930         mtspr   SPRN_DEC,r10
2931 #ifdef CONFIG_PPC_WATCHDOG
2932         b       soft_nmi_common
2933 #else
2934         b       2f
2935 #endif
2936 1:      andi.   r10,r10,PACA_IRQ_MUST_HARD_MASK
2937         beq     2f
2938         xori    r12,r12,MSR_EE  /* clear MSR_EE */
2939         .if \hsrr
2940         mtspr   SPRN_HSRR1,r12
2941         .else
2942         mtspr   SPRN_SRR1,r12
2943         .endif
2944         ori     r11,r11,PACA_IRQ_HARD_DIS
2945         stb     r11,PACAIRQHAPPENED(r13)
2946 2:      /* done */
2947         ld      r10,PACA_EXGEN+EX_CTR(r13)
2948         mtctr   r10
2949         mtcrf   0x80,r9
2950         std     r1,PACAR1(r13)
2951         ld      r9,PACA_EXGEN+EX_R9(r13)
2952         ld      r10,PACA_EXGEN+EX_R10(r13)
2953         ld      r11,PACA_EXGEN+EX_R11(r13)
2954         ld      r12,PACA_EXGEN+EX_R12(r13)
2955         ld      r13,PACA_EXGEN+EX_R13(r13)
2956         /* May return to masked low address where r13 is not set up */
2957         .if \hsrr
2958         HRFI_TO_KERNEL
2959         .else
2960         RFI_TO_KERNEL
2961         .endif
2962         b       .
2963 .endm
2964
2965 TRAMP_REAL_BEGIN(stf_barrier_fallback)
2966         std     r9,PACA_EXRFI+EX_R9(r13)
2967         std     r10,PACA_EXRFI+EX_R10(r13)
2968         sync
2969         ld      r9,PACA_EXRFI+EX_R9(r13)
2970         ld      r10,PACA_EXRFI+EX_R10(r13)
2971         ori     31,31,0
2972         .rept 14
2973         b       1f
2974 1:
2975         .endr
2976         blr
2977
2978 /* Clobbers r10, r11, ctr */
2979 .macro L1D_DISPLACEMENT_FLUSH
2980         ld      r10,PACA_RFI_FLUSH_FALLBACK_AREA(r13)
2981         ld      r11,PACA_L1D_FLUSH_SIZE(r13)
2982         srdi    r11,r11,(7 + 3) /* 128 byte lines, unrolled 8x */
2983         mtctr   r11
2984         DCBT_BOOK3S_STOP_ALL_STREAM_IDS(r11) /* Stop prefetch streams */
2985
2986         /* order ld/st prior to dcbt stop all streams with flushing */
2987         sync
2988
2989         /*
2990          * The load addresses are at staggered offsets within cachelines,
2991          * which suits some pipelines better (on others it should not
2992          * hurt).
2993          */
2994 1:
2995         ld      r11,(0x80 + 8)*0(r10)
2996         ld      r11,(0x80 + 8)*1(r10)
2997         ld      r11,(0x80 + 8)*2(r10)
2998         ld      r11,(0x80 + 8)*3(r10)
2999         ld      r11,(0x80 + 8)*4(r10)
3000         ld      r11,(0x80 + 8)*5(r10)
3001         ld      r11,(0x80 + 8)*6(r10)
3002         ld      r11,(0x80 + 8)*7(r10)
3003         addi    r10,r10,0x80*8
3004         bdnz    1b
3005 .endm
3006
3007 TRAMP_REAL_BEGIN(entry_flush_fallback)
3008         std     r9,PACA_EXRFI+EX_R9(r13)
3009         std     r10,PACA_EXRFI+EX_R10(r13)
3010         std     r11,PACA_EXRFI+EX_R11(r13)
3011         mfctr   r9
3012         L1D_DISPLACEMENT_FLUSH
3013         mtctr   r9
3014         ld      r9,PACA_EXRFI+EX_R9(r13)
3015         ld      r10,PACA_EXRFI+EX_R10(r13)
3016         ld      r11,PACA_EXRFI+EX_R11(r13)
3017         blr
3018
3019 TRAMP_REAL_BEGIN(rfi_flush_fallback)
3020         SET_SCRATCH0(r13);
3021         GET_PACA(r13);
3022         std     r1,PACA_EXRFI+EX_R12(r13)
3023         ld      r1,PACAKSAVE(r13)
3024         std     r9,PACA_EXRFI+EX_R9(r13)
3025         std     r10,PACA_EXRFI+EX_R10(r13)
3026         std     r11,PACA_EXRFI+EX_R11(r13)
3027         mfctr   r9
3028         L1D_DISPLACEMENT_FLUSH
3029         mtctr   r9
3030         ld      r9,PACA_EXRFI+EX_R9(r13)
3031         ld      r10,PACA_EXRFI+EX_R10(r13)
3032         ld      r11,PACA_EXRFI+EX_R11(r13)
3033         ld      r1,PACA_EXRFI+EX_R12(r13)
3034         GET_SCRATCH0(r13);
3035         rfid
3036
3037 TRAMP_REAL_BEGIN(hrfi_flush_fallback)
3038         SET_SCRATCH0(r13);
3039         GET_PACA(r13);
3040         std     r1,PACA_EXRFI+EX_R12(r13)
3041         ld      r1,PACAKSAVE(r13)
3042         std     r9,PACA_EXRFI+EX_R9(r13)
3043         std     r10,PACA_EXRFI+EX_R10(r13)
3044         std     r11,PACA_EXRFI+EX_R11(r13)
3045         mfctr   r9
3046         L1D_DISPLACEMENT_FLUSH
3047         mtctr   r9
3048         ld      r9,PACA_EXRFI+EX_R9(r13)
3049         ld      r10,PACA_EXRFI+EX_R10(r13)
3050         ld      r11,PACA_EXRFI+EX_R11(r13)
3051         ld      r1,PACA_EXRFI+EX_R12(r13)
3052         GET_SCRATCH0(r13);
3053         hrfid
3054
3055 TRAMP_REAL_BEGIN(rfscv_flush_fallback)
3056         /* system call volatile */
3057         mr      r7,r13
3058         GET_PACA(r13);
3059         mr      r8,r1
3060         ld      r1,PACAKSAVE(r13)
3061         mfctr   r9
3062         ld      r10,PACA_RFI_FLUSH_FALLBACK_AREA(r13)
3063         ld      r11,PACA_L1D_FLUSH_SIZE(r13)
3064         srdi    r11,r11,(7 + 3) /* 128 byte lines, unrolled 8x */
3065         mtctr   r11
3066         DCBT_BOOK3S_STOP_ALL_STREAM_IDS(r11) /* Stop prefetch streams */
3067
3068         /* order ld/st prior to dcbt stop all streams with flushing */
3069         sync
3070
3071         /*
3072          * The load adresses are at staggered offsets within cachelines,
3073          * which suits some pipelines better (on others it should not
3074          * hurt).
3075          */
3076 1:
3077         ld      r11,(0x80 + 8)*0(r10)
3078         ld      r11,(0x80 + 8)*1(r10)
3079         ld      r11,(0x80 + 8)*2(r10)
3080         ld      r11,(0x80 + 8)*3(r10)
3081         ld      r11,(0x80 + 8)*4(r10)
3082         ld      r11,(0x80 + 8)*5(r10)
3083         ld      r11,(0x80 + 8)*6(r10)
3084         ld      r11,(0x80 + 8)*7(r10)
3085         addi    r10,r10,0x80*8
3086         bdnz    1b
3087
3088         mtctr   r9
3089         li      r9,0
3090         li      r10,0
3091         li      r11,0
3092         mr      r1,r8
3093         mr      r13,r7
3094         RFSCV
3095
3096 USE_TEXT_SECTION()
3097
3098 _GLOBAL(do_uaccess_flush)
3099         UACCESS_FLUSH_FIXUP_SECTION
3100         nop
3101         nop
3102         nop
3103         blr
3104         L1D_DISPLACEMENT_FLUSH
3105         blr
3106 _ASM_NOKPROBE_SYMBOL(do_uaccess_flush)
3107 EXPORT_SYMBOL(do_uaccess_flush)
3108
3109
3110 MASKED_INTERRUPT
3111 MASKED_INTERRUPT hsrr=1
3112
3113 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
3114 kvmppc_skip_interrupt:
3115         /*
3116          * Here all GPRs are unchanged from when the interrupt happened
3117          * except for r13, which is saved in SPRG_SCRATCH0.
3118          */
3119         mfspr   r13, SPRN_SRR0
3120         addi    r13, r13, 4
3121         mtspr   SPRN_SRR0, r13
3122         GET_SCRATCH0(r13)
3123         RFI_TO_KERNEL
3124         b       .
3125
3126 kvmppc_skip_Hinterrupt:
3127         /*
3128          * Here all GPRs are unchanged from when the interrupt happened
3129          * except for r13, which is saved in SPRG_SCRATCH0.
3130          */
3131         mfspr   r13, SPRN_HSRR0
3132         addi    r13, r13, 4
3133         mtspr   SPRN_HSRR0, r13
3134         GET_SCRATCH0(r13)
3135         HRFI_TO_KERNEL
3136         b       .
3137 #endif
3138
3139         /*
3140          * Relocation-on interrupts: A subset of the interrupts can be delivered
3141          * with IR=1/DR=1, if AIL==2 and MSR.HV won't be changed by delivering
3142          * it.  Addresses are the same as the original interrupt addresses, but
3143          * offset by 0xc000000000004000.
3144          * It's impossible to receive interrupts below 0x300 via this mechanism.
3145          * KVM: None of these traps are from the guest ; anything that escalated
3146          * to HV=1 from HV=0 is delivered via real mode handlers.
3147          */
3148
3149         /*
3150          * This uses the standard macro, since the original 0x300 vector
3151          * only has extra guff for STAB-based processors -- which never
3152          * come here.
3153          */
3154
3155 EXC_COMMON_BEGIN(ppc64_runlatch_on_trampoline)
3156         b       __ppc64_runlatch_on
3157
3158 USE_FIXED_SECTION(virt_trampolines)
3159         /*
3160          * All code below __end_interrupts is treated as soft-masked. If
3161          * any code runs here with MSR[EE]=1, it must then cope with pending
3162          * soft interrupt being raised (i.e., by ensuring it is replayed).
3163          *
3164          * The __end_interrupts marker must be past the out-of-line (OOL)
3165          * handlers, so that they are copied to real address 0x100 when running
3166          * a relocatable kernel. This ensures they can be reached from the short
3167          * trampoline handlers (like 0x4f00, 0x4f20, etc.) which branch
3168          * directly, without using LOAD_HANDLER().
3169          */
3170         .align  7
3171         .globl  __end_interrupts
3172 __end_interrupts:
3173 DEFINE_FIXED_SYMBOL(__end_interrupts)
3174
3175 #ifdef CONFIG_PPC_970_NAP
3176         /*
3177          * Called by exception entry code if _TLF_NAPPING was set, this clears
3178          * the NAPPING flag, and redirects the exception exit to
3179          * power4_fixup_nap_return.
3180          */
3181         .globl power4_fixup_nap
3182 EXC_COMMON_BEGIN(power4_fixup_nap)
3183         andc    r9,r9,r10
3184         std     r9,TI_LOCAL_FLAGS(r11)
3185         LOAD_REG_ADDR(r10, power4_idle_nap_return)
3186         std     r10,_NIP(r1)
3187         blr
3188
3189 power4_idle_nap_return:
3190         blr
3191 #endif
3192
3193 CLOSE_FIXED_SECTION(real_vectors);
3194 CLOSE_FIXED_SECTION(real_trampolines);
3195 CLOSE_FIXED_SECTION(virt_vectors);
3196 CLOSE_FIXED_SECTION(virt_trampolines);
3197
3198 USE_TEXT_SECTION()
3199
3200 /* MSR[RI] should be clear because this uses SRR[01] */
3201 enable_machine_check:
3202         mflr    r0
3203         bcl     20,31,$+4
3204 0:      mflr    r3
3205         addi    r3,r3,(1f - 0b)
3206         mtspr   SPRN_SRR0,r3
3207         mfmsr   r3
3208         ori     r3,r3,MSR_ME
3209         mtspr   SPRN_SRR1,r3
3210         RFI_TO_KERNEL
3211 1:      mtlr    r0
3212         blr
3213
3214 /* MSR[RI] should be clear because this uses SRR[01] */
3215 disable_machine_check:
3216         mflr    r0
3217         bcl     20,31,$+4
3218 0:      mflr    r3
3219         addi    r3,r3,(1f - 0b)
3220         mtspr   SPRN_SRR0,r3
3221         mfmsr   r3
3222         li      r4,MSR_ME
3223         andc    r3,r3,r4
3224         mtspr   SPRN_SRR1,r3
3225         RFI_TO_KERNEL
3226 1:      mtlr    r0
3227         blr