arch/arm64/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * ld script to make ARM Linux kernel
   4  * taken from the i386 version by Russell King
   5  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   6  */
   7
   8 #include <asm/hyp_image.h>
   9 #ifdef CONFIG_KVM
  10 #define HYPERVISOR_EXTABLE                                      \
  11         . = ALIGN(SZ_8);                                        \
  12         __start___kvm_ex_table = .;                             \
  13         *(__kvm_ex_table)                                       \
  14         __stop___kvm_ex_table = .;
  15
  16 #define HYPERVISOR_DATA_SECTIONS                                \
  17         HYP_SECTION_NAME(.rodata) : {                           \
  18                 . = ALIGN(PAGE_SIZE);                           \
  19                 __hyp_rodata_start = .;                         \
  20                 *(HYP_SECTION_NAME(.data..ro_after_init))       \
  21                 *(HYP_SECTION_NAME(.rodata))                    \
  22                 . = ALIGN(PAGE_SIZE);                           \
  23                 __hyp_rodata_end = .;                           \
  24         }
  25
  26 #define HYPERVISOR_PERCPU_SECTION                               \
  27         . = ALIGN(PAGE_SIZE);                                   \
  28         HYP_SECTION_NAME(.data..percpu) : {                     \
  29                 *(HYP_SECTION_NAME(.data..percpu))              \
  30         }
  31
  32 #define HYPERVISOR_RELOC_SECTION                                \
  33         .hyp.reloc : ALIGN(4) {                                 \
  34                 __hyp_reloc_begin = .;                          \
  35                 *(.hyp.reloc)                                   \
  36                 __hyp_reloc_end = .;                            \
  37         }
  38
  39 #define BSS_FIRST_SECTIONS                                      \
  40         __hyp_bss_start = .;                                    \
  41         *(HYP_SECTION_NAME(.bss))                               \
  42         . = ALIGN(PAGE_SIZE);                                   \
  43         __hyp_bss_end = .;
  44
  45 /*
  46  * We require that __hyp_bss_start and __bss_start are aligned, and enforce it
  47  * with an assertion. But the BSS_SECTION macro places an empty .sbss section
  48  * between them, which can in some cases cause the linker to misalign them. To
  49  * work around the issue, force a page alignment for __bss_start.
  50  */
  51 #define SBSS_ALIGN                      PAGE_SIZE
  52 #else /* CONFIG_KVM */
  53 #define HYPERVISOR_EXTABLE
  54 #define HYPERVISOR_DATA_SECTIONS
  55 #define HYPERVISOR_PERCPU_SECTION
  56 #define HYPERVISOR_RELOC_SECTION
  57 #define SBSS_ALIGN                      0
  58 #endif
  59
  60 #define RO_EXCEPTION_TABLE_ALIGN        4
  61 #define RUNTIME_DISCARD_EXIT
  62
  63 #include <asm-generic/vmlinux.lds.h>
  64 #include <asm/cache.h>
  65 #include <asm/kernel-pgtable.h>
  66 #include <asm/kexec.h>
  67 #include <asm/memory.h>
  68 #include <asm/page.h>
  69
  70 #include "image.h"
  71
  72 OUTPUT_ARCH(aarch64)
  73 ENTRY(_text)
  74
  75 jiffies = jiffies_64;
  76
  77 #define HYPERVISOR_TEXT                                 \
  78         . = ALIGN(PAGE_SIZE);                           \
  79         __hyp_idmap_text_start = .;                     \
  80         *(.hyp.idmap.text)                              \
  81         __hyp_idmap_text_end = .;                       \
  82         __hyp_text_start = .;                           \
  83         *(.hyp.text)                                    \
  84         HYPERVISOR_EXTABLE                              \
  85         . = ALIGN(PAGE_SIZE);                           \
  86         __hyp_text_end = .;
  87
  88 #define IDMAP_TEXT                                      \
  89         . = ALIGN(SZ_4K);                               \
  90         __idmap_text_start = .;                         \
  91         *(.idmap.text)                                  \
  92         __idmap_text_end = .;
  93
  94 #ifdef CONFIG_HIBERNATION
  95 #define HIBERNATE_TEXT                                  \
  96         __hibernate_exit_text_start = .;                \
  97         *(.hibernate_exit.text)                         \
  98         __hibernate_exit_text_end = .;
  99 #else
 100 #define HIBERNATE_TEXT
 101 #endif
 102
 103 #ifdef CONFIG_KEXEC_CORE
 104 #define KEXEC_TEXT                                      \
 105         __relocate_new_kernel_start = .;                \
 106         *(.kexec_relocate.text)                         \
 107         __relocate_new_kernel_end = .;
 108 #else
 109 #define KEXEC_TEXT
 110 #endif
 111
 112 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 113 #define TRAMP_TEXT                                      \
 114         . = ALIGN(PAGE_SIZE);                           \
 115         __entry_tramp_text_start = .;                   \
 116         *(.entry.tramp.text)                            \
 117         . = ALIGN(PAGE_SIZE);                           \
 118         __entry_tramp_text_end = .;                     \
 119         *(.entry.tramp.rodata)
 120 #else
 121 #define TRAMP_TEXT
 122 #endif
 123
 124 /*
 125  * The size of the PE/COFF section that covers the kernel image, which
 126  * runs from _stext to _edata, must be a round multiple of the PE/COFF
 127  * FileAlignment, which we set to its minimum value of 0x200. '_stext'
 128  * itself is 4 KB aligned, so padding out _edata to a 0x200 aligned
 129  * boundary should be sufficient.
 130  */
 131 PECOFF_FILE_ALIGNMENT = 0x200;
 132
 133 #ifdef CONFIG_EFI
 134 #define PECOFF_EDATA_PADDING    \
 135         .pecoff_edata_padding : { BYTE(0); . = ALIGN(PECOFF_FILE_ALIGNMENT); }
 136 #else
 137 #define PECOFF_EDATA_PADDING
 138 #endif
 139
 140 SECTIONS
 141 {
 142         /*
 143          * XXX: The linker does not define how output sections are
 144          * assigned to input sections when there are multiple statements
 145          * matching the same input section name.  There is no documented
 146          * order of matching.
 147          */
 148         DISCARDS
 149         /DISCARD/ : {
 150                 *(.interp .dynamic)
 151                 *(.dynsym .dynstr .hash .gnu.hash)
 152         }
 153
 154         . = KIMAGE_VADDR;
 155
 156         .head.text : {
 157                 _text = .;
 158                 HEAD_TEXT
 159         }
 160         .text : ALIGN(SEGMENT_ALIGN) {  /* Real text segment            */
 161                 _stext = .;             /* Text and read-only data      */
 162                         IRQENTRY_TEXT
 163                         SOFTIRQENTRY_TEXT
 164                         ENTRY_TEXT
 165                         TEXT_TEXT
 166                         SCHED_TEXT
 167                         CPUIDLE_TEXT
 168                         LOCK_TEXT
 169                         KPROBES_TEXT
 170                         HYPERVISOR_TEXT
 171                         IDMAP_TEXT
 172                         *(.gnu.warning)
 173                 . = ALIGN(16);
 174                 *(.got)                 /* Global offset table          */
 175         }
 176
 177         /*
 178          * Make sure that the .got.plt is either completely empty or it
 179          * contains only the lazy dispatch entries.
 180          */
 181         .got.plt : { *(.got.plt) }
 182         ASSERT(SIZEOF(.got.plt) == 0 || SIZEOF(.got.plt) == 0x18,
 183                "Unexpected GOT/PLT entries detected!")
 184
 185         . = ALIGN(SEGMENT_ALIGN);
 186         _etext = .;                     /* End of text section */
 187
 188         /* everything from this point to __init_begin will be marked RO NX */
 189         RO_DATA(PAGE_SIZE)
 190
 191         HYPERVISOR_DATA_SECTIONS
 192
 193         /* code sections that are never executed via the kernel mapping */
 194         .rodata.text : {
 195                 TRAMP_TEXT
 196                 HIBERNATE_TEXT
 197                 KEXEC_TEXT
 198                 . = ALIGN(PAGE_SIZE);
 199         }
 200
 201         idmap_pg_dir = .;
 202         . += IDMAP_DIR_SIZE;
 203         idmap_pg_end = .;
 204
 205 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 206         tramp_pg_dir = .;
 207         . += PAGE_SIZE;
 208 #endif
 209
 210         reserved_pg_dir = .;
 211         . += PAGE_SIZE;
 212
 213         swapper_pg_dir = .;
 214         . += PAGE_SIZE;
 215
 216         . = ALIGN(SEGMENT_ALIGN);
 217         __init_begin = .;
 218         __inittext_begin = .;
 219
 220         INIT_TEXT_SECTION(8)
 221
 222         __exittext_begin = .;
 223         .exit.text : {
 224                 EXIT_TEXT
 225         }
 226         __exittext_end = .;
 227
 228         . = ALIGN(4);
 229         .altinstructions : {
 230                 __alt_instructions = .;
 231                 *(.altinstructions)
 232                 __alt_instructions_end = .;
 233         }
 234
 235         . = ALIGN(SEGMENT_ALIGN);
 236         __inittext_end = .;
 237         __initdata_begin = .;
 238
 239         .init.data : {
 240                 INIT_DATA
 241                 INIT_SETUP(16)
 242                 INIT_CALLS
 243                 CON_INITCALL
 244                 INIT_RAM_FS
 245                 *(.init.altinstructions .init.bss)      /* from the EFI stub */
 246         }
 247         .exit.data : {
 248                 EXIT_DATA
 249         }
 250
 251         PERCPU_SECTION(L1_CACHE_BYTES)
 252         HYPERVISOR_PERCPU_SECTION
 253
 254         HYPERVISOR_RELOC_SECTION
 255
 256         .rela.dyn : ALIGN(8) {
 257                 *(.rela .rela*)
 258         }
 259
 260         __rela_offset   = ABSOLUTE(ADDR(.rela.dyn) - KIMAGE_VADDR);
 261         __rela_size     = SIZEOF(.rela.dyn);
 262
 263 #ifdef CONFIG_RELR
 264         .relr.dyn : ALIGN(8) {
 265                 *(.relr.dyn)
 266         }
 267
 268         __relr_offset   = ABSOLUTE(ADDR(.relr.dyn) - KIMAGE_VADDR);
 269         __relr_size     = SIZEOF(.relr.dyn);
 270 #endif
 271
 272         . = ALIGN(SEGMENT_ALIGN);
 273         __initdata_end = .;
 274         __init_end = .;
 275
 276         _data = .;
 277         _sdata = .;
 278         RW_DATA(L1_CACHE_BYTES, PAGE_SIZE, THREAD_ALIGN)
 279
 280         /*
 281          * Data written with the MMU off but read with the MMU on requires
 282          * cache lines to be invalidated, discarding up to a Cache Writeback
 283          * Granule (CWG) of data from the cache. Keep the section that
 284          * requires this type of maintenance to be in its own Cache Writeback
 285          * Granule (CWG) area so the cache maintenance operations don't
 286          * interfere with adjacent data.
 287          */
 288         .mmuoff.data.write : ALIGN(SZ_2K) {
 289                 __mmuoff_data_start = .;
 290                 *(.mmuoff.data.write)
 291         }
 292         . = ALIGN(SZ_2K);
 293         .mmuoff.data.read : {
 294                 *(.mmuoff.data.read)
 295                 __mmuoff_data_end = .;
 296         }
 297
 298         PECOFF_EDATA_PADDING
 299         __pecoff_data_rawsize = ABSOLUTE(. - __initdata_begin);
 300         _edata = .;
 301
 302         BSS_SECTION(SBSS_ALIGN, 0, 0)
 303
 304         . = ALIGN(PAGE_SIZE);
 305         init_pg_dir = .;
 306         . += INIT_DIR_SIZE;
 307         init_pg_end = .;
 308
 309         . = ALIGN(SEGMENT_ALIGN);
 310         __pecoff_data_size = ABSOLUTE(. - __initdata_begin);
 311         _end = .;
 312
 313         STABS_DEBUG
 314         DWARF_DEBUG
 315         ELF_DETAILS
 316
 317         HEAD_SYMBOLS
 318
 319         /*
 320          * Sections that should stay zero sized, which is safer to
 321          * explicitly check instead of blindly discarding.
 322          */
 323         .plt : {
 324                 *(.plt) *(.plt.*) *(.iplt) *(.igot .igot.plt)
 325         }
 326         ASSERT(SIZEOF(.plt) == 0, "Unexpected run-time procedure linkages detected!")
 327
 328         .data.rel.ro : { *(.data.rel.ro) }
 329         ASSERT(SIZEOF(.data.rel.ro) == 0, "Unexpected RELRO detected!")
 330 }
 331
 332 #include "image-vars.h"
 333
 334 /*
 335  * The HYP init code and ID map text can't be longer than a page each. The
 336  * former is page-aligned, but the latter may not be with 16K or 64K pages, so
 337  * it should also not cross a page boundary.
 338  */
 339 ASSERT(__hyp_idmap_text_end - __hyp_idmap_text_start <= PAGE_SIZE,
 340         "HYP init code too big")
 341 ASSERT(__idmap_text_end - (__idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 342         "ID map text too big or misaligned")
 343 #ifdef CONFIG_HIBERNATION
 344 ASSERT(__hibernate_exit_text_end - __hibernate_exit_text_start <= SZ_4K,
 345        "Hibernate exit text is bigger than 4 KiB")
 346 #endif
 347 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 348 ASSERT((__entry_tramp_text_end - __entry_tramp_text_start) <= 3*PAGE_SIZE,
 349         "Entry trampoline text too big")
 350 #endif
 351 #ifdef CONFIG_KVM
 352 ASSERT(__hyp_bss_start == __bss_start, "HYP and Host BSS are misaligned")
 353 #endif
 354 /*
 355  * If padding is applied before .head.text, virt<->phys conversions will fail.
 356  */
 357 ASSERT(_text == KIMAGE_VADDR, "HEAD is misaligned")
 358
 359 ASSERT(swapper_pg_dir - reserved_pg_dir == RESERVED_SWAPPER_OFFSET,
 360        "RESERVED_SWAPPER_OFFSET is wrong!")
 361
 362 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 363 ASSERT(swapper_pg_dir - tramp_pg_dir == TRAMP_SWAPPER_OFFSET,
 364        "TRAMP_SWAPPER_OFFSET is wrong!")
 365 #endif
 366
 367 #ifdef CONFIG_KEXEC_CORE
 368 /* kexec relocation code should fit into one KEXEC_CONTROL_PAGE_SIZE */
 369 ASSERT(__relocate_new_kernel_end - __relocate_new_kernel_start <= SZ_4K,
 370        "kexec relocation code is bigger than 4 KiB")
 371 ASSERT(KEXEC_CONTROL_PAGE_SIZE >= SZ_4K, "KEXEC_CONTROL_PAGE_SIZE is broken")
 372 #endif