arch/arm64/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * ld script to make ARM Linux kernel
   4  * taken from the i386 version by Russell King
   5  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   6  */
   7
   8 #include <asm-generic/vmlinux.lds.h>
   9 #include <asm/cache.h>
  10 #include <asm/kernel-pgtable.h>
  11 #include <asm/thread_info.h>
  12 #include <asm/memory.h>
  13 #include <asm/page.h>
  14 #include <asm/pgtable.h>
  15
  16 #include "image.h"
  17
  18 /* .exit.text needed in case of alternative patching */
  19 #define ARM_EXIT_KEEP(x)        x
  20 #define ARM_EXIT_DISCARD(x)
  21
  22 OUTPUT_ARCH(aarch64)
  23 ENTRY(_text)
  24
  25 jiffies = jiffies_64;
  26
  27 #define HYPERVISOR_TEXT                                 \
  28         /*                                              \
  29          * Align to 4 KB so that                        \
  30          * a) the HYP vector table is at its minimum    \
  31          *    alignment of 2048 bytes                   \
  32          * b) the HYP init code will not cross a page   \
  33          *    boundary if its size does not exceed      \
  34          *    4 KB (see related ASSERT() below)         \
  35          */                                             \
  36         . = ALIGN(SZ_4K);                               \
  37         __hyp_idmap_text_start = .;                     \
  38         *(.hyp.idmap.text)                              \
  39         __hyp_idmap_text_end = .;                       \
  40         __hyp_text_start = .;                           \
  41         *(.hyp.text)                                    \
  42         __hyp_text_end = .;
  43
  44 #define IDMAP_TEXT                                      \
  45         . = ALIGN(SZ_4K);                               \
  46         __idmap_text_start = .;                         \
  47         *(.idmap.text)                                  \
  48         __idmap_text_end = .;
  49
  50 #ifdef CONFIG_HIBERNATION
  51 #define HIBERNATE_TEXT                                  \
  52         . = ALIGN(SZ_4K);                               \
  53         __hibernate_exit_text_start = .;                \
  54         *(.hibernate_exit.text)                         \
  55         __hibernate_exit_text_end = .;
  56 #else
  57 #define HIBERNATE_TEXT
  58 #endif
  59
  60 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
  61 #define TRAMP_TEXT                                      \
  62         . = ALIGN(PAGE_SIZE);                           \
  63         __entry_tramp_text_start = .;                   \
  64         *(.entry.tramp.text)                            \
  65         . = ALIGN(PAGE_SIZE);                           \
  66         __entry_tramp_text_end = .;
  67 #else
  68 #define TRAMP_TEXT
  69 #endif
  70
  71 /*
  72  * The size of the PE/COFF section that covers the kernel image, which
  73  * runs from stext to _edata, must be a round multiple of the PE/COFF
  74  * FileAlignment, which we set to its minimum value of 0x200. 'stext'
  75  * itself is 4 KB aligned, so padding out _edata to a 0x200 aligned
  76  * boundary should be sufficient.
  77  */
  78 PECOFF_FILE_ALIGNMENT = 0x200;
  79
  80 #ifdef CONFIG_EFI
  81 #define PECOFF_EDATA_PADDING    \
  82         .pecoff_edata_padding : { BYTE(0); . = ALIGN(PECOFF_FILE_ALIGNMENT); }
  83 #else
  84 #define PECOFF_EDATA_PADDING
  85 #endif
  86
  87 SECTIONS
  88 {
  89         /*
  90          * XXX: The linker does not define how output sections are
  91          * assigned to input sections when there are multiple statements
  92          * matching the same input section name.  There is no documented
  93          * order of matching.
  94          */
  95         /DISCARD/ : {
  96                 ARM_EXIT_DISCARD(EXIT_TEXT)
  97                 ARM_EXIT_DISCARD(EXIT_DATA)
  98                 EXIT_CALL
  99                 *(.discard)
 100                 *(.discard.*)
 101                 *(.interp .dynamic)
 102                 *(.dynsym .dynstr .hash .gnu.hash)
 103                 *(.eh_frame)
 104         }
 105
 106         . = KIMAGE_VADDR + TEXT_OFFSET;
 107
 108         .head.text : {
 109                 _text = .;
 110                 HEAD_TEXT
 111         }
 112         .text : {                       /* Real text segment            */
 113                 _stext = .;             /* Text and read-only data      */
 114                         IRQENTRY_TEXT
 115                         SOFTIRQENTRY_TEXT
 116                         ENTRY_TEXT
 117                         TEXT_TEXT
 118                         SCHED_TEXT
 119                         CPUIDLE_TEXT
 120                         LOCK_TEXT
 121                         KPROBES_TEXT
 122                         HYPERVISOR_TEXT
 123                         IDMAP_TEXT
 124                         HIBERNATE_TEXT
 125                         TRAMP_TEXT
 126                         *(.fixup)
 127                         *(.gnu.warning)
 128                 . = ALIGN(16);
 129                 *(.got)                 /* Global offset table          */
 130         }
 131
 132         . = ALIGN(SEGMENT_ALIGN);
 133         _etext = .;                     /* End of text section */
 134
 135         RO_DATA(PAGE_SIZE)              /* everything from this point to     */
 136         EXCEPTION_TABLE(8)              /* __init_begin will be marked RO NX */
 137         NOTES
 138
 139         . = ALIGN(PAGE_SIZE);
 140         idmap_pg_dir = .;
 141         . += IDMAP_DIR_SIZE;
 142
 143 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 144         tramp_pg_dir = .;
 145         . += PAGE_SIZE;
 146 #endif
 147
 148 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 149         reserved_ttbr0 = .;
 150         . += RESERVED_TTBR0_SIZE;
 151 #endif
 152         swapper_pg_dir = .;
 153         . += PAGE_SIZE;
 154         swapper_pg_end = .;
 155
 156         . = ALIGN(SEGMENT_ALIGN);
 157         __init_begin = .;
 158         __inittext_begin = .;
 159
 160         INIT_TEXT_SECTION(8)
 161         .exit.text : {
 162                 ARM_EXIT_KEEP(EXIT_TEXT)
 163         }
 164
 165         . = ALIGN(4);
 166         .altinstructions : {
 167                 __alt_instructions = .;
 168                 *(.altinstructions)
 169                 __alt_instructions_end = .;
 170         }
 171         .altinstr_replacement : {
 172                 *(.altinstr_replacement)
 173         }
 174
 175         . = ALIGN(PAGE_SIZE);
 176         __inittext_end = .;
 177         __initdata_begin = .;
 178
 179         .init.data : {
 180                 INIT_DATA
 181                 INIT_SETUP(16)
 182                 INIT_CALLS
 183                 CON_INITCALL
 184                 INIT_RAM_FS
 185                 *(.init.rodata.* .init.bss)     /* from the EFI stub */
 186         }
 187         .exit.data : {
 188                 ARM_EXIT_KEEP(EXIT_DATA)
 189         }
 190
 191         PERCPU_SECTION(L1_CACHE_BYTES)
 192
 193         .rela.dyn : ALIGN(8) {
 194                 *(.rela .rela*)
 195         }
 196
 197         __rela_offset   = ABSOLUTE(ADDR(.rela.dyn) - KIMAGE_VADDR);
 198         __rela_size     = SIZEOF(.rela.dyn);
 199
 200 #ifdef CONFIG_RELR
 201         .relr.dyn : ALIGN(8) {
 202                 *(.relr.dyn)
 203         }
 204
 205         __relr_offset   = ABSOLUTE(ADDR(.relr.dyn) - KIMAGE_VADDR);
 206         __relr_size     = SIZEOF(.relr.dyn);
 207 #endif
 208
 209         . = ALIGN(SEGMENT_ALIGN);
 210         __initdata_end = .;
 211         __init_end = .;
 212
 213         _data = .;
 214         _sdata = .;
 215         RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, THREAD_ALIGN)
 216
 217         /*
 218          * Data written with the MMU off but read with the MMU on requires
 219          * cache lines to be invalidated, discarding up to a Cache Writeback
 220          * Granule (CWG) of data from the cache. Keep the section that
 221          * requires this type of maintenance to be in its own Cache Writeback
 222          * Granule (CWG) area so the cache maintenance operations don't
 223          * interfere with adjacent data.
 224          */
 225         .mmuoff.data.write : ALIGN(SZ_2K) {
 226                 __mmuoff_data_start = .;
 227                 *(.mmuoff.data.write)
 228         }
 229         . = ALIGN(SZ_2K);
 230         .mmuoff.data.read : {
 231                 *(.mmuoff.data.read)
 232                 __mmuoff_data_end = .;
 233         }
 234
 235         PECOFF_EDATA_PADDING
 236         __pecoff_data_rawsize = ABSOLUTE(. - __initdata_begin);
 237         _edata = .;
 238
 239         BSS_SECTION(0, 0, 0)
 240
 241         . = ALIGN(PAGE_SIZE);
 242         init_pg_dir = .;
 243         . += INIT_DIR_SIZE;
 244         init_pg_end = .;
 245
 246         __pecoff_data_size = ABSOLUTE(. - __initdata_begin);
 247         _end = .;
 248
 249         STABS_DEBUG
 250
 251         HEAD_SYMBOLS
 252 }
 253
 254 #include "image-vars.h"
 255
 256 /*
 257  * The HYP init code and ID map text can't be longer than a page each,
 258  * and should not cross a page boundary.
 259  */
 260 ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 261         "HYP init code too big or misaligned")
 262 ASSERT(__idmap_text_end - (__idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 263         "ID map text too big or misaligned")
 264 #ifdef CONFIG_HIBERNATION
 265 ASSERT(__hibernate_exit_text_end - (__hibernate_exit_text_start & ~(SZ_4K - 1))
 266         <= SZ_4K, "Hibernate exit text too big or misaligned")
 267 #endif
 268 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 269 ASSERT((__entry_tramp_text_end - __entry_tramp_text_start) == PAGE_SIZE,
 270         "Entry trampoline text too big")
 271 #endif
 272 /*
 273  * If padding is applied before .head.text, virt<->phys conversions will fail.
 274  */
 275 ASSERT(_text == (KIMAGE_VADDR + TEXT_OFFSET), "HEAD is misaligned")