arch/arm64/kernel/hyp-stub.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  * Hypervisor stub
   4  *
   5  * Copyright (C) 2012 ARM Ltd.
   6  * Author:      Marc Zyngier <marc.zyngier@arm.com>
   7  */
   8
   9 #include <linux/init.h>
  10 #include <linux/linkage.h>
  11
  12 #include <asm/assembler.h>
  13 #include <asm/el2_setup.h>
  14 #include <asm/kvm_arm.h>
  15 #include <asm/kvm_asm.h>
  16 #include <asm/ptrace.h>
  17 #include <asm/virt.h>
  18
  19 // Warning, hardcoded register allocation
  20 // This will clobber x1 and x2, and expect x1 to contain
  21 // the id register value as read from the HW
  22 .macro __check_override idreg, fld, width, pass, fail
  23         ubfx    x1, x1, #\fld, #\width
  24         cbz     x1, \fail
  25
  26         adr_l   x1, \idreg\()_override
  27         ldr     x2, [x1, FTR_OVR_VAL_OFFSET]
  28         ldr     x1, [x1, FTR_OVR_MASK_OFFSET]
  29         ubfx    x2, x2, #\fld, #\width
  30         ubfx    x1, x1, #\fld, #\width
  31         cmp     x1, xzr
  32         and     x2, x2, x1
  33         csinv   x2, x2, xzr, ne
  34         cbnz    x2, \pass
  35         b       \fail
  36 .endm
  37
  38 .macro check_override idreg, fld, pass, fail
  39         mrs     x1, \idreg\()_el1
  40         __check_override \idreg \fld 4 \pass \fail
  41 .endm
  42
  43         .text
  44         .pushsection    .hyp.text, "ax"
  45
  46         .align 11
  47
  48 SYM_CODE_START(__hyp_stub_vectors)
  49         ventry  el2_sync_invalid                // Synchronous EL2t
  50         ventry  el2_irq_invalid                 // IRQ EL2t
  51         ventry  el2_fiq_invalid                 // FIQ EL2t
  52         ventry  el2_error_invalid               // Error EL2t
  53
  54         ventry  elx_sync                        // Synchronous EL2h
  55         ventry  el2_irq_invalid                 // IRQ EL2h
  56         ventry  el2_fiq_invalid                 // FIQ EL2h
  57         ventry  el2_error_invalid               // Error EL2h
  58
  59         ventry  elx_sync                        // Synchronous 64-bit EL1
  60         ventry  el1_irq_invalid                 // IRQ 64-bit EL1
  61         ventry  el1_fiq_invalid                 // FIQ 64-bit EL1
  62         ventry  el1_error_invalid               // Error 64-bit EL1
  63
  64         ventry  el1_sync_invalid                // Synchronous 32-bit EL1
  65         ventry  el1_irq_invalid                 // IRQ 32-bit EL1
  66         ventry  el1_fiq_invalid                 // FIQ 32-bit EL1
  67         ventry  el1_error_invalid               // Error 32-bit EL1
  68 SYM_CODE_END(__hyp_stub_vectors)
  69
  70         .align 11
  71
  72 SYM_CODE_START_LOCAL(elx_sync)
  73         cmp     x0, #HVC_SET_VECTORS
  74         b.ne    1f
  75         msr     vbar_el2, x1
  76         b       9f
  77
  78 1:      cmp     x0, #HVC_FINALISE_EL2
  79         b.eq    __finalise_el2
  80
  81 2:      cmp     x0, #HVC_SOFT_RESTART
  82         b.ne    3f
  83         mov     x0, x2
  84         mov     x2, x4
  85         mov     x4, x1
  86         mov     x1, x3
  87         br      x4                              // no return
  88
  89 3:      cmp     x0, #HVC_RESET_VECTORS
  90         beq     9f                              // Nothing to reset!
  91
  92         /* Someone called kvm_call_hyp() against the hyp-stub... */
  93         mov_q   x0, HVC_STUB_ERR
  94         eret
  95
  96 9:      mov     x0, xzr
  97         eret
  98 SYM_CODE_END(elx_sync)
  99
 100 SYM_CODE_START_LOCAL(__finalise_el2)
 101         check_override id_aa64pfr0 ID_AA64PFR0_SVE_SHIFT .Linit_sve .Lskip_sve
 102
 103 .Linit_sve:     /* SVE register access */
 104         mrs     x0, cptr_el2                    // Disable SVE traps
 105         bic     x0, x0, #CPTR_EL2_TZ
 106         msr     cptr_el2, x0
 107         isb
 108         mov     x1, #ZCR_ELx_LEN_MASK           // SVE: Enable full vector
 109         msr_s   SYS_ZCR_EL2, x1                 // length for EL1.
 110
 111 .Lskip_sve:
 112         check_override id_aa64pfr1 ID_AA64PFR1_SME_SHIFT .Linit_sme .Lskip_sme
 113
 114 .Linit_sme:     /* SME register access and priority mapping */
 115         mrs     x0, cptr_el2                    // Disable SME traps
 116         bic     x0, x0, #CPTR_EL2_TSM
 117         msr     cptr_el2, x0
 118         isb
 119
 120         mrs     x1, sctlr_el2
 121         orr     x1, x1, #SCTLR_ELx_ENTP2        // Disable TPIDR2 traps
 122         msr     sctlr_el2, x1
 123         isb
 124
 125         mov     x1, #0                          // SMCR controls
 126
 127         mrs_s   x2, SYS_ID_AA64SMFR0_EL1
 128         ubfx    x2, x2, #ID_AA64SMFR0_FA64_SHIFT, #1 // Full FP in SM?
 129         cbz     x2, .Lskip_sme_fa64
 130
 131         orr     x1, x1, SMCR_ELx_FA64_MASK
 132 .Lskip_sme_fa64:
 133
 134         orr     x1, x1, #SMCR_ELx_LEN_MASK      // Enable full SME vector
 135         msr_s   SYS_SMCR_EL2, x1                // length for EL1.
 136
 137         mrs_s   x1, SYS_SMIDR_EL1               // Priority mapping supported?
 138         ubfx    x1, x1, #SMIDR_EL1_SMPS_SHIFT, #1
 139         cbz     x1, .Lskip_sme
 140
 141         msr_s   SYS_SMPRIMAP_EL2, xzr           // Make all priorities equal
 142
 143         mrs     x1, id_aa64mmfr1_el1            // HCRX_EL2 present?
 144         ubfx    x1, x1, #ID_AA64MMFR1_HCX_SHIFT, #4
 145         cbz     x1, .Lskip_sme
 146
 147         mrs_s   x1, SYS_HCRX_EL2
 148         orr     x1, x1, #HCRX_EL2_SMPME_MASK    // Enable priority mapping
 149         msr_s   SYS_HCRX_EL2, x1
 150
 151 .Lskip_sme:
 152
 153         // nVHE? No way! Give me the real thing!
 154         // Sanity check: MMU *must* be off
 155         mrs     x1, sctlr_el2
 156         tbnz    x1, #0, 1f
 157
 158         // Needs to be VHE capable, obviously
 159         check_override id_aa64mmfr1 ID_AA64MMFR1_VHE_SHIFT 2f 1f
 160
 161 1:      mov_q   x0, HVC_STUB_ERR
 162         eret
 163 2:
 164         // Engage the VHE magic!
 165         mov_q   x0, HCR_HOST_VHE_FLAGS
 166         msr     hcr_el2, x0
 167         isb
 168
 169         // Use the EL1 allocated stack, per-cpu offset
 170         mrs     x0, sp_el1
 171         mov     sp, x0
 172         mrs     x0, tpidr_el1
 173         msr     tpidr_el2, x0
 174
 175         // FP configuration, vectors
 176         mrs_s   x0, SYS_CPACR_EL12
 177         msr     cpacr_el1, x0
 178         mrs_s   x0, SYS_VBAR_EL12
 179         msr     vbar_el1, x0
 180
 181         // Use EL2 translations for SPE & TRBE and disable access from EL1
 182         mrs     x0, mdcr_el2
 183         bic     x0, x0, #(MDCR_EL2_E2PB_MASK << MDCR_EL2_E2PB_SHIFT)
 184         bic     x0, x0, #(MDCR_EL2_E2TB_MASK << MDCR_EL2_E2TB_SHIFT)
 185         msr     mdcr_el2, x0
 186
 187         // Transfer the MM state from EL1 to EL2
 188         mrs_s   x0, SYS_TCR_EL12
 189         msr     tcr_el1, x0
 190         mrs_s   x0, SYS_TTBR0_EL12
 191         msr     ttbr0_el1, x0
 192         mrs_s   x0, SYS_TTBR1_EL12
 193         msr     ttbr1_el1, x0
 194         mrs_s   x0, SYS_MAIR_EL12
 195         msr     mair_el1, x0
 196         isb
 197
 198         // Hack the exception return to stay at EL2
 199         mrs     x0, spsr_el1
 200         and     x0, x0, #~PSR_MODE_MASK
 201         mov     x1, #PSR_MODE_EL2h
 202         orr     x0, x0, x1
 203         msr     spsr_el1, x0
 204
 205         b       enter_vhe
 206 SYM_CODE_END(__finalise_el2)
 207
 208         // At the point where we reach enter_vhe(), we run with
 209         // the MMU off (which is enforced by __finalise_el2()).
 210         // We thus need to be in the idmap, or everything will
 211         // explode when enabling the MMU.
 212
 213         .pushsection    .idmap.text, "ax"
 214
 215 SYM_CODE_START_LOCAL(enter_vhe)
 216         // Invalidate TLBs before enabling the MMU
 217         tlbi    vmalle1
 218         dsb     nsh
 219         isb
 220
 221         // Enable the EL2 S1 MMU, as set up from EL1
 222         mrs_s   x0, SYS_SCTLR_EL12
 223         set_sctlr_el1   x0
 224
 225         // Disable the EL1 S1 MMU for a good measure
 226         mov_q   x0, INIT_SCTLR_EL1_MMU_OFF
 227         msr_s   SYS_SCTLR_EL12, x0
 228
 229         mov     x0, xzr
 230
 231         eret
 232 SYM_CODE_END(enter_vhe)
 233
 234         .popsection
 235
 236 .macro invalid_vector   label
 237 SYM_CODE_START_LOCAL(\label)
 238         b \label
 239 SYM_CODE_END(\label)
 240 .endm
 241
 242         invalid_vector  el2_sync_invalid
 243         invalid_vector  el2_irq_invalid
 244         invalid_vector  el2_fiq_invalid
 245         invalid_vector  el2_error_invalid
 246         invalid_vector  el1_sync_invalid
 247         invalid_vector  el1_irq_invalid
 248         invalid_vector  el1_fiq_invalid
 249         invalid_vector  el1_error_invalid
 250
 251         .popsection
 252
 253 /*
 254  * __hyp_set_vectors: Call this after boot to set the initial hypervisor
 255  * vectors as part of hypervisor installation.  On an SMP system, this should
 256  * be called on each CPU.
 257  *
 258  * x0 must be the physical address of the new vector table, and must be
 259  * 2KB aligned.
 260  *
 261  * Before calling this, you must check that the stub hypervisor is installed
 262  * everywhere, by waiting for any secondary CPUs to be brought up and then
 263  * checking that is_hyp_mode_available() is true.
 264  *
 265  * If not, there is a pre-existing hypervisor, some CPUs failed to boot, or
 266  * something else went wrong... in such cases, trying to install a new
 267  * hypervisor is unlikely to work as desired.
 268  *
 269  * When you call into your shiny new hypervisor, sp_el2 will contain junk,
 270  * so you will need to set that to something sensible at the new hypervisor's
 271  * initialisation entry point.
 272  */
 273
 274 SYM_FUNC_START(__hyp_set_vectors)
 275         mov     x1, x0
 276         mov     x0, #HVC_SET_VECTORS
 277         hvc     #0
 278         ret
 279 SYM_FUNC_END(__hyp_set_vectors)
 280
 281 SYM_FUNC_START(__hyp_reset_vectors)
 282         mov     x0, #HVC_RESET_VECTORS
 283         hvc     #0
 284         ret
 285 SYM_FUNC_END(__hyp_reset_vectors)
 286
 287 /*
 288  * Entry point to finalise EL2 and switch to VHE if deemed capable
 289  *
 290  * w0: boot mode, as returned by init_kernel_el()
 291  */
 292 SYM_FUNC_START(finalise_el2)
 293         // Need to have booted at EL2
 294         cmp     w0, #BOOT_CPU_MODE_EL2
 295         b.ne    1f
 296
 297         // and still be at EL1
 298         mrs     x0, CurrentEL
 299         cmp     x0, #CurrentEL_EL1
 300         b.ne    1f
 301
 302         mov     x0, #HVC_FINALISE_EL2
 303         hvc     #0
 304 1:
 305         ret
 306 SYM_FUNC_END(finalise_el2)