arch/arm64/kernel/entry.S

   1 /* SPDX-License-Identifier: GPL-2.0-only */
   2 /*
   3  * Low-level exception handling code
   4  *
   5  * Copyright (C) 2012 ARM Ltd.
   6  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   7  *              Will Deacon <will.deacon@arm.com>
   8  */
   9
  10 #include <linux/arm-smccc.h>
  11 #include <linux/init.h>
  12 #include <linux/linkage.h>
  13
  14 #include <asm/alternative.h>
  15 #include <asm/assembler.h>
  16 #include <asm/asm-offsets.h>
  17 #include <asm/asm_pointer_auth.h>
  18 #include <asm/bug.h>
  19 #include <asm/cpufeature.h>
  20 #include <asm/errno.h>
  21 #include <asm/esr.h>
  22 #include <asm/irq.h>
  23 #include <asm/memory.h>
  24 #include <asm/mmu.h>
  25 #include <asm/processor.h>
  26 #include <asm/ptrace.h>
  27 #include <asm/scs.h>
  28 #include <asm/thread_info.h>
  29 #include <asm/asm-uaccess.h>
  30 #include <asm/unistd.h>
  31
  32 /*
  33  * Context tracking subsystem.  Used to instrument transitions
  34  * between user and kernel mode.
  35  */
  36         .macro ct_user_exit_irqoff
  37 #ifdef CONFIG_CONTEXT_TRACKING
  38         bl      enter_from_user_mode
  39 #endif
  40         .endm
  41
  42         .macro ct_user_enter
  43 #ifdef CONFIG_CONTEXT_TRACKING
  44         bl      context_tracking_user_enter
  45 #endif
  46         .endm
  47
  48         .macro  clear_gp_regs
  49         .irp    n,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29
  50         mov     x\n, xzr
  51         .endr
  52         .endm
  53
  54 /*
  55  * Bad Abort numbers
  56  *-----------------
  57  */
  58 #define BAD_SYNC        0
  59 #define BAD_IRQ         1
  60 #define BAD_FIQ         2
  61 #define BAD_ERROR       3
  62
  63         .macro kernel_ventry, el, label, regsize = 64
  64         .align 7
  65 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
  66         .if     \el == 0
  67 alternative_if ARM64_UNMAP_KERNEL_AT_EL0
  68         .if     \regsize == 64
  69         mrs     x30, tpidrro_el0
  70         msr     tpidrro_el0, xzr
  71         .else
  72         mov     x30, xzr
  73         .endif
  74 alternative_else_nop_endif
  75         .endif
  76 #endif
  77
  78         sub     sp, sp, #S_FRAME_SIZE
  79 #ifdef CONFIG_VMAP_STACK
  80         /*
  81          * Test whether the SP has overflowed, without corrupting a GPR.
  82          * Task and IRQ stacks are aligned so that SP & (1 << THREAD_SHIFT)
  83          * should always be zero.
  84          */
  85         add     sp, sp, x0                      // sp' = sp + x0
  86         sub     x0, sp, x0                      // x0' = sp' - x0 = (sp + x0) - x0 = sp
  87         tbnz    x0, #THREAD_SHIFT, 0f
  88         sub     x0, sp, x0                      // x0'' = sp' - x0' = (sp + x0) - sp = x0
  89         sub     sp, sp, x0                      // sp'' = sp' - x0 = (sp + x0) - x0 = sp
  90         b       el\()\el\()_\label
  91
  92 0:
  93         /*
  94          * Either we've just detected an overflow, or we've taken an exception
  95          * while on the overflow stack. Either way, we won't return to
  96          * userspace, and can clobber EL0 registers to free up GPRs.
  97          */
  98
  99         /* Stash the original SP (minus S_FRAME_SIZE) in tpidr_el0. */
 100         msr     tpidr_el0, x0
 101
 102         /* Recover the original x0 value and stash it in tpidrro_el0 */
 103         sub     x0, sp, x0
 104         msr     tpidrro_el0, x0
 105
 106         /* Switch to the overflow stack */
 107         adr_this_cpu sp, overflow_stack + OVERFLOW_STACK_SIZE, x0
 108
 109         /*
 110          * Check whether we were already on the overflow stack. This may happen
 111          * after panic() re-enables interrupts.
 112          */
 113         mrs     x0, tpidr_el0                   // sp of interrupted context
 114         sub     x0, sp, x0                      // delta with top of overflow stack
 115         tst     x0, #~(OVERFLOW_STACK_SIZE - 1) // within range?
 116         b.ne    __bad_stack                     // no? -> bad stack pointer
 117
 118         /* We were already on the overflow stack. Restore sp/x0 and carry on. */
 119         sub     sp, sp, x0
 120         mrs     x0, tpidrro_el0
 121 #endif
 122         b       el\()\el\()_\label
 123         .endm
 124
 125         .macro tramp_alias, dst, sym
 126         mov_q   \dst, TRAMP_VALIAS
 127         add     \dst, \dst, #(\sym - .entry.tramp.text)
 128         .endm
 129
 130         /*
 131          * This macro corrupts x0-x3. It is the caller's duty  to save/restore
 132          * them if required.
 133          */
 134         .macro  apply_ssbd, state, tmp1, tmp2
 135 alternative_cb  spectre_v4_patch_fw_mitigation_enable
 136         b       .L__asm_ssbd_skip\@             // Patched to NOP
 137 alternative_cb_end
 138         ldr_this_cpu    \tmp2, arm64_ssbd_callback_required, \tmp1
 139         cbz     \tmp2,  .L__asm_ssbd_skip\@
 140         ldr     \tmp2, [tsk, #TSK_TI_FLAGS]
 141         tbnz    \tmp2, #TIF_SSBD, .L__asm_ssbd_skip\@
 142         mov     w0, #ARM_SMCCC_ARCH_WORKAROUND_2
 143         mov     w1, #\state
 144 alternative_cb  spectre_v4_patch_fw_mitigation_conduit
 145         nop                                     // Patched to SMC/HVC #0
 146 alternative_cb_end
 147 .L__asm_ssbd_skip\@:
 148         .endm
 149
 150         /* Check for MTE asynchronous tag check faults */
 151         .macro check_mte_async_tcf, flgs, tmp
 152 #ifdef CONFIG_ARM64_MTE
 153 alternative_if_not ARM64_MTE
 154         b       1f
 155 alternative_else_nop_endif
 156         mrs_s   \tmp, SYS_TFSRE0_EL1
 157         tbz     \tmp, #SYS_TFSR_EL1_TF0_SHIFT, 1f
 158         /* Asynchronous TCF occurred for TTBR0 access, set the TI flag */
 159         orr     \flgs, \flgs, #_TIF_MTE_ASYNC_FAULT
 160         str     \flgs, [tsk, #TSK_TI_FLAGS]
 161         msr_s   SYS_TFSRE0_EL1, xzr
 162 1:
 163 #endif
 164         .endm
 165
 166         /* Clear the MTE asynchronous tag check faults */
 167         .macro clear_mte_async_tcf
 168 #ifdef CONFIG_ARM64_MTE
 169 alternative_if ARM64_MTE
 170         dsb     ish
 171         msr_s   SYS_TFSRE0_EL1, xzr
 172 alternative_else_nop_endif
 173 #endif
 174         .endm
 175
 176         .macro  kernel_entry, el, regsize = 64
 177         .if     \regsize == 32
 178         mov     w0, w0                          // zero upper 32 bits of x0
 179         .endif
 180         stp     x0, x1, [sp, #16 * 0]
 181         stp     x2, x3, [sp, #16 * 1]
 182         stp     x4, x5, [sp, #16 * 2]
 183         stp     x6, x7, [sp, #16 * 3]
 184         stp     x8, x9, [sp, #16 * 4]
 185         stp     x10, x11, [sp, #16 * 5]
 186         stp     x12, x13, [sp, #16 * 6]
 187         stp     x14, x15, [sp, #16 * 7]
 188         stp     x16, x17, [sp, #16 * 8]
 189         stp     x18, x19, [sp, #16 * 9]
 190         stp     x20, x21, [sp, #16 * 10]
 191         stp     x22, x23, [sp, #16 * 11]
 192         stp     x24, x25, [sp, #16 * 12]
 193         stp     x26, x27, [sp, #16 * 13]
 194         stp     x28, x29, [sp, #16 * 14]
 195
 196         .if     \el == 0
 197         clear_gp_regs
 198         mrs     x21, sp_el0
 199         ldr_this_cpu    tsk, __entry_task, x20
 200         msr     sp_el0, tsk
 201
 202         /*
 203          * Ensure MDSCR_EL1.SS is clear, since we can unmask debug exceptions
 204          * when scheduling.
 205          */
 206         ldr     x19, [tsk, #TSK_TI_FLAGS]
 207         disable_step_tsk x19, x20
 208
 209         /* Check for asynchronous tag check faults in user space */
 210         check_mte_async_tcf x19, x22
 211         apply_ssbd 1, x22, x23
 212
 213         ptrauth_keys_install_kernel tsk, x20, x22, x23
 214
 215         scs_load tsk, x20
 216         .else
 217         add     x21, sp, #S_FRAME_SIZE
 218         get_current_task tsk
 219         /* Save the task's original addr_limit and set USER_DS */
 220         ldr     x20, [tsk, #TSK_TI_ADDR_LIMIT]
 221         str     x20, [sp, #S_ORIG_ADDR_LIMIT]
 222         mov     x20, #USER_DS
 223         str     x20, [tsk, #TSK_TI_ADDR_LIMIT]
 224         /* No need to reset PSTATE.UAO, hardware's already set it to 0 for us */
 225         .endif /* \el == 0 */
 226         mrs     x22, elr_el1
 227         mrs     x23, spsr_el1
 228         stp     lr, x21, [sp, #S_LR]
 229
 230         /*
 231          * In order to be able to dump the contents of struct pt_regs at the
 232          * time the exception was taken (in case we attempt to walk the call
 233          * stack later), chain it together with the stack frames.
 234          */
 235         .if \el == 0
 236         stp     xzr, xzr, [sp, #S_STACKFRAME]
 237         .else
 238         stp     x29, x22, [sp, #S_STACKFRAME]
 239         .endif
 240         add     x29, sp, #S_STACKFRAME
 241
 242 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 243 alternative_if_not ARM64_HAS_PAN
 244         bl      __swpan_entry_el\el
 245 alternative_else_nop_endif
 246 #endif
 247
 248         stp     x22, x23, [sp, #S_PC]
 249
 250         /* Not in a syscall by default (el0_svc overwrites for real syscall) */
 251         .if     \el == 0
 252         mov     w21, #NO_SYSCALL
 253         str     w21, [sp, #S_SYSCALLNO]
 254         .endif
 255
 256         /* Save pmr */
 257 alternative_if ARM64_HAS_IRQ_PRIO_MASKING
 258         mrs_s   x20, SYS_ICC_PMR_EL1
 259         str     x20, [sp, #S_PMR_SAVE]
 260 alternative_else_nop_endif
 261
 262         /* Re-enable tag checking (TCO set on exception entry) */
 263 #ifdef CONFIG_ARM64_MTE
 264 alternative_if ARM64_MTE
 265         SET_PSTATE_TCO(0)
 266 alternative_else_nop_endif
 267 #endif
 268
 269         /*
 270          * Registers that may be useful after this macro is invoked:
 271          *
 272          * x20 - ICC_PMR_EL1
 273          * x21 - aborted SP
 274          * x22 - aborted PC
 275          * x23 - aborted PSTATE
 276         */
 277         .endm
 278
 279         .macro  kernel_exit, el
 280         .if     \el != 0
 281         disable_daif
 282
 283         /* Restore the task's original addr_limit. */
 284         ldr     x20, [sp, #S_ORIG_ADDR_LIMIT]
 285         str     x20, [tsk, #TSK_TI_ADDR_LIMIT]
 286
 287         /* No need to restore UAO, it will be restored from SPSR_EL1 */
 288         .endif
 289
 290         /* Restore pmr */
 291 alternative_if ARM64_HAS_IRQ_PRIO_MASKING
 292         ldr     x20, [sp, #S_PMR_SAVE]
 293         msr_s   SYS_ICC_PMR_EL1, x20
 294         mrs_s   x21, SYS_ICC_CTLR_EL1
 295         tbz     x21, #6, .L__skip_pmr_sync\@    // Check for ICC_CTLR_EL1.PMHE
 296         dsb     sy                              // Ensure priority change is seen by redistributor
 297 .L__skip_pmr_sync\@:
 298 alternative_else_nop_endif
 299
 300         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 301         .if     \el == 0
 302         ct_user_enter
 303         .endif
 304
 305 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 306 alternative_if_not ARM64_HAS_PAN
 307         bl      __swpan_exit_el\el
 308 alternative_else_nop_endif
 309 #endif
 310
 311         .if     \el == 0
 312         ldr     x23, [sp, #S_SP]                // load return stack pointer
 313         msr     sp_el0, x23
 314         tst     x22, #PSR_MODE32_BIT            // native task?
 315         b.eq    3f
 316
 317 #ifdef CONFIG_ARM64_ERRATUM_845719
 318 alternative_if ARM64_WORKAROUND_845719
 319 #ifdef CONFIG_PID_IN_CONTEXTIDR
 320         mrs     x29, contextidr_el1
 321         msr     contextidr_el1, x29
 322 #else
 323         msr contextidr_el1, xzr
 324 #endif
 325 alternative_else_nop_endif
 326 #endif
 327 3:
 328         scs_save tsk, x0
 329
 330         /* No kernel C function calls after this as user keys are set. */
 331         ptrauth_keys_install_user tsk, x0, x1, x2
 332
 333         apply_ssbd 0, x0, x1
 334         .endif
 335
 336         msr     elr_el1, x21                    // set up the return data
 337         msr     spsr_el1, x22
 338         ldp     x0, x1, [sp, #16 * 0]
 339         ldp     x2, x3, [sp, #16 * 1]
 340         ldp     x4, x5, [sp, #16 * 2]
 341         ldp     x6, x7, [sp, #16 * 3]
 342         ldp     x8, x9, [sp, #16 * 4]
 343         ldp     x10, x11, [sp, #16 * 5]
 344         ldp     x12, x13, [sp, #16 * 6]
 345         ldp     x14, x15, [sp, #16 * 7]
 346         ldp     x16, x17, [sp, #16 * 8]
 347         ldp     x18, x19, [sp, #16 * 9]
 348         ldp     x20, x21, [sp, #16 * 10]
 349         ldp     x22, x23, [sp, #16 * 11]
 350         ldp     x24, x25, [sp, #16 * 12]
 351         ldp     x26, x27, [sp, #16 * 13]
 352         ldp     x28, x29, [sp, #16 * 14]
 353         ldr     lr, [sp, #S_LR]
 354         add     sp, sp, #S_FRAME_SIZE           // restore sp
 355
 356         .if     \el == 0
 357 alternative_insn eret, nop, ARM64_UNMAP_KERNEL_AT_EL0
 358 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 359         bne     4f
 360         msr     far_el1, x30
 361         tramp_alias     x30, tramp_exit_native
 362         br      x30
 363 4:
 364         tramp_alias     x30, tramp_exit_compat
 365         br      x30
 366 #endif
 367         .else
 368         /* Ensure any device/NC reads complete */
 369         alternative_insn nop, "dmb sy", ARM64_WORKAROUND_1508412
 370
 371         eret
 372         .endif
 373         sb
 374         .endm
 375
 376 #ifdef CONFIG_ARM64_SW_TTBR0_PAN
 377         /*
 378          * Set the TTBR0 PAN bit in SPSR. When the exception is taken from
 379          * EL0, there is no need to check the state of TTBR0_EL1 since
 380          * accesses are always enabled.
 381          * Note that the meaning of this bit differs from the ARMv8.1 PAN
 382          * feature as all TTBR0_EL1 accesses are disabled, not just those to
 383          * user mappings.
 384          */
 385 SYM_CODE_START_LOCAL(__swpan_entry_el1)
 386         mrs     x21, ttbr0_el1
 387         tst     x21, #TTBR_ASID_MASK            // Check for the reserved ASID
 388         orr     x23, x23, #PSR_PAN_BIT          // Set the emulated PAN in the saved SPSR
 389         b.eq    1f                              // TTBR0 access already disabled
 390         and     x23, x23, #~PSR_PAN_BIT         // Clear the emulated PAN in the saved SPSR
 391 SYM_INNER_LABEL(__swpan_entry_el0, SYM_L_LOCAL)
 392         __uaccess_ttbr0_disable x21
 393 1:      ret
 394 SYM_CODE_END(__swpan_entry_el1)
 395
 396         /*
 397          * Restore access to TTBR0_EL1. If returning to EL0, no need for SPSR
 398          * PAN bit checking.
 399          */
 400 SYM_CODE_START_LOCAL(__swpan_exit_el1)
 401         tbnz    x22, #22, 1f                    // Skip re-enabling TTBR0 access if the PSR_PAN_BIT is set
 402         __uaccess_ttbr0_enable x0, x1
 403 1:      and     x22, x22, #~PSR_PAN_BIT         // ARMv8.0 CPUs do not understand this bit
 404         ret
 405 SYM_CODE_END(__swpan_exit_el1)
 406
 407 SYM_CODE_START_LOCAL(__swpan_exit_el0)
 408         __uaccess_ttbr0_enable x0, x1
 409         /*
 410          * Enable errata workarounds only if returning to user. The only
 411          * workaround currently required for TTBR0_EL1 changes are for the
 412          * Cavium erratum 27456 (broadcast TLBI instructions may cause I-cache
 413          * corruption).
 414          */
 415         b       post_ttbr_update_workaround
 416 SYM_CODE_END(__swpan_exit_el0)
 417 #endif
 418
 419         .macro  irq_stack_entry
 420         mov     x19, sp                 // preserve the original sp
 421 #ifdef CONFIG_SHADOW_CALL_STACK
 422         mov     x24, scs_sp             // preserve the original shadow stack
 423 #endif
 424
 425         /*
 426          * Compare sp with the base of the task stack.
 427          * If the top ~(THREAD_SIZE - 1) bits match, we are on a task stack,
 428          * and should switch to the irq stack.
 429          */
 430         ldr     x25, [tsk, TSK_STACK]
 431         eor     x25, x25, x19
 432         and     x25, x25, #~(THREAD_SIZE - 1)
 433         cbnz    x25, 9998f
 434
 435         ldr_this_cpu x25, irq_stack_ptr, x26
 436         mov     x26, #IRQ_STACK_SIZE
 437         add     x26, x25, x26
 438
 439         /* switch to the irq stack */
 440         mov     sp, x26
 441
 442 #ifdef CONFIG_SHADOW_CALL_STACK
 443         /* also switch to the irq shadow stack */
 444         adr_this_cpu scs_sp, irq_shadow_call_stack, x26
 445 #endif
 446
 447 9998:
 448         .endm
 449
 450         /*
 451          * The callee-saved regs (x19-x29) should be preserved between
 452          * irq_stack_entry and irq_stack_exit, but note that kernel_entry
 453          * uses x20-x23 to store data for later use.
 454          */
 455         .macro  irq_stack_exit
 456         mov     sp, x19
 457 #ifdef CONFIG_SHADOW_CALL_STACK
 458         mov     scs_sp, x24
 459 #endif
 460         .endm
 461
 462 /* GPRs used by entry code */
 463 tsk     .req    x28             // current thread_info
 464
 465 /*
 466  * Interrupt handling.
 467  */
 468         .macro  irq_handler
 469         ldr_l   x1, handle_arch_irq
 470         mov     x0, sp
 471         irq_stack_entry
 472         blr     x1
 473         irq_stack_exit
 474         .endm
 475
 476 #ifdef CONFIG_ARM64_PSEUDO_NMI
 477         /*
 478          * Set res to 0 if irqs were unmasked in interrupted context.
 479          * Otherwise set res to non-0 value.
 480          */
 481         .macro  test_irqs_unmasked res:req, pmr:req
 482 alternative_if ARM64_HAS_IRQ_PRIO_MASKING
 483         sub     \res, \pmr, #GIC_PRIO_IRQON
 484 alternative_else
 485         mov     \res, xzr
 486 alternative_endif
 487         .endm
 488 #endif
 489
 490         .macro  gic_prio_kentry_setup, tmp:req
 491 #ifdef CONFIG_ARM64_PSEUDO_NMI
 492         alternative_if ARM64_HAS_IRQ_PRIO_MASKING
 493         mov     \tmp, #(GIC_PRIO_PSR_I_SET | GIC_PRIO_IRQON)
 494         msr_s   SYS_ICC_PMR_EL1, \tmp
 495         alternative_else_nop_endif
 496 #endif
 497         .endm
 498
 499         .macro  gic_prio_irq_setup, pmr:req, tmp:req
 500 #ifdef CONFIG_ARM64_PSEUDO_NMI
 501         alternative_if ARM64_HAS_IRQ_PRIO_MASKING
 502         orr     \tmp, \pmr, #GIC_PRIO_PSR_I_SET
 503         msr_s   SYS_ICC_PMR_EL1, \tmp
 504         alternative_else_nop_endif
 505 #endif
 506         .endm
 507
 508         .text
 509
 510 /*
 511  * Exception vectors.
 512  */
 513         .pushsection ".entry.text", "ax"
 514
 515         .align  11
 516 SYM_CODE_START(vectors)
 517         kernel_ventry   1, sync_invalid                 // Synchronous EL1t
 518         kernel_ventry   1, irq_invalid                  // IRQ EL1t
 519         kernel_ventry   1, fiq_invalid                  // FIQ EL1t
 520         kernel_ventry   1, error_invalid                // Error EL1t
 521
 522         kernel_ventry   1, sync                         // Synchronous EL1h
 523         kernel_ventry   1, irq                          // IRQ EL1h
 524         kernel_ventry   1, fiq_invalid                  // FIQ EL1h
 525         kernel_ventry   1, error                        // Error EL1h
 526
 527         kernel_ventry   0, sync                         // Synchronous 64-bit EL0
 528         kernel_ventry   0, irq                          // IRQ 64-bit EL0
 529         kernel_ventry   0, fiq_invalid                  // FIQ 64-bit EL0
 530         kernel_ventry   0, error                        // Error 64-bit EL0
 531
 532 #ifdef CONFIG_COMPAT
 533         kernel_ventry   0, sync_compat, 32              // Synchronous 32-bit EL0
 534         kernel_ventry   0, irq_compat, 32               // IRQ 32-bit EL0
 535         kernel_ventry   0, fiq_invalid_compat, 32       // FIQ 32-bit EL0
 536         kernel_ventry   0, error_compat, 32             // Error 32-bit EL0
 537 #else
 538         kernel_ventry   0, sync_invalid, 32             // Synchronous 32-bit EL0
 539         kernel_ventry   0, irq_invalid, 32              // IRQ 32-bit EL0
 540         kernel_ventry   0, fiq_invalid, 32              // FIQ 32-bit EL0
 541         kernel_ventry   0, error_invalid, 32            // Error 32-bit EL0
 542 #endif
 543 SYM_CODE_END(vectors)
 544
 545 #ifdef CONFIG_VMAP_STACK
 546         /*
 547          * We detected an overflow in kernel_ventry, which switched to the
 548          * overflow stack. Stash the exception regs, and head to our overflow
 549          * handler.
 550          */
 551 __bad_stack:
 552         /* Restore the original x0 value */
 553         mrs     x0, tpidrro_el0
 554
 555         /*
 556          * Store the original GPRs to the new stack. The orginal SP (minus
 557          * S_FRAME_SIZE) was stashed in tpidr_el0 by kernel_ventry.
 558          */
 559         sub     sp, sp, #S_FRAME_SIZE
 560         kernel_entry 1
 561         mrs     x0, tpidr_el0
 562         add     x0, x0, #S_FRAME_SIZE
 563         str     x0, [sp, #S_SP]
 564
 565         /* Stash the regs for handle_bad_stack */
 566         mov     x0, sp
 567
 568         /* Time to die */
 569         bl      handle_bad_stack
 570         ASM_BUG()
 571 #endif /* CONFIG_VMAP_STACK */
 572
 573 /*
 574  * Invalid mode handlers
 575  */
 576         .macro  inv_entry, el, reason, regsize = 64
 577         kernel_entry \el, \regsize
 578         mov     x0, sp
 579         mov     x1, #\reason
 580         mrs     x2, esr_el1
 581         bl      bad_mode
 582         ASM_BUG()
 583         .endm
 584
 585 SYM_CODE_START_LOCAL(el0_sync_invalid)
 586         inv_entry 0, BAD_SYNC
 587 SYM_CODE_END(el0_sync_invalid)
 588
 589 SYM_CODE_START_LOCAL(el0_irq_invalid)
 590         inv_entry 0, BAD_IRQ
 591 SYM_CODE_END(el0_irq_invalid)
 592
 593 SYM_CODE_START_LOCAL(el0_fiq_invalid)
 594         inv_entry 0, BAD_FIQ
 595 SYM_CODE_END(el0_fiq_invalid)
 596
 597 SYM_CODE_START_LOCAL(el0_error_invalid)
 598         inv_entry 0, BAD_ERROR
 599 SYM_CODE_END(el0_error_invalid)
 600
 601 #ifdef CONFIG_COMPAT
 602 SYM_CODE_START_LOCAL(el0_fiq_invalid_compat)
 603         inv_entry 0, BAD_FIQ, 32
 604 SYM_CODE_END(el0_fiq_invalid_compat)
 605 #endif
 606
 607 SYM_CODE_START_LOCAL(el1_sync_invalid)
 608         inv_entry 1, BAD_SYNC
 609 SYM_CODE_END(el1_sync_invalid)
 610
 611 SYM_CODE_START_LOCAL(el1_irq_invalid)
 612         inv_entry 1, BAD_IRQ
 613 SYM_CODE_END(el1_irq_invalid)
 614
 615 SYM_CODE_START_LOCAL(el1_fiq_invalid)
 616         inv_entry 1, BAD_FIQ
 617 SYM_CODE_END(el1_fiq_invalid)
 618
 619 SYM_CODE_START_LOCAL(el1_error_invalid)
 620         inv_entry 1, BAD_ERROR
 621 SYM_CODE_END(el1_error_invalid)
 622
 623 /*
 624  * EL1 mode handlers.
 625  */
 626         .align  6
 627 SYM_CODE_START_LOCAL_NOALIGN(el1_sync)
 628         kernel_entry 1
 629         mov     x0, sp
 630         bl      el1_sync_handler
 631         kernel_exit 1
 632 SYM_CODE_END(el1_sync)
 633
 634         .align  6
 635 SYM_CODE_START_LOCAL_NOALIGN(el1_irq)
 636         kernel_entry 1
 637         gic_prio_irq_setup pmr=x20, tmp=x1
 638         enable_da_f
 639
 640         mov     x0, sp
 641         bl      enter_el1_irq_or_nmi
 642
 643         irq_handler
 644
 645 #ifdef CONFIG_PREEMPTION
 646         ldr     x24, [tsk, #TSK_TI_PREEMPT]     // get preempt count
 647 alternative_if ARM64_HAS_IRQ_PRIO_MASKING
 648         /*
 649          * DA_F were cleared at start of handling. If anything is set in DAIF,
 650          * we come back from an NMI, so skip preemption
 651          */
 652         mrs     x0, daif
 653         orr     x24, x24, x0
 654 alternative_else_nop_endif
 655         cbnz    x24, 1f                         // preempt count != 0 || NMI return path
 656         bl      arm64_preempt_schedule_irq      // irq en/disable is done inside
 657 1:
 658 #endif
 659
 660         mov     x0, sp
 661         bl      exit_el1_irq_or_nmi
 662
 663         kernel_exit 1
 664 SYM_CODE_END(el1_irq)
 665
 666 /*
 667  * EL0 mode handlers.
 668  */
 669         .align  6
 670 SYM_CODE_START_LOCAL_NOALIGN(el0_sync)
 671         kernel_entry 0
 672         mov     x0, sp
 673         bl      el0_sync_handler
 674         b       ret_to_user
 675 SYM_CODE_END(el0_sync)
 676
 677 #ifdef CONFIG_COMPAT
 678         .align  6
 679 SYM_CODE_START_LOCAL_NOALIGN(el0_sync_compat)
 680         kernel_entry 0, 32
 681         mov     x0, sp
 682         bl      el0_sync_compat_handler
 683         b       ret_to_user
 684 SYM_CODE_END(el0_sync_compat)
 685
 686         .align  6
 687 SYM_CODE_START_LOCAL_NOALIGN(el0_irq_compat)
 688         kernel_entry 0, 32
 689         b       el0_irq_naked
 690 SYM_CODE_END(el0_irq_compat)
 691
 692 SYM_CODE_START_LOCAL_NOALIGN(el0_error_compat)
 693         kernel_entry 0, 32
 694         b       el0_error_naked
 695 SYM_CODE_END(el0_error_compat)
 696 #endif
 697
 698         .align  6
 699 SYM_CODE_START_LOCAL_NOALIGN(el0_irq)
 700         kernel_entry 0
 701 el0_irq_naked:
 702         gic_prio_irq_setup pmr=x20, tmp=x0
 703         ct_user_exit_irqoff
 704         enable_da_f
 705
 706 #ifdef CONFIG_TRACE_IRQFLAGS
 707         bl      trace_hardirqs_off
 708 #endif
 709
 710         tbz     x22, #55, 1f
 711         bl      do_el0_irq_bp_hardening
 712 1:
 713         irq_handler
 714
 715 #ifdef CONFIG_TRACE_IRQFLAGS
 716         bl      trace_hardirqs_on
 717 #endif
 718         b       ret_to_user
 719 SYM_CODE_END(el0_irq)
 720
 721 SYM_CODE_START_LOCAL(el1_error)
 722         kernel_entry 1
 723         mrs     x1, esr_el1
 724         gic_prio_kentry_setup tmp=x2
 725         enable_dbg
 726         mov     x0, sp
 727         bl      do_serror
 728         kernel_exit 1
 729 SYM_CODE_END(el1_error)
 730
 731 SYM_CODE_START_LOCAL(el0_error)
 732         kernel_entry 0
 733 el0_error_naked:
 734         mrs     x25, esr_el1
 735         gic_prio_kentry_setup tmp=x2
 736         ct_user_exit_irqoff
 737         enable_dbg
 738         mov     x0, sp
 739         mov     x1, x25
 740         bl      do_serror
 741         enable_da_f
 742         b       ret_to_user
 743 SYM_CODE_END(el0_error)
 744
 745 /*
 746  * "slow" syscall return path.
 747  */
 748 SYM_CODE_START_LOCAL(ret_to_user)
 749         disable_daif
 750         gic_prio_kentry_setup tmp=x3
 751         ldr     x19, [tsk, #TSK_TI_FLAGS]
 752         and     x2, x19, #_TIF_WORK_MASK
 753         cbnz    x2, work_pending
 754 finish_ret_to_user:
 755         /* Ignore asynchronous tag check faults in the uaccess routines */
 756         clear_mte_async_tcf
 757         enable_step_tsk x19, x2
 758 #ifdef CONFIG_GCC_PLUGIN_STACKLEAK
 759         bl      stackleak_erase
 760 #endif
 761         kernel_exit 0
 762
 763 /*
 764  * Ok, we need to do extra processing, enter the slow path.
 765  */
 766 work_pending:
 767         mov     x0, sp                          // 'regs'
 768         mov     x1, x19
 769         bl      do_notify_resume
 770 #ifdef CONFIG_TRACE_IRQFLAGS
 771         bl      trace_hardirqs_on               // enabled while in userspace
 772 #endif
 773         ldr     x19, [tsk, #TSK_TI_FLAGS]       // re-check for single-step
 774         b       finish_ret_to_user
 775 SYM_CODE_END(ret_to_user)
 776
 777         .popsection                             // .entry.text
 778
 779 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 780 /*
 781  * Exception vectors trampoline.
 782  */
 783         .pushsection ".entry.tramp.text", "ax"
 784
 785         .macro tramp_map_kernel, tmp
 786         mrs     \tmp, ttbr1_el1
 787         add     \tmp, \tmp, #(PAGE_SIZE + RESERVED_TTBR0_SIZE)
 788         bic     \tmp, \tmp, #USER_ASID_FLAG
 789         msr     ttbr1_el1, \tmp
 790 #ifdef CONFIG_QCOM_FALKOR_ERRATUM_1003
 791 alternative_if ARM64_WORKAROUND_QCOM_FALKOR_E1003
 792         /* ASID already in \tmp[63:48] */
 793         movk    \tmp, #:abs_g2_nc:(TRAMP_VALIAS >> 12)
 794         movk    \tmp, #:abs_g1_nc:(TRAMP_VALIAS >> 12)
 795         /* 2MB boundary containing the vectors, so we nobble the walk cache */
 796         movk    \tmp, #:abs_g0_nc:((TRAMP_VALIAS & ~(SZ_2M - 1)) >> 12)
 797         isb
 798         tlbi    vae1, \tmp
 799         dsb     nsh
 800 alternative_else_nop_endif
 801 #endif /* CONFIG_QCOM_FALKOR_ERRATUM_1003 */
 802         .endm
 803
 804         .macro tramp_unmap_kernel, tmp
 805         mrs     \tmp, ttbr1_el1
 806         sub     \tmp, \tmp, #(PAGE_SIZE + RESERVED_TTBR0_SIZE)
 807         orr     \tmp, \tmp, #USER_ASID_FLAG
 808         msr     ttbr1_el1, \tmp
 809         /*
 810          * We avoid running the post_ttbr_update_workaround here because
 811          * it's only needed by Cavium ThunderX, which requires KPTI to be
 812          * disabled.
 813          */
 814         .endm
 815
 816         .macro tramp_ventry, regsize = 64
 817         .align  7
 818 1:
 819         .if     \regsize == 64
 820         msr     tpidrro_el0, x30        // Restored in kernel_ventry
 821         .endif
 822         /*
 823          * Defend against branch aliasing attacks by pushing a dummy
 824          * entry onto the return stack and using a RET instruction to
 825          * enter the full-fat kernel vectors.
 826          */
 827         bl      2f
 828         b       .
 829 2:
 830         tramp_map_kernel        x30
 831 #ifdef CONFIG_RANDOMIZE_BASE
 832         adr     x30, tramp_vectors + PAGE_SIZE
 833 alternative_insn isb, nop, ARM64_WORKAROUND_QCOM_FALKOR_E1003
 834         ldr     x30, [x30]
 835 #else
 836         ldr     x30, =vectors
 837 #endif
 838 alternative_if_not ARM64_WORKAROUND_CAVIUM_TX2_219_PRFM
 839         prfm    plil1strm, [x30, #(1b - tramp_vectors)]
 840 alternative_else_nop_endif
 841         msr     vbar_el1, x30
 842         add     x30, x30, #(1b - tramp_vectors)
 843         isb
 844         ret
 845         .endm
 846
 847         .macro tramp_exit, regsize = 64
 848         adr     x30, tramp_vectors
 849         msr     vbar_el1, x30
 850         tramp_unmap_kernel      x30
 851         .if     \regsize == 64
 852         mrs     x30, far_el1
 853         .endif
 854         eret
 855         sb
 856         .endm
 857
 858         .align  11
 859 SYM_CODE_START_NOALIGN(tramp_vectors)
 860         .space  0x400
 861
 862         tramp_ventry
 863         tramp_ventry
 864         tramp_ventry
 865         tramp_ventry
 866
 867         tramp_ventry    32
 868         tramp_ventry    32
 869         tramp_ventry    32
 870         tramp_ventry    32
 871 SYM_CODE_END(tramp_vectors)
 872
 873 SYM_CODE_START(tramp_exit_native)
 874         tramp_exit
 875 SYM_CODE_END(tramp_exit_native)
 876
 877 SYM_CODE_START(tramp_exit_compat)
 878         tramp_exit      32
 879 SYM_CODE_END(tramp_exit_compat)
 880
 881         .ltorg
 882         .popsection                             // .entry.tramp.text
 883 #ifdef CONFIG_RANDOMIZE_BASE
 884         .pushsection ".rodata", "a"
 885         .align PAGE_SHIFT
 886 SYM_DATA_START(__entry_tramp_data_start)
 887         .quad   vectors
 888 SYM_DATA_END(__entry_tramp_data_start)
 889         .popsection                             // .rodata
 890 #endif /* CONFIG_RANDOMIZE_BASE */
 891 #endif /* CONFIG_UNMAP_KERNEL_AT_EL0 */
 892
 893 /*
 894  * Register switch for AArch64. The callee-saved registers need to be saved
 895  * and restored. On entry:
 896  *   x0 = previous task_struct (must be preserved across the switch)
 897  *   x1 = next task_struct
 898  * Previous and next are guaranteed not to be the same.
 899  *
 900  */
 901 SYM_FUNC_START(cpu_switch_to)
 902         mov     x10, #THREAD_CPU_CONTEXT
 903         add     x8, x0, x10
 904         mov     x9, sp
 905         stp     x19, x20, [x8], #16             // store callee-saved registers
 906         stp     x21, x22, [x8], #16
 907         stp     x23, x24, [x8], #16
 908         stp     x25, x26, [x8], #16
 909         stp     x27, x28, [x8], #16
 910         stp     x29, x9, [x8], #16
 911         str     lr, [x8]
 912         add     x8, x1, x10
 913         ldp     x19, x20, [x8], #16             // restore callee-saved registers
 914         ldp     x21, x22, [x8], #16
 915         ldp     x23, x24, [x8], #16
 916         ldp     x25, x26, [x8], #16
 917         ldp     x27, x28, [x8], #16
 918         ldp     x29, x9, [x8], #16
 919         ldr     lr, [x8]
 920         mov     sp, x9
 921         msr     sp_el0, x1
 922         ptrauth_keys_install_kernel x1, x8, x9, x10
 923         scs_save x0, x8
 924         scs_load x1, x8
 925         ret
 926 SYM_FUNC_END(cpu_switch_to)
 927 NOKPROBE(cpu_switch_to)
 928
 929 /*
 930  * This is how we return from a fork.
 931  */
 932 SYM_CODE_START(ret_from_fork)
 933         bl      schedule_tail
 934         cbz     x19, 1f                         // not a kernel thread
 935         mov     x0, x20
 936         blr     x19
 937 1:      get_current_task tsk
 938         b       ret_to_user
 939 SYM_CODE_END(ret_from_fork)
 940 NOKPROBE(ret_from_fork)
 941
 942 #ifdef CONFIG_ARM_SDE_INTERFACE
 943
 944 #include <asm/sdei.h>
 945 #include <uapi/linux/arm_sdei.h>
 946
 947 .macro sdei_handler_exit exit_mode
 948         /* On success, this call never returns... */
 949         cmp     \exit_mode, #SDEI_EXIT_SMC
 950         b.ne    99f
 951         smc     #0
 952         b       .
 953 99:     hvc     #0
 954         b       .
 955 .endm
 956
 957 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
 958 /*
 959  * The regular SDEI entry point may have been unmapped along with the rest of
 960  * the kernel. This trampoline restores the kernel mapping to make the x1 memory
 961  * argument accessible.
 962  *
 963  * This clobbers x4, __sdei_handler() will restore this from firmware's
 964  * copy.
 965  */
 966 .ltorg
 967 .pushsection ".entry.tramp.text", "ax"
 968 SYM_CODE_START(__sdei_asm_entry_trampoline)
 969         mrs     x4, ttbr1_el1
 970         tbz     x4, #USER_ASID_BIT, 1f
 971
 972         tramp_map_kernel tmp=x4
 973         isb
 974         mov     x4, xzr
 975
 976         /*
 977          * Use reg->interrupted_regs.addr_limit to remember whether to unmap
 978          * the kernel on exit.
 979          */
 980 1:      str     x4, [x1, #(SDEI_EVENT_INTREGS + S_ORIG_ADDR_LIMIT)]
 981
 982 #ifdef CONFIG_RANDOMIZE_BASE
 983         adr     x4, tramp_vectors + PAGE_SIZE
 984         add     x4, x4, #:lo12:__sdei_asm_trampoline_next_handler
 985         ldr     x4, [x4]
 986 #else
 987         ldr     x4, =__sdei_asm_handler
 988 #endif
 989         br      x4
 990 SYM_CODE_END(__sdei_asm_entry_trampoline)
 991 NOKPROBE(__sdei_asm_entry_trampoline)
 992
 993 /*
 994  * Make the exit call and restore the original ttbr1_el1
 995  *
 996  * x0 & x1: setup for the exit API call
 997  * x2: exit_mode
 998  * x4: struct sdei_registered_event argument from registration time.
 999  */
1000 SYM_CODE_START(__sdei_asm_exit_trampoline)
1001         ldr     x4, [x4, #(SDEI_EVENT_INTREGS + S_ORIG_ADDR_LIMIT)]
1002         cbnz    x4, 1f
1003
1004         tramp_unmap_kernel      tmp=x4
1005
1006 1:      sdei_handler_exit exit_mode=x2
1007 SYM_CODE_END(__sdei_asm_exit_trampoline)
1008 NOKPROBE(__sdei_asm_exit_trampoline)
1009         .ltorg
1010 .popsection             // .entry.tramp.text
1011 #ifdef CONFIG_RANDOMIZE_BASE
1012 .pushsection ".rodata", "a"
1013 SYM_DATA_START(__sdei_asm_trampoline_next_handler)
1014         .quad   __sdei_asm_handler
1015 SYM_DATA_END(__sdei_asm_trampoline_next_handler)
1016 .popsection             // .rodata
1017 #endif /* CONFIG_RANDOMIZE_BASE */
1018 #endif /* CONFIG_UNMAP_KERNEL_AT_EL0 */
1019
1020 /*
1021  * Software Delegated Exception entry point.
1022  *
1023  * x0: Event number
1024  * x1: struct sdei_registered_event argument from registration time.
1025  * x2: interrupted PC
1026  * x3: interrupted PSTATE
1027  * x4: maybe clobbered by the trampoline
1028  *
1029  * Firmware has preserved x0->x17 for us, we must save/restore the rest to
1030  * follow SMC-CC. We save (or retrieve) all the registers as the handler may
1031  * want them.
1032  */
1033 SYM_CODE_START(__sdei_asm_handler)
1034         stp     x2, x3, [x1, #SDEI_EVENT_INTREGS + S_PC]
1035         stp     x4, x5, [x1, #SDEI_EVENT_INTREGS + 16 * 2]
1036         stp     x6, x7, [x1, #SDEI_EVENT_INTREGS + 16 * 3]
1037         stp     x8, x9, [x1, #SDEI_EVENT_INTREGS + 16 * 4]
1038         stp     x10, x11, [x1, #SDEI_EVENT_INTREGS + 16 * 5]
1039         stp     x12, x13, [x1, #SDEI_EVENT_INTREGS + 16 * 6]
1040         stp     x14, x15, [x1, #SDEI_EVENT_INTREGS + 16 * 7]
1041         stp     x16, x17, [x1, #SDEI_EVENT_INTREGS + 16 * 8]
1042         stp     x18, x19, [x1, #SDEI_EVENT_INTREGS + 16 * 9]
1043         stp     x20, x21, [x1, #SDEI_EVENT_INTREGS + 16 * 10]
1044         stp     x22, x23, [x1, #SDEI_EVENT_INTREGS + 16 * 11]
1045         stp     x24, x25, [x1, #SDEI_EVENT_INTREGS + 16 * 12]
1046         stp     x26, x27, [x1, #SDEI_EVENT_INTREGS + 16 * 13]
1047         stp     x28, x29, [x1, #SDEI_EVENT_INTREGS + 16 * 14]
1048         mov     x4, sp
1049         stp     lr, x4, [x1, #SDEI_EVENT_INTREGS + S_LR]
1050
1051         mov     x19, x1
1052
1053 #if defined(CONFIG_VMAP_STACK) || defined(CONFIG_SHADOW_CALL_STACK)
1054         ldrb    w4, [x19, #SDEI_EVENT_PRIORITY]
1055 #endif
1056
1057 #ifdef CONFIG_VMAP_STACK
1058         /*
1059          * entry.S may have been using sp as a scratch register, find whether
1060          * this is a normal or critical event and switch to the appropriate
1061          * stack for this CPU.
1062          */
1063         cbnz    w4, 1f
1064         ldr_this_cpu dst=x5, sym=sdei_stack_normal_ptr, tmp=x6
1065         b       2f
1066 1:      ldr_this_cpu dst=x5, sym=sdei_stack_critical_ptr, tmp=x6
1067 2:      mov     x6, #SDEI_STACK_SIZE
1068         add     x5, x5, x6
1069         mov     sp, x5
1070 #endif
1071
1072 #ifdef CONFIG_SHADOW_CALL_STACK
1073         /* Use a separate shadow call stack for normal and critical events */
1074         cbnz    w4, 3f
1075         adr_this_cpu dst=scs_sp, sym=sdei_shadow_call_stack_normal, tmp=x6
1076         b       4f
1077 3:      adr_this_cpu dst=scs_sp, sym=sdei_shadow_call_stack_critical, tmp=x6
1078 4:
1079 #endif
1080
1081         /*
1082          * We may have interrupted userspace, or a guest, or exit-from or
1083          * return-to either of these. We can't trust sp_el0, restore it.
1084          */
1085         mrs     x28, sp_el0
1086         ldr_this_cpu    dst=x0, sym=__entry_task, tmp=x1
1087         msr     sp_el0, x0
1088
1089         /* If we interrupted the kernel point to the previous stack/frame. */
1090         and     x0, x3, #0xc
1091         mrs     x1, CurrentEL
1092         cmp     x0, x1
1093         csel    x29, x29, xzr, eq       // fp, or zero
1094         csel    x4, x2, xzr, eq         // elr, or zero
1095
1096         stp     x29, x4, [sp, #-16]!
1097         mov     x29, sp
1098
1099         add     x0, x19, #SDEI_EVENT_INTREGS
1100         mov     x1, x19
1101         bl      __sdei_handler
1102
1103         msr     sp_el0, x28
1104         /* restore regs >x17 that we clobbered */
1105         mov     x4, x19         // keep x4 for __sdei_asm_exit_trampoline
1106         ldp     x28, x29, [x4, #SDEI_EVENT_INTREGS + 16 * 14]
1107         ldp     x18, x19, [x4, #SDEI_EVENT_INTREGS + 16 * 9]
1108         ldp     lr, x1, [x4, #SDEI_EVENT_INTREGS + S_LR]
1109         mov     sp, x1
1110
1111         mov     x1, x0                  // address to complete_and_resume
1112         /* x0 = (x0 <= 1) ? EVENT_COMPLETE:EVENT_COMPLETE_AND_RESUME */
1113         cmp     x0, #1
1114         mov_q   x2, SDEI_1_0_FN_SDEI_EVENT_COMPLETE
1115         mov_q   x3, SDEI_1_0_FN_SDEI_EVENT_COMPLETE_AND_RESUME
1116         csel    x0, x2, x3, ls
1117
1118         ldr_l   x2, sdei_exit_mode
1119
1120 alternative_if_not ARM64_UNMAP_KERNEL_AT_EL0
1121         sdei_handler_exit exit_mode=x2
1122 alternative_else_nop_endif
1123
1124 #ifdef CONFIG_UNMAP_KERNEL_AT_EL0
1125         tramp_alias     dst=x5, sym=__sdei_asm_exit_trampoline
1126         br      x5
1127 #endif
1128 SYM_CODE_END(__sdei_asm_handler)
1129 NOKPROBE(__sdei_asm_handler)
1130 #endif /* CONFIG_ARM_SDE_INTERFACE */