arch/arm/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /* ld script to make ARM Linux kernel
   3  * taken from the i386 version by Russell King
   4  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  */
   6
   7 #ifdef CONFIG_XIP_KERNEL
   8 #include "vmlinux-xip.lds.S"
   9 #else
  10
  11 #include <linux/pgtable.h>
  12 #include <asm/vmlinux.lds.h>
  13 #include <asm/cache.h>
  14 #include <asm/thread_info.h>
  15 #include <asm/memory.h>
  16 #include <asm/mpu.h>
  17 #include <asm/page.h>
  18
  19 OUTPUT_ARCH(arm)
  20 ENTRY(stext)
  21
  22 #ifndef __ARMEB__
  23 jiffies = jiffies_64;
  24 #else
  25 jiffies = jiffies_64 + 4;
  26 #endif
  27
  28 SECTIONS
  29 {
  30         /*
  31          * XXX: The linker does not define how output sections are
  32          * assigned to input sections when there are multiple statements
  33          * matching the same input section name.  There is no documented
  34          * order of matching.
  35          *
  36          * unwind exit sections must be discarded before the rest of the
  37          * unwind sections get included.
  38          */
  39         /DISCARD/ : {
  40                 ARM_DISCARD
  41 #ifndef CONFIG_SMP_ON_UP
  42                 *(.alt.smp.init)
  43 #endif
  44         }
  45
  46         . = PAGE_OFFSET + TEXT_OFFSET;
  47         .head.text : {
  48                 _text = .;
  49                 HEAD_TEXT
  50         }
  51
  52 #ifdef CONFIG_STRICT_KERNEL_RWX
  53         . = ALIGN(1<<SECTION_SHIFT);
  54 #endif
  55
  56 #ifdef CONFIG_ARM_MPU
  57         . = ALIGN(PMSAv8_MINALIGN);
  58 #endif
  59         .text : {                       /* Real text segment            */
  60                 _stext = .;             /* Text and read-only data      */
  61                 ARM_TEXT
  62         }
  63
  64 #ifdef CONFIG_DEBUG_ALIGN_RODATA
  65         . = ALIGN(1<<SECTION_SHIFT);
  66 #endif
  67         _etext = .;                     /* End of text section */
  68
  69         RO_DATA(PAGE_SIZE)
  70
  71         . = ALIGN(4);
  72         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
  73                 __start___ex_table = .;
  74                 ARM_MMU_KEEP(*(__ex_table))
  75                 __stop___ex_table = .;
  76         }
  77
  78 #ifdef CONFIG_ARM_UNWIND
  79         ARM_UNWIND_SECTIONS
  80 #endif
  81
  82 #ifdef CONFIG_STRICT_KERNEL_RWX
  83         . = ALIGN(1<<SECTION_SHIFT);
  84 #else
  85         . = ALIGN(PAGE_SIZE);
  86 #endif
  87         __init_begin = .;
  88
  89         ARM_VECTORS
  90         INIT_TEXT_SECTION(8)
  91         .exit.text : {
  92                 ARM_EXIT_KEEP(EXIT_TEXT)
  93         }
  94         .init.proc.info : {
  95                 ARM_CPU_DISCARD(PROC_INFO)
  96         }
  97         .init.arch.info : {
  98                 __arch_info_begin = .;
  99                 *(.arch.info.init)
 100                 __arch_info_end = .;
 101         }
 102         .init.tagtable : {
 103                 __tagtable_begin = .;
 104                 *(.taglist.init)
 105                 __tagtable_end = .;
 106         }
 107 #ifdef CONFIG_SMP_ON_UP
 108         .init.smpalt : {
 109                 __smpalt_begin = .;
 110                 *(.alt.smp.init)
 111                 __smpalt_end = .;
 112         }
 113 #endif
 114         .init.pv_table : {
 115                 __pv_table_begin = .;
 116                 *(.pv_table)
 117                 __pv_table_end = .;
 118         }
 119
 120         INIT_DATA_SECTION(16)
 121
 122         .exit.data : {
 123                 ARM_EXIT_KEEP(EXIT_DATA)
 124         }
 125
 126 #ifdef CONFIG_SMP
 127         PERCPU_SECTION(L1_CACHE_BYTES)
 128 #endif
 129
 130 #ifdef CONFIG_HAVE_TCM
 131         ARM_TCM
 132 #endif
 133
 134 #ifdef CONFIG_STRICT_KERNEL_RWX
 135         . = ALIGN(1<<SECTION_SHIFT);
 136 #else
 137         . = ALIGN(THREAD_SIZE);
 138 #endif
 139         __init_end = .;
 140
 141         _sdata = .;
 142         RW_DATA(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
 143         _edata = .;
 144
 145         BSS_SECTION(0, 0, 0)
 146 #ifdef CONFIG_ARM_MPU
 147         . = ALIGN(PMSAv8_MINALIGN);
 148 #endif
 149         _end = .;
 150
 151         STABS_DEBUG
 152         DWARF_DEBUG
 153         ARM_DETAILS
 154
 155         ARM_ASSERTS
 156 }
 157
 158 #ifdef CONFIG_STRICT_KERNEL_RWX
 159 /*
 160  * Without CONFIG_DEBUG_ALIGN_RODATA, __start_rodata_section_aligned will
 161  * be the first section-aligned location after __start_rodata. Otherwise,
 162  * it will be equal to __start_rodata.
 163  */
 164 __start_rodata_section_aligned = ALIGN(__start_rodata, 1 << SECTION_SHIFT);
 165 #endif
 166
 167 /*
 168  * These must never be empty
 169  * If you have to comment these two assert statements out, your
 170  * binutils is too old (for other reasons as well)
 171  */
 172 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 173 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")
 174
 175 #endif /* CONFIG_XIP_KERNEL */